subroutine dlaev2	(	double precision	A,
		double precision	B,
		double precision	C,
		double precision	RT1,
		double precision	RT2,
		double precision	CS1,
		double precision	SN1
	)

DLAEV2 computes the eigenvalues and eigenvectors of a 2-by-2 symmetric/Hermitian matrix.

Download DLAEV2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLAEV2 computes the eigendecomposition of a 2-by-2 symmetric matrix
    [  A   B  ]
    [  B   C  ].
 On return, RT1 is the eigenvalue of larger absolute value, RT2 is the
 eigenvalue of smaller absolute value, and (CS1,SN1) is the unit right
 eigenvector for RT1, giving the decomposition

    [ CS1  SN1 ] [  A   B  ] [ CS1 -SN1 ]  =  [ RT1  0  ]
    [-SN1  CS1 ] [  B   C  ] [ SN1  CS1 ]     [  0  RT2 ].

Parameters

[in]	A	A is DOUBLE PRECISION The (1,1) element of the 2-by-2 matrix.
[in]	B	B is DOUBLE PRECISION The (1,2) element and the conjugate of the (2,1) element of the 2-by-2 matrix.
[in]	C	C is DOUBLE PRECISION The (2,2) element of the 2-by-2 matrix.
[out]	RT1	RT1 is DOUBLE PRECISION The eigenvalue of larger absolute value.
[out]	RT2	RT2 is DOUBLE PRECISION The eigenvalue of smaller absolute value.
[out]	CS1	CS1 is DOUBLE PRECISION
[out]	SN1	SN1 is DOUBLE PRECISION The vector (CS1, SN1) is a unit right eigenvector for RT1.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Further Details:

  RT1 is accurate to a few ulps barring over/underflow.

  RT2 may be inaccurate if there is massive cancellation in the
  determinant A*C-B*B; higher precision or correctly rounded or
  correctly truncated arithmetic would be needed to compute RT2
  accurately in all cases.

  CS1 and SN1 are accurate to a few ulps barring over/underflow.

  Overflow is possible only if RT1 is within a factor of 5 of overflow.
  Underflow is harmless if the input data is 0 or exceeds
     underflow_threshold / macheps.

Definition at line 122 of file dlaev2.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   a, b, c, cs1, rt1, rt2, sn1
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one
      parameter                ( one = 1.0d0 )
      DOUBLE PRECISION   two
      parameter                ( two = 2.0d0 )
      DOUBLE PRECISION   zero
      parameter                ( zero = 0.0d0 )
      DOUBLE PRECISION   half
      parameter                ( half = 0.5d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            sgn1, sgn2
      DOUBLE PRECISION   ab, acmn, acmx, acs, adf, cs, ct, df, rt, sm,
     $                   tb, tn
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
*     Compute the eigenvalues
*
      sm = a + c
      df = a - c
      adf = abs( df )
      tb = b + b
      ab = abs( tb )
      IF( abs( a ).GT.abs( c ) ) THEN
         acmx = a
         acmn = c
      ELSE
         acmx = c
         acmn = a
      END IF
      IF( adf.GT.ab ) THEN
         rt = adf*sqrt( one+( ab / adf )**2 )
      ELSE IF( adf.LT.ab ) THEN
         rt = ab*sqrt( one+( adf / ab )**2 )
      ELSE
*
*        Includes case AB=ADF=0
*
         rt = ab*sqrt( two )
      END IF
      IF( sm.LT.zero ) THEN
         rt1 = half*( sm-rt )
         sgn1 = -1
*
*        Order of execution important.
*        To get fully accurate smaller eigenvalue,
*        next line needs to be executed in higher precision.
*
         rt2 = ( acmx / rt1 )*acmn - ( b / rt1 )*b
      ELSE IF( sm.GT.zero ) THEN
         rt1 = half*( sm+rt )
         sgn1 = 1
*
*        Order of execution important.
*        To get fully accurate smaller eigenvalue,
*        next line needs to be executed in higher precision.
*
         rt2 = ( acmx / rt1 )*acmn - ( b / rt1 )*b
      ELSE
*
*        Includes case RT1 = RT2 = 0
*
         rt1 = half*rt
         rt2 = -half*rt
         sgn1 = 1
      END IF
*
*     Compute the eigenvector
*
      IF( df.GE.zero ) THEN
         cs = df + rt
         sgn2 = 1
      ELSE
         cs = df - rt
         sgn2 = -1
      END IF
      acs = abs( cs )
      IF( acs.GT.ab ) THEN
         ct = -tb / cs
         sn1 = one / sqrt( one+ct*ct )
         cs1 = ct*sn1
      ELSE
         IF( ab.EQ.zero ) THEN
            cs1 = one
            sn1 = zero
         ELSE
            tn = -cs / tb
            cs1 = one / sqrt( one+tn*tn )
            sn1 = tn*cs1
         END IF
      END IF
      IF( sgn1.EQ.sgn2 ) THEN
         tn = cs1
         cs1 = -sn1
         sn1 = tn
      END IF
      RETURN
*
*     End of DLAEV2
*

Here is the caller graph for this function: