LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine zgtsv ( integer  N,
integer  NRHS,
complex*16, dimension( * )  DL,
complex*16, dimension( * )  D,
complex*16, dimension( * )  DU,
complex*16, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

ZGTSV computes the solution to system of linear equations A * X = B for GT matrices

Download ZGTSV + dependencies [TGZ] [ZIP] [TXT]

Purpose: 
 ZGTSV  solves the equation

    A*X = B,

 where A is an N-by-N tridiagonal matrix, by Gaussian elimination with
 partial pivoting.

 Note that the equation  A**T *X = B  may be solved by interchanging the
 order of the arguments DU and DL.
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in,out]DL
          DL is COMPLEX*16 array, dimension (N-1)
          On entry, DL must contain the (n-1) subdiagonal elements of
          A.
          On exit, DL is overwritten by the (n-2) elements of the
          second superdiagonal of the upper triangular matrix U from
          the LU factorization of A, in DL(1), ..., DL(n-2).
[in,out]D
          D is COMPLEX*16 array, dimension (N)
          On entry, D must contain the diagonal elements of A.
          On exit, D is overwritten by the n diagonal elements of U.
[in,out]DU
          DU is COMPLEX*16 array, dimension (N-1)
          On entry, DU must contain the (n-1) superdiagonal elements
          of A.
          On exit, DU is overwritten by the (n-1) elements of the first
          superdiagonal of U.
[in,out]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
          On entry, the N-by-NRHS right hand side matrix B.
          On exit, if INFO = 0, the N-by-NRHS solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, U(i,i) is exactly zero, and the solution
                has not been computed.  The factorization has not been
                completed unless i = N.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 126 of file zgtsv.f.

126 *
127 * -- LAPACK driver routine (version 3.4.2) --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 * September 2012
131 *
132 * .. Scalar Arguments ..
133  INTEGER info, ldb, n, nrhs
134 * ..
135 * .. Array Arguments ..
136  COMPLEX*16 b( ldb, * ), d( * ), dl( * ), du( * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  COMPLEX*16 zero
143  parameter ( zero = ( 0.0d+0, 0.0d+0 ) )
144 * ..
145 * .. Local Scalars ..
146  INTEGER j, k
147  COMPLEX*16 mult, temp, zdum
148 * ..
149 * .. Intrinsic Functions ..
150  INTRINSIC abs, dble, dimag, max
151 * ..
152 * .. External Subroutines ..
153  EXTERNAL xerbla
154 * ..
155 * .. Statement Functions ..
156  DOUBLE PRECISION cabs1
157 * ..
158 * .. Statement Function definitions ..
159  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
160 * ..
161 * .. Executable Statements ..
162 *
163  info = 0
164  IF( n.LT.0 ) THEN
165  info = -1
166  ELSE IF( nrhs.LT.0 ) THEN
167  info = -2
168  ELSE IF( ldb.LT.max( 1, n ) ) THEN
169  info = -7
170  END IF
171  IF( info.NE.0 ) THEN
172  CALL xerbla( 'ZGTSV ', -info )
173  RETURN
174  END IF
175 *
176  IF( n.EQ.0 )
177  $ RETURN
178 *
179  DO 30 k = 1, n - 1
180  IF( dl( k ).EQ.zero ) THEN
181 *
182 * Subdiagonal is zero, no elimination is required.
183 *
184  IF( d( k ).EQ.zero ) THEN
185 *
186 * Diagonal is zero: set INFO = K and return; a unique
187 * solution can not be found.
188 *
189  info = k
190  RETURN
191  END IF
192  ELSE IF( cabs1( d( k ) ).GE.cabs1( dl( k ) ) ) THEN
193 *
194 * No row interchange required
195 *
196  mult = dl( k ) / d( k )
197  d( k+1 ) = d( k+1 ) - mult*du( k )
198  DO 10 j = 1, nrhs
199  b( k+1, j ) = b( k+1, j ) - mult*b( k, j )
200  10 CONTINUE
201  IF( k.LT.( n-1 ) )
202  $ dl( k ) = zero
203  ELSE
204 *
205 * Interchange rows K and K+1
206 *
207  mult = d( k ) / dl( k )
208  d( k ) = dl( k )
209  temp = d( k+1 )
210  d( k+1 ) = du( k ) - mult*temp
211  IF( k.LT.( n-1 ) ) THEN
212  dl( k ) = du( k+1 )
213  du( k+1 ) = -mult*dl( k )
214  END IF
215  du( k ) = temp
216  DO 20 j = 1, nrhs
217  temp = b( k, j )
218  b( k, j ) = b( k+1, j )
219  b( k+1, j ) = temp - mult*b( k+1, j )
220  20 CONTINUE
221  END IF
222  30 CONTINUE
223  IF( d( n ).EQ.zero ) THEN
224  info = n
225  RETURN
226  END IF
227 *
228 * Back solve with the matrix U from the factorization.
229 *
230  DO 50 j = 1, nrhs
231  b( n, j ) = b( n, j ) / d( n )
232  IF( n.GT.1 )
233  $ b( n-1, j ) = ( b( n-1, j )-du( n-1 )*b( n, j ) ) / d( n-1 )
234  DO 40 k = n - 2, 1, -1
235  b( k, j ) = ( b( k, j )-du( k )*b( k+1, j )-dl( k )*
236  $ b( k+2, j ) ) / d( k )
237  40 CONTINUE
238  50 CONTINUE
239 *
240  RETURN
241 *
242 * End of ZGTSV
243 *
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62

Here is the call graph for this function:

Here is the caller graph for this function: