subroutine dppt03	(	character	UPLO,
		integer	N,
		double precision, dimension( * )	A,
		double precision, dimension( * )	AINV,
		double precision, dimension( ldwork, * )	WORK,
		integer	LDWORK,
		double precision, dimension( * )	RWORK,
		double precision	RCOND,
		double precision	RESID
	)

DPPT03

Purpose:

 DPPT03 computes the residual for a symmetric packed matrix times its
 inverse:
    norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (N*(N+1)/2) The original symmetric matrix A, stored as a packed triangular matrix.
[in]	AINV	AINV is DOUBLE PRECISION array, dimension (N*(N+1)/2) The (symmetric) inverse of the matrix A, stored as a packed triangular matrix.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LDWORK,N)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of the array WORK. LDWORK >= max(1,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RCOND	RCOND is DOUBLE PRECISION The reciprocal of the condition number of A, computed as ( 1/norm(A) ) / norm(AINV).
[out]	RESID	RESID is DOUBLE PRECISION norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 112 of file dppt03.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldwork, n
      DOUBLE PRECISION   rcond, resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( * ), ainv( * ), rwork( * ),
     $                   work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, jj
      DOUBLE PRECISION   ainvnm, anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, dlange, dlansp
      EXTERNAL           lsame, dlamch, dlange, dlansp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dspmv
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansp( '1', uplo, n, a, rwork )
      ainvnm = dlansp( '1', uplo, n, ainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.EQ.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     UPLO = 'U':
*     Copy the leading N-1 x N-1 submatrix of AINV to WORK(1:N,2:N) and
*     expand it to a full matrix, then multiply by A one column at a
*     time, moving the result one column to the left.
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Copy AINV
*
         jj = 1
         DO 10 j = 1, n - 1
            CALL dcopy( j, ainv( jj ), 1, work( 1, j+1 ), 1 )
            CALL dcopy( j-1, ainv( jj ), 1, work( j, 2 ), ldwork )
            jj = jj + j
   10    CONTINUE
         jj = ( ( n-1 )*n ) / 2 + 1
         CALL dcopy( n-1, ainv( jj ), 1, work( n, 2 ), ldwork )
*
*        Multiply by A
*
         DO 20 j = 1, n - 1
            CALL dspmv( 'Upper', n, -one, a, work( 1, j+1 ), 1, zero,
     $                  work( 1, j ), 1 )
   20    CONTINUE
         CALL dspmv( 'Upper', n, -one, a, ainv( jj ), 1, zero,
     $               work( 1, n ), 1 )
*
*     UPLO = 'L':
*     Copy the trailing N-1 x N-1 submatrix of AINV to WORK(1:N,1:N-1)
*     and multiply by A, moving each column to the right.
*
      ELSE
*
*        Copy AINV
*
         CALL dcopy( n-1, ainv( 2 ), 1, work( 1, 1 ), ldwork )
         jj = n + 1
         DO 30 j = 2, n
            CALL dcopy( n-j+1, ainv( jj ), 1, work( j, j-1 ), 1 )
            CALL dcopy( n-j, ainv( jj+1 ), 1, work( j, j ), ldwork )
            jj = jj + n - j + 1
   30    CONTINUE
*
*        Multiply by A
*
         DO 40 j = n, 2, -1
            CALL dspmv( 'Lower', n, -one, a, work( 1, j-1 ), 1, zero,
     $                  work( 1, j ), 1 )
   40    CONTINUE
         CALL dspmv( 'Lower', n, -one, a, ainv( 1 ), 1, zero,
     $               work( 1, 1 ), 1 )
*
      END IF
*
*     Add the identity matrix to WORK .
*
      DO 50 i = 1, n
         work( i, i ) = work( i, i ) + one
   50 CONTINUE
*
*     Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = dlange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / dble( n )
*
      RETURN
*
*     End of DPPT03
*

Here is the call graph for this function:

Here is the caller graph for this function: