subroutine zgbequ	(	integer	M,
		integer	N,
		integer	KL,
		integer	KU,
		complex*16, dimension( ldab, * )	AB,
		integer	LDAB,
		double precision, dimension( * )	R,
		double precision, dimension( * )	C,
		double precision	ROWCND,
		double precision	COLCND,
		double precision	AMAX,
		integer	INFO
	)

ZGBEQU

Download ZGBEQU + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZGBEQU computes row and column scalings intended to equilibrate an
 M-by-N band matrix A and reduce its condition number.  R returns the
 row scale factors and C the column scale factors, chosen to try to
 make the largest element in each row and column of the matrix B with
 elements B(i,j)=R(i)*A(i,j)*C(j) have absolute value 1.

 R(i) and C(j) are restricted to be between SMLNUM = smallest safe
 number and BIGNUM = largest safe number.  Use of these scaling
 factors is not guaranteed to reduce the condition number of A but
 works well in practice.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	KL	KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.
[in]	KU	KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.
[in]	AB	AB is COMPLEX*16 array, dimension (LDAB,N) The band matrix A, stored in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(m,j+kl).
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KL+KU+1.
[out]	R	R is DOUBLE PRECISION array, dimension (M) If INFO = 0, or INFO > M, R contains the row scale factors for A.
[out]	C	C is DOUBLE PRECISION array, dimension (N) If INFO = 0, C contains the column scale factors for A.
[out]	ROWCND	ROWCND is DOUBLE PRECISION If INFO = 0 or INFO > M, ROWCND contains the ratio of the smallest R(i) to the largest R(i). If ROWCND >= 0.1 and AMAX is neither too large nor too small, it is not worth scaling by R.
[out]	COLCND	COLCND is DOUBLE PRECISION If INFO = 0, COLCND contains the ratio of the smallest C(i) to the largest C(i). If COLCND >= 0.1, it is not worth scaling by C.
[out]	AMAX	AMAX is DOUBLE PRECISION Absolute value of largest matrix element. If AMAX is very close to overflow or very close to underflow, the matrix should be scaled.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, and i is <= M: the i-th row of A is exactly zero > M: the (i-M)-th column of A is exactly zero

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 156 of file zgbequ.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, kl, ku, ldab, m, n
      DOUBLE PRECISION   amax, colcnd, rowcnd
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   c( * ), r( * )
      COMPLEX*16         ab( ldab, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, kd
      DOUBLE PRECISION   bignum, rcmax, rcmin, smlnum
      COMPLEX*16         zdum
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 ) THEN
         info = -3
      ELSE IF( ku.LT.0 ) THEN
         info = -4
      ELSE IF( ldab.LT.kl+ku+1 ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGBEQU', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         rowcnd = one
         colcnd = one
         amax = zero
         RETURN
      END IF
*
*     Get machine constants.
*
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
*
*     Compute row scale factors.
*
      DO 10 i = 1, m
         r( i ) = zero
   10 CONTINUE
*
*     Find the maximum element in each row.
*
      kd = ku + 1
      DO 30 j = 1, n
         DO 20 i = max( j-ku, 1 ), min( j+kl, m )
            r( i ) = max( r( i ), cabs1( ab( kd+i-j, j ) ) )
   20    CONTINUE
   30 CONTINUE
*
*     Find the maximum and minimum scale factors.
*
      rcmin = bignum
      rcmax = zero
      DO 40 i = 1, m
         rcmax = max( rcmax, r( i ) )
         rcmin = min( rcmin, r( i ) )
   40 CONTINUE
      amax = rcmax
*
      IF( rcmin.EQ.zero ) THEN
*
*        Find the first zero scale factor and return an error code.
*
         DO 50 i = 1, m
            IF( r( i ).EQ.zero ) THEN
               info = i
               RETURN
            END IF
   50    CONTINUE
      ELSE
*
*        Invert the scale factors.
*
         DO 60 i = 1, m
            r( i ) = one / min( max( r( i ), smlnum ), bignum )
   60    CONTINUE
*
*        Compute ROWCND = min(R(I)) / max(R(I))
*
         rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
      END IF
*
*     Compute column scale factors
*
      DO 70 j = 1, n
         c( j ) = zero
   70 CONTINUE
*
*     Find the maximum element in each column,
*     assuming the row scaling computed above.
*
      kd = ku + 1
      DO 90 j = 1, n
         DO 80 i = max( j-ku, 1 ), min( j+kl, m )
            c( j ) = max( c( j ), cabs1( ab( kd+i-j, j ) )*r( i ) )
   80    CONTINUE
   90 CONTINUE
*
*     Find the maximum and minimum scale factors.
*
      rcmin = bignum
      rcmax = zero
      DO 100 j = 1, n
         rcmin = min( rcmin, c( j ) )
         rcmax = max( rcmax, c( j ) )
  100 CONTINUE
*
      IF( rcmin.EQ.zero ) THEN
*
*        Find the first zero scale factor and return an error code.
*
         DO 110 j = 1, n
            IF( c( j ).EQ.zero ) THEN
               info = m + j
               RETURN
            END IF
  110    CONTINUE
      ELSE
*
*        Invert the scale factors.
*
         DO 120 j = 1, n
            c( j ) = one / min( max( c( j ), smlnum ), bignum )
  120    CONTINUE
*
*        Compute COLCND = min(C(J)) / max(C(J))
*
         colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
      END IF
*
      RETURN
*
*     End of ZGBEQU
*

Here is the call graph for this function:

Here is the caller graph for this function: