subroutine clakf2	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( lda, * )	B,
		complex, dimension( lda, * )	D,
		complex, dimension( lda, * )	E,
		complex, dimension( ldz, * )	Z,
		integer	LDZ
	)

CLAKF2

Purpose:

 Form the 2*M*N by 2*M*N matrix

        Z = [ kron(In, A)  -kron(B', Im) ]
            [ kron(In, D)  -kron(E', Im) ],

 where In is the identity matrix of size n and X' is the transpose
 of X. kron(X, Y) is the Kronecker product between the matrices X
 and Y.

Parameters

[in]	M	M is INTEGER Size of matrix, must be >= 1.
[in]	N	N is INTEGER Size of matrix, must be >= 1.
[in]	A	A is COMPLEX, dimension ( LDA, M ) The matrix A in the output matrix Z.
[in]	LDA	LDA is INTEGER The leading dimension of A, B, D, and E. ( LDA >= M+N )
[in]	B	B is COMPLEX, dimension ( LDA, N )
[in]	D	D is COMPLEX, dimension ( LDA, M )
[in]	E	E is COMPLEX, dimension ( LDA, N ) The matrices used in forming the output matrix Z.
[out]	Z	Z is COMPLEX, dimension ( LDZ, 2*M*N ) The resultant Kronecker M*N*2 by M*N*2 matrix (see above.)
[in]	LDZ	LDZ is INTEGER The leading dimension of Z. ( LDZ >= 2*M*N )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 107 of file clakf2.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldz, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), b( lda, * ), d( lda, * ),
     $                   e( lda, * ), z( ldz, * )
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      COMPLEX            zero
      parameter                ( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ik, j, jk, l, mn, mn2
*     ..
*     .. External Subroutines ..
      EXTERNAL           claset
*     ..
*     .. Executable Statements ..
*
*     Initialize Z
*
      mn = m*n
      mn2 = 2*mn
      CALL claset( 'Full', mn2, mn2, zero, zero, z, ldz )
*
      ik = 1
      DO 50 l = 1, n
*
*        form kron(In, A)
*
         DO 20 i = 1, m
            DO 10 j = 1, m
               z( ik+i-1, ik+j-1 ) = a( i, j )
   10       CONTINUE
   20    CONTINUE
*
*        form kron(In, D)
*
         DO 40 i = 1, m
            DO 30 j = 1, m
               z( ik+mn+i-1, ik+j-1 ) = d( i, j )
   30       CONTINUE
   40    CONTINUE
*
         ik = ik + m
   50 CONTINUE
*
      ik = 1
      DO 90 l = 1, n
         jk = mn + 1
*
         DO 80 j = 1, n
*
*           form -kron(B', Im)
*
            DO 60 i = 1, m
               z( ik+i-1, jk+i-1 ) = -b( j, l )
   60       CONTINUE
*
*           form -kron(E', Im)
*
            DO 70 i = 1, m
               z( ik+mn+i-1, jk+i-1 ) = -e( j, l )
   70       CONTINUE
*
            jk = jk + m
   80    CONTINUE
*
         ik = ik + m
   90 CONTINUE
*
      RETURN
*
*     End of CLAKF2
*

Here is the call graph for this function:

Here is the caller graph for this function: