subroutine cstt22	(	integer	N,
		integer	M,
		integer	KBAND,
		real, dimension( * )	AD,
		real, dimension( * )	AE,
		real, dimension( * )	SD,
		real, dimension( * )	SE,
		complex, dimension( ldu, * )	U,
		integer	LDU,
		complex, dimension( ldwork, * )	WORK,
		integer	LDWORK,
		real, dimension( * )	RWORK,
		real, dimension( 2 )	RESULT
	)

CSTT22

Purpose:

 CSTT22  checks a set of M eigenvalues and eigenvectors,

     A U = U S

 where A is Hermitian tridiagonal, the columns of U are unitary,
 and S is diagonal (if KBAND=0) or Hermitian tridiagonal (if KBAND=1).
 Two tests are performed:

    RESULT(1) = | U* A U - S | / ( |A| m ulp )

    RESULT(2) = | I - U*U | / ( m ulp )

Parameters

[in]	N	N is INTEGER The size of the matrix. If it is zero, CSTT22 does nothing. It must be at least zero.
[in]	M	M is INTEGER The number of eigenpairs to check. If it is zero, CSTT22 does nothing. It must be at least zero.
[in]	KBAND	KBAND is INTEGER The bandwidth of the matrix S. It may only be zero or one. If zero, then S is diagonal, and SE is not referenced. If one, then S is Hermitian tri-diagonal.
[in]	AD	AD is REAL array, dimension (N) The diagonal of the original (unfactored) matrix A. A is assumed to be Hermitian tridiagonal.
[in]	AE	AE is REAL array, dimension (N) The off-diagonal of the original (unfactored) matrix A. A is assumed to be Hermitian tridiagonal. AE(1) is ignored, AE(2) is the (1,2) and (2,1) element, etc.
[in]	SD	SD is REAL array, dimension (N) The diagonal of the (Hermitian tri-) diagonal matrix S.
[in]	SE	SE is REAL array, dimension (N) The off-diagonal of the (Hermitian tri-) diagonal matrix S. Not referenced if KBSND=0. If KBAND=1, then AE(1) is ignored, SE(2) is the (1,2) and (2,1) element, etc.
[in]	U	U is REAL array, dimension (LDU, N) The unitary matrix in the decomposition.
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N.
[out]	WORK	WORK is COMPLEX array, dimension (LDWORK, M+1)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of WORK. LDWORK must be at least max(1,M).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESULT	RESULT is REAL array, dimension (2) The values computed by the two tests described above. The values are currently limited to 1/ulp, to avoid overflow.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 147 of file cstt22.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            kband, ldu, ldwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               ad( * ), ae( * ), result( 2 ), rwork( * ),
     $                   sd( * ), se( * )
      COMPLEX            u( ldu, * ), work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e0, one = 1.0e0 )
      COMPLEX            czero, cone
      parameter                ( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      REAL               anorm, ulp, unfl, wnorm
      COMPLEX            aukj
*     ..
*     .. External Functions ..
      REAL               clange, clansy, slamch
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 .OR. m.LE.0 )
     $   RETURN
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )
*
*     Do Test 1
*
*     Compute the 1-norm of A.
*
      IF( n.GT.1 ) THEN
         anorm = abs( ad( 1 ) ) + abs( ae( 1 ) )
         DO 10 j = 2, n - 1
            anorm = max( anorm, abs( ad( j ) )+abs( ae( j ) )+
     $              abs( ae( j-1 ) ) )
   10    CONTINUE
         anorm = max( anorm, abs( ad( n ) )+abs( ae( n-1 ) ) )
      ELSE
         anorm = abs( ad( 1 ) )
      END IF
      anorm = max( anorm, unfl )
*
*     Norm of U*AU - S
*
      DO 40 i = 1, m
         DO 30 j = 1, m
            work( i, j ) = czero
            DO 20 k = 1, n
               aukj = ad( k )*u( k, j )
               IF( k.NE.n )
     $            aukj = aukj + ae( k )*u( k+1, j )
               IF( k.NE.1 )
     $            aukj = aukj + ae( k-1 )*u( k-1, j )
               work( i, j ) = work( i, j ) + u( k, i )*aukj
   20       CONTINUE
   30    CONTINUE
         work( i, i ) = work( i, i ) - sd( i )
         IF( kband.EQ.1 ) THEN
            IF( i.NE.1 )
     $         work( i, i-1 ) = work( i, i-1 ) - se( i-1 )
            IF( i.NE.n )
     $         work( i, i+1 ) = work( i, i+1 ) - se( i )
         END IF
   40 CONTINUE
*
      wnorm = clansy( '1', 'L', m, work, m, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( m*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, m*anorm ) / anorm ) / ( m*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, REAL( M ) ) / ( m*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U*U - I
*
      CALL cgemm( 'T', 'N', m, m, n, cone, u, ldu, u, ldu, czero, work,
     $            m )
*
      DO 50 j = 1, m
         work( j, j ) = work( j, j ) - one
   50 CONTINUE
*
      result( 2 ) = min( REAL( M ), clange( '1', m, m, work, m,
     $              rwork ) ) / ( m*ulp )
*
      RETURN
*
*     End of CSTT22
*

Here is the call graph for this function:

Here is the caller graph for this function: