subroutine sbdt02	(	integer	M,
		integer	N,
		real, dimension( ldb, * )	B,
		integer	LDB,
		real, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( ldu, * )	U,
		integer	LDU,
		real, dimension( * )	WORK,
		real	RESID
	)

SBDT02

Purpose:

 SBDT02 tests the change of basis C = U' * B by computing the residual

    RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),

 where B and C are M by N matrices, U is an M by M orthogonal matrix,
 and EPS is the machine precision.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices B and C and the order of the matrix Q.
[in]	N	N is INTEGER The number of columns of the matrices B and C.
[in]	B	B is REAL array, dimension (LDB,N) The m by n matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[in]	C	C is REAL array, dimension (LDC,N) The m by n matrix C, assumed to contain U' * B.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).
[in]	U	U is REAL array, dimension (LDU,M) The m by m orthogonal matrix U.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M).
[out]	WORK	WORK is REAL array, dimension (M)
[out]	RESID	RESID is REAL RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 113 of file sbdt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            ldb, ldc, ldu, m, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      REAL               b( ldb, * ), c( ldc, * ), u( ldu, * ),
     $                   work( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            j
      REAL               bnorm, eps, realmn
*     ..
*     .. External Functions ..
      REAL               sasum, slamch, slange
      EXTERNAL           sasum, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           scopy, sgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      resid = zero
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
      realmn = REAL( MAX( M, N ) )
      eps = slamch( 'Precision' )
*
*     Compute norm( B - U * C )
*
      DO 10 j = 1, n
         CALL scopy( m, b( 1, j ), 1, work, 1 )
         CALL sgemv( 'No transpose', m, m, -one, u, ldu, c( 1, j ), 1,
     $               one, work, 1 )
         resid = max( resid, sasum( m, work, 1 ) )
   10 CONTINUE
*
*     Compute norm of B.
*
      bnorm = slange( '1', m, n, b, ldb, work )
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( realmn*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, realmn*bnorm ) / bnorm ) /
     $                 ( realmn*eps )
            ELSE
               resid = min( resid / bnorm, realmn ) / ( realmn*eps )
            END IF
         END IF
      END IF
      RETURN
*
*     End of SBDT02
*

Here is the call graph for this function:

Here is the caller graph for this function: