subroutine slarrc	(	character	JOBT,
		integer	N,
		real	VL,
		real	VU,
		real, dimension( * )	D,
		real, dimension( * )	E,
		real	PIVMIN,
		integer	EIGCNT,
		integer	LCNT,
		integer	RCNT,
		integer	INFO
	)

SLARRC computes the number of eigenvalues of the symmetric tridiagonal matrix.

Download SLARRC + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 Find the number of eigenvalues of the symmetric tridiagonal matrix T
 that are in the interval (VL,VU] if JOBT = 'T', and of L D L^T
 if JOBT = 'L'.

Parameters

[in]	JOBT	JOBT is CHARACTER*1 = 'T': Compute Sturm count for matrix T. = 'L': Compute Sturm count for matrix L D L^T.
[in]	N	N is INTEGER The order of the matrix. N > 0.
[in]	VL	VL is REAL The lower bound for the eigenvalues.
[in]	VU	VU is REAL The upper bound for the eigenvalues.
[in]	D	D is REAL array, dimension (N) JOBT = 'T': The N diagonal elements of the tridiagonal matrix T. JOBT = 'L': The N diagonal elements of the diagonal matrix D.
[in]	E	E is REAL array, dimension (N) JOBT = 'T': The N-1 offdiagonal elements of the matrix T. JOBT = 'L': The N-1 offdiagonal elements of the matrix L.
[in]	PIVMIN	PIVMIN is REAL The minimum pivot in the Sturm sequence for T.
[out]	EIGCNT	EIGCNT is INTEGER The number of eigenvalues of the symmetric tridiagonal matrix T that are in the interval (VL,VU]
[out]	LCNT	LCNT is INTEGER
[out]	RCNT	RCNT is INTEGER The left and right negcounts of the interval.
[out]	INFO	INFO is INTEGER

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2016

Contributors:

Beresford Parlett, University of California, Berkeley, USA
Jim Demmel, University of California, Berkeley, USA
Inderjit Dhillon, University of Texas, Austin, USA
Osni Marques, LBNL/NERSC, USA
Christof Voemel, University of California, Berkeley, USA

Definition at line 139 of file slarrc.f.

*
*  -- LAPACK auxiliary routine (version 3.6.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      CHARACTER          jobt
      INTEGER            eigcnt, info, lcnt, n, rcnt
      REAL               pivmin, vl, vu
*     ..
*     .. Array Arguments ..
      REAL               d( * ), e( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero
      parameter                ( zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      LOGICAL            matt
      REAL               lpivot, rpivot, sl, su, tmp, tmp2

*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
      info = 0
      lcnt = 0
      rcnt = 0
      eigcnt = 0
      matt = lsame( jobt, 'T' )


      IF (matt) THEN
*        Sturm sequence count on T
         lpivot = d( 1 ) - vl
         rpivot = d( 1 ) - vu
         IF( lpivot.LE.zero ) THEN
            lcnt = lcnt + 1
         ENDIF
         IF( rpivot.LE.zero ) THEN
            rcnt = rcnt + 1
         ENDIF
         DO 10 i = 1, n-1
            tmp = e(i)**2
            lpivot = ( d( i+1 )-vl ) - tmp/lpivot
            rpivot = ( d( i+1 )-vu ) - tmp/rpivot
            IF( lpivot.LE.zero ) THEN
               lcnt = lcnt + 1
            ENDIF
            IF( rpivot.LE.zero ) THEN
               rcnt = rcnt + 1
            ENDIF
 10      CONTINUE
      ELSE
*        Sturm sequence count on L D L^T
         sl = -vl
         su = -vu
         DO 20 i = 1, n - 1
            lpivot = d( i ) + sl
            rpivot = d( i ) + su
            IF( lpivot.LE.zero ) THEN
               lcnt = lcnt + 1
            ENDIF
            IF( rpivot.LE.zero ) THEN
               rcnt = rcnt + 1
            ENDIF
            tmp = e(i) * d(i) * e(i)
*
            tmp2 = tmp / lpivot
            IF( tmp2.EQ.zero ) THEN
               sl =  tmp - vl
            ELSE
               sl = sl*tmp2 - vl
            END IF
*
            tmp2 = tmp / rpivot
            IF( tmp2.EQ.zero ) THEN
               su =  tmp - vu
            ELSE
               su = su*tmp2 - vu
            END IF
 20      CONTINUE
         lpivot = d( n ) + sl
         rpivot = d( n ) + su
         IF( lpivot.LE.zero ) THEN
            lcnt = lcnt + 1
         ENDIF
         IF( rpivot.LE.zero ) THEN
            rcnt = rcnt + 1
         ENDIF
      ENDIF
      eigcnt = rcnt - lcnt

      RETURN
*
*     end of SLARRC
*

Here is the caller graph for this function: