subroutine dgbt02	(	character	TRANS,
		integer	M,
		integer	N,
		integer	KL,
		integer	KU,
		integer	NRHS,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldx, * )	X,
		integer	LDX,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision	RESID
	)

DGBT02

Purpose:

 DGBT02 computes the residual for a solution of a banded system of
 equations  A*x = b  or  A'*x = b:
    RESID = norm( B - A*X ) / ( norm(A) * norm(X) * EPS).
 where EPS is the machine precision.

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A *x = b = 'T': A'*x = b, where A' is the transpose of A = 'C': A'*x = b, where A' is the transpose of A
[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	KL	KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.
[in]	KU	KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.
[in]	NRHS	NRHS is INTEGER The number of columns of B. NRHS >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The original matrix A in band storage, stored in rows 1 to KL+KU+1.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,KL+KU+1).
[in]	X	X is DOUBLE PRECISION array, dimension (LDX,NRHS) The computed solution vectors for the system of linear equations.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M).
[in,out]	B	B is DOUBLE PRECISION array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - A*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. IF TRANS = 'N', LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N).
[out]	RESID	RESID is DOUBLE PRECISION The maximum over the number of right hand sides of norm(B - A*X) / ( norm(A) * norm(X) * EPS ).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 141 of file dgbt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            kl, ku, lda, ldb, ldx, m, n, nrhs
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i1, i2, j, kd, n1
      DOUBLE PRECISION   anorm, bnorm, eps, xnorm
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dasum, dlamch
      EXTERNAL           lsame, dasum, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgbmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if N = 0 pr NRHS = 0
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      kd = ku + 1
      anorm = zero
      DO 10 j = 1, n
         i1 = max( kd+1-j, 1 )
         i2 = min( kd+m-j, kl+kd )
         anorm = max( anorm, dasum( i2-i1+1, a( i1, j ), 1 ) )
   10 CONTINUE
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
      IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
         n1 = n
      ELSE
         n1 = m
      END IF
*
*     Compute  B - A*X (or  B - A'*X )
*
      DO 20 j = 1, nrhs
         CALL dgbmv( trans, m, n, kl, ku, -one, a, lda, x( 1, j ), 1,
     $               one, b( 1, j ), 1 )
   20 CONTINUE
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - A*X) / ( norm(A) * norm(X) * EPS ).
*
      resid = zero
      DO 30 j = 1, nrhs
         bnorm = dasum( n1, b( 1, j ), 1 )
         xnorm = dasum( n1, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   30 CONTINUE
*
      RETURN
*
*     End of DGBT02
*

Here is the call graph for this function:

Here is the caller graph for this function: