subroutine shst01	(	integer	N,
		integer	ILO,
		integer	IHI,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( ldh, * )	H,
		integer	LDH,
		real, dimension( ldq, * )	Q,
		integer	LDQ,
		real, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( 2 )	RESULT
	)

SHST01

Purpose:

 SHST01 tests the reduction of a general matrix A to upper Hessenberg
 form:  A = Q*H*Q'.  Two test ratios are computed;

 RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
 RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

 The matrix Q is assumed to be given explicitly as it would be
 following SGEHRD + SORGHR.

 In this version, ILO and IHI are not used and are assumed to be 1 and
 N, respectively.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	ILO	ILO is INTEGER
[in]	IHI	IHI is INTEGER A is assumed to be upper triangular in rows and columns 1:ILO-1 and IHI+1:N, so Q differs from the identity only in rows and columns ILO+1:IHI.
[in]	A	A is REAL array, dimension (LDA,N) The original n by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	H	H is REAL array, dimension (LDH,N) The upper Hessenberg matrix H from the reduction A = Q*H*Q' as computed by SGEHRD. H is assumed to be zero below the first subdiagonal.
[in]	LDH	LDH is INTEGER The leading dimension of the array H. LDH >= max(1,N).
[in]	Q	Q is REAL array, dimension (LDQ,N) The orthogonal matrix Q from the reduction A = Q*H*Q' as computed by SGEHRD + SORGHR.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= 2*N*N.
[out]	RESULT	RESULT is REAL array, dimension (2) RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 136 of file shst01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            ihi, ilo, lda, ldh, ldq, lwork, n
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), h( ldh, * ), q( ldq, * ),
     $                   result( 2 ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            ldwork
      REAL               anorm, eps, ovfl, smlnum, unfl, wnorm
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slabad, slacpy, sort01
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      unfl = slamch( 'Safe minimum' )
      eps = slamch( 'Precision' )
      ovfl = one / unfl
      CALL slabad( unfl, ovfl )
      smlnum = unfl*n / eps
*
*     Test 1:  Compute norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*
*     Copy A to WORK
*
      ldwork = max( 1, n )
      CALL slacpy( ' ', n, n, a, lda, work, ldwork )
*
*     Compute Q*H
*
      CALL sgemm( 'No transpose', 'No transpose', n, n, n, one, q, ldq,
     $            h, ldh, zero, work( ldwork*n+1 ), ldwork )
*
*     Compute A - Q*H*Q'
*
      CALL sgemm( 'No transpose', 'Transpose', n, n, n, -one,
     $            work( ldwork*n+1 ), ldwork, q, ldq, one, work,
     $            ldwork )
*
      anorm = max( slange( '1', n, n, a, lda, work( ldwork*n+1 ) ),
     $        unfl )
      wnorm = slange( '1', n, n, work, ldwork, work( ldwork*n+1 ) )
*
*     Note that RESULT(1) cannot overflow and is bounded by 1/(N*EPS)
*
      result( 1 ) = min( wnorm, anorm ) / max( smlnum, anorm*eps ) / n
*
*     Test 2:  Compute norm( I - Q'*Q ) / ( N * EPS )
*
      CALL sort01( 'Columns', n, n, q, ldq, work, lwork, result( 2 ) )
*
      RETURN
*
*     End of SHST01
*

Here is the call graph for this function:

Here is the caller graph for this function: