subroutine cpoequb	(	integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	S,
		real	SCOND,
		real	AMAX,
		integer	INFO
	)

CPOEQUB

Download CPOEQUB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CPOEQUB computes row and column scalings intended to equilibrate a
 symmetric positive definite matrix A and reduce its condition number
 (with respect to the two-norm).  S contains the scale factors,
 S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
 elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
 choice of S puts the condition number of B within a factor N of the
 smallest possible condition number over all possible diagonal
 scalings.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The N-by-N symmetric positive definite matrix whose scaling factors are to be computed. Only the diagonal elements of A are referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	S	S is REAL array, dimension (N) If INFO = 0, S contains the scale factors for A.
[out]	SCOND	SCOND is REAL If INFO = 0, S contains the ratio of the smallest S(i) to the largest S(i). If SCOND >= 0.1 and AMAX is neither too large nor too small, it is not worth scaling by S.
[out]	AMAX	AMAX is REAL Absolute value of largest matrix element. If AMAX is very close to overflow or very close to underflow, the matrix should be scaled.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the i-th diagonal element is nonpositive.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 115 of file cpoequb.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, n
      REAL               amax, scond
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * )
      REAL               s( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      REAL               smin, base, tmp
*     ..
*     .. External Functions ..
      REAL               slamch
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt, log, int
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
*     Positive definite only performs 1 pass of equilibration.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPOEQUB', -info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( n.EQ.0 ) THEN
         scond = one
         amax = zero
         RETURN
      END IF

      base = slamch( 'B' )
      tmp = -0.5 / log( base )
*
*     Find the minimum and maximum diagonal elements.
*
      s( 1 ) = a( 1, 1 )
      smin = s( 1 )
      amax = s( 1 )
      DO 10 i = 2, n
         s( i ) = a( i, i )
         smin = min( smin, s( i ) )
         amax = max( amax, s( i ) )
   10 CONTINUE
*
      IF( smin.LE.zero ) THEN
*
*        Find the first non-positive diagonal element and return.
*
         DO 20 i = 1, n
            IF( s( i ).LE.zero ) THEN
               info = i
               RETURN
            END IF
   20    CONTINUE
      ELSE
*
*        Set the scale factors to the reciprocals
*        of the diagonal elements.
*
         DO 30 i = 1, n
            s( i ) = base ** int( tmp * log( s( i ) ) )
   30    CONTINUE
*
*        Compute SCOND = min(S(I)) / max(S(I)).
*
         scond = sqrt( smin ) / sqrt( amax )
      END IF
*
      RETURN
*
*     End of CPOEQUB
*

Here is the call graph for this function:

Here is the caller graph for this function: