subroutine dgerqs	(	integer	M,
		integer	N,
		integer	NRHS,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	TAU,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision, dimension( lwork )	WORK,
		integer	LWORK,
		integer	INFO
	)

DGERQS

Purpose:

 Compute a minimum-norm solution
     min || A*X - B ||
 using the RQ factorization
     A = R*Q
 computed by DGERQF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= M >= 0.
[in]	NRHS	NRHS is INTEGER The number of columns of B. NRHS >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) Details of the RQ factorization of the original matrix A as returned by DGERQF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= M.
[in]	TAU	TAU is DOUBLE PRECISION array, dimension (M) Details of the orthogonal matrix Q.
[in,out]	B	B is DOUBLE PRECISION array, dimension (LDB,NRHS) On entry, the right hand side vectors for the linear system. On exit, the solution vectors X. Each solution vector is contained in rows 1:N of a column of B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK must be at least NRHS, and should be at least NRHS*NB, where NB is the block size for this environment.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 124 of file dgerqs.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, ldb, lwork, m, n, nrhs
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlaset, dormrq, dtrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. m.GT.n ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.1 .OR. lwork.LT.nrhs .AND. m.GT.0 .AND. n.GT.0 )
     $          THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGERQS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 .OR. m.EQ.0 )
     $   RETURN
*
*     Solve R*X = B(n-m+1:n,:)
*
      CALL dtrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', m, nrhs,
     $            one, a( 1, n-m+1 ), lda, b( n-m+1, 1 ), ldb )
*
*     Set B(1:n-m,:) to zero
*
      CALL dlaset( 'Full', n-m, nrhs, zero, zero, b, ldb )
*
*     B := Q' * B
*
      CALL dormrq( 'Left', 'Transpose', n, nrhs, m, a, lda, tau, b, ldb,
     $             work, lwork, info )
*
      RETURN
*
*     End of DGERQS
*

Here is the call graph for this function:

Here is the caller graph for this function: