subroutine sgbequb	(	integer	M,
		integer	N,
		integer	KL,
		integer	KU,
		real, dimension( ldab, * )	AB,
		integer	LDAB,
		real, dimension( * )	R,
		real, dimension( * )	C,
		real	ROWCND,
		real	COLCND,
		real	AMAX,
		integer	INFO
	)

SGBEQUB

Download SGBEQUB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SGBEQUB computes row and column scalings intended to equilibrate an
 M-by-N matrix A and reduce its condition number.  R returns the row
 scale factors and C the column scale factors, chosen to try to make
 the largest element in each row and column of the matrix B with
 elements B(i,j)=R(i)*A(i,j)*C(j) have an absolute value of at most
 the radix.

 R(i) and C(j) are restricted to be a power of the radix between
 SMLNUM = smallest safe number and BIGNUM = largest safe number.  Use
 of these scaling factors is not guaranteed to reduce the condition
 number of A but works well in practice.

 This routine differs from SGEEQU by restricting the scaling factors
 to a power of the radix.  Baring over- and underflow, scaling by
 these factors introduces no additional rounding errors.  However, the
 scaled entries' magnitured are no longer approximately 1 but lie
 between sqrt(radix) and 1/sqrt(radix).

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	KL	KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.
[in]	KU	KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.
[in]	AB	AB is REAL array, dimension (LDAB,N) On entry, the matrix A in band storage, in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
[in]	LDAB	LDAB is INTEGER The leading dimension of the array A. LDAB >= max(1,M).
[out]	R	R is REAL array, dimension (M) If INFO = 0 or INFO > M, R contains the row scale factors for A.
[out]	C	C is REAL array, dimension (N) If INFO = 0, C contains the column scale factors for A.
[out]	ROWCND	ROWCND is REAL If INFO = 0 or INFO > M, ROWCND contains the ratio of the smallest R(i) to the largest R(i). If ROWCND >= 0.1 and AMAX is neither too large nor too small, it is not worth scaling by R.
[out]	COLCND	COLCND is REAL If INFO = 0, COLCND contains the ratio of the smallest C(i) to the largest C(i). If COLCND >= 0.1, it is not worth scaling by C.
[out]	AMAX	AMAX is REAL Absolute value of largest matrix element. If AMAX is very close to overflow or very close to underflow, the matrix should be scaled.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, and i is <= M: the i-th row of A is exactly zero > M: the (i-M)-th column of A is exactly zero

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2016

Definition at line 162 of file sgbequb.f.

*
*  -- LAPACK computational routine (version 3.6.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      INTEGER            info, kl, ku, ldab, m, n
      REAL               amax, colcnd, rowcnd
*     ..
*     .. Array Arguments ..
      REAL               ab( ldab, * ), c( * ), r( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, kd
      REAL               bignum, rcmax, rcmin, smlnum, radix, logrdx
*     ..
*     .. External Functions ..
      REAL               slamch
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, log
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 ) THEN
         info = -3
      ELSE IF( ku.LT.0 ) THEN
         info = -4
      ELSE IF( ldab.LT.kl+ku+1 ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGBEQUB', -info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         rowcnd = one
         colcnd = one
         amax = zero
         RETURN
      END IF
*
*     Get machine constants.  Assume SMLNUM is a power of the radix.
*
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      radix = slamch( 'B' )
      logrdx = log(radix)
*
*     Compute row scale factors.
*
      DO 10 i = 1, m
         r( i ) = zero
   10 CONTINUE
*
*     Find the maximum element in each row.
*
      kd = ku + 1
      DO 30 j = 1, n
         DO 20 i = max( j-ku, 1 ), min( j+kl, m )
            r( i ) = max( r( i ), abs( ab( kd+i-j, j ) ) )
   20    CONTINUE
   30 CONTINUE
      DO i = 1, m
         IF( r( i ).GT.zero ) THEN
            r( i ) = radix**int( log( r( i ) ) / logrdx )
         END IF
      END DO
*
*     Find the maximum and minimum scale factors.
*
      rcmin = bignum
      rcmax = zero
      DO 40 i = 1, m
         rcmax = max( rcmax, r( i ) )
         rcmin = min( rcmin, r( i ) )
   40 CONTINUE
      amax = rcmax
*
      IF( rcmin.EQ.zero ) THEN
*
*        Find the first zero scale factor and return an error code.
*
         DO 50 i = 1, m
            IF( r( i ).EQ.zero ) THEN
               info = i
               RETURN
            END IF
   50    CONTINUE
      ELSE
*
*        Invert the scale factors.
*
         DO 60 i = 1, m
            r( i ) = one / min( max( r( i ), smlnum ), bignum )
   60    CONTINUE
*
*        Compute ROWCND = min(R(I)) / max(R(I)).
*
         rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
      END IF
*
*     Compute column scale factors.
*
      DO 70 j = 1, n
         c( j ) = zero
   70 CONTINUE
*
*     Find the maximum element in each column,
*     assuming the row scaling computed above.
*
      DO 90 j = 1, n
         DO 80 i = max( j-ku, 1 ), min( j+kl, m )
            c( j ) = max( c( j ), abs( ab( kd+i-j, j ) )*r( i ) )
   80    CONTINUE
         IF( c( j ).GT.zero ) THEN
            c( j ) = radix**int( log( c( j ) ) / logrdx )
         END IF
   90 CONTINUE
*
*     Find the maximum and minimum scale factors.
*
      rcmin = bignum
      rcmax = zero
      DO 100 j = 1, n
         rcmin = min( rcmin, c( j ) )
         rcmax = max( rcmax, c( j ) )
  100 CONTINUE
*
      IF( rcmin.EQ.zero ) THEN
*
*        Find the first zero scale factor and return an error code.
*
         DO 110 j = 1, n
            IF( c( j ).EQ.zero ) THEN
               info = m + j
               RETURN
            END IF
  110    CONTINUE
      ELSE
*
*        Invert the scale factors.
*
         DO 120 j = 1, n
            c( j ) = one / min( max( c( j ), smlnum ), bignum )
  120    CONTINUE
*
*        Compute COLCND = min(C(J)) / max(C(J)).
*
         colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
      END IF
*
      RETURN
*
*     End of SGBEQUB
*

Here is the call graph for this function:

Here is the caller graph for this function: