subroutine sckcsd	(	integer	NM,
		integer, dimension( * )	MVAL,
		integer, dimension( * )	PVAL,
		integer, dimension( * )	QVAL,
		integer	NMATS,
		integer, dimension( 4 )	ISEED,
		real	THRESH,
		integer	MMAX,
		real, dimension( * )	X,
		real, dimension( * )	XF,
		real, dimension( * )	U1,
		real, dimension( * )	U2,
		real, dimension( * )	V1T,
		real, dimension( * )	V2T,
		real, dimension( * )	THETA,
		integer, dimension( * )	IWORK,
		real, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		integer	NIN,
		integer	NOUT,
		integer	INFO
	)

SCKCSD

Purpose:

 SCKCSD tests SORCSD:
        the CSD for an M-by-M orthogonal matrix X partitioned as
        [ X11 X12; X21 X22 ]. X11 is P-by-Q.

Parameters

[in]	NM	NM is INTEGER The number of values of M contained in the vector MVAL.
[in]	MVAL	MVAL is INTEGER array, dimension (NM) The values of the matrix row dimension M.
[in]	PVAL	PVAL is INTEGER array, dimension (NM) The values of the matrix row dimension P.
[in]	QVAL	QVAL is INTEGER array, dimension (NM) The values of the matrix column dimension Q.
[in]	NMATS	NMATS is INTEGER The number of matrix types to be tested for each combination of matrix dimensions. If NMATS >= NTYPES (the maximum number of matrix types), then all the different types are generated for testing. If NMATS < NTYPES, another input line is read to get the numbers of the matrix types to be used.
[in,out]	ISEED	ISEED is INTEGER array, dimension (4) On entry, the seed of the random number generator. The array elements should be between 0 and 4095, otherwise they will be reduced mod 4096, and ISEED(4) must be odd. On exit, the next seed in the random number sequence after all the test matrices have been generated.
[in]	THRESH	THRESH is REAL The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	MMAX	MMAX is INTEGER The maximum value permitted for M, used in dimensioning the work arrays.
[out]	X	X is REAL array, dimension (MMAX*MMAX)
[out]	XF	XF is REAL array, dimension (MMAX*MMAX)
[out]	U1	U1 is REAL array, dimension (MMAX*MMAX)
[out]	U2	U2 is REAL array, dimension (MMAX*MMAX)
[out]	V1T	V1T is REAL array, dimension (MMAX*MMAX)
[out]	V2T	V2T is REAL array, dimension (MMAX*MMAX)
[out]	THETA	THETA is REAL array, dimension (MMAX)
[out]	IWORK	IWORK is INTEGER array, dimension (MMAX)
[out]	WORK	WORK is REAL array
[out]	RWORK	RWORK is REAL array
[in]	NIN	NIN is INTEGER The unit number for input.
[in]	NOUT	NOUT is INTEGER The unit number for output.
[out]	INFO	INFO is INTEGER = 0 : successful exit > 0 : If SLAROR returns an error code, the absolute value of it is returned.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 186 of file sckcsd.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, nin, nm, nmats, mmax, nout
      REAL               thresh
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 ), iwork( * ), mval( * ), pval( * ),
     $                   qval( * )
      REAL               rwork( * ), theta( * )
      REAL               u1( * ), u2( * ), v1t( * ), v2t( * ),
     $                   work( * ), x( * ), xf( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ntests
      parameter                ( ntests = 15 )
      INTEGER            ntypes
      parameter                ( ntypes = 4 )
      REAL               gapdigit, one, orth, piover2, ten, zero
      parameter                ( gapdigit = 10.0e0, one = 1.0e0,
     $                     orth = 1.0e-4,
     $                     piover2 = 1.57079632679489662e0,
     $                     ten = 10.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            firstt
      CHARACTER*3        path
      INTEGER            i, iinfo, im, imat, j, ldu1, ldu2, ldv1t,
     $                   ldv2t, ldx, lwork, m, nfail, nrun, nt, p, q, r
*     ..
*     .. Local Arrays ..
      LOGICAL            dotype( ntypes )
      REAL               result( ntests )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahdg, alareq, alasum, scsdts, slacsg, slaror,
     $                   slaset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, min
*     ..
*     .. External Functions ..
      REAL               slaran, slarnd
      EXTERNAL           slaran, slarnd
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 3 ) = 'CSD'
      info = 0
      nrun = 0
      nfail = 0
      firstt = .true.
      CALL alareq( path, nmats, dotype, ntypes, nin, nout )
      ldx = mmax
      ldu1 = mmax
      ldu2 = mmax
      ldv1t = mmax
      ldv2t = mmax
      lwork = mmax*mmax
*
*     Do for each value of M in MVAL.
*
      DO 30 im = 1, nm
         m = mval( im )
         p = pval( im )
         q = qval( im )
*
         DO 20 imat = 1, ntypes
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 20
*
*           Generate X
*
            IF( imat.EQ.1 ) THEN
               CALL slaror( 'L', 'I', m, m, x, ldx, iseed, work, iinfo )
               IF( m .NE. 0 .AND. iinfo .NE. 0 ) THEN
                  WRITE( nout, fmt = 9999 ) m, iinfo
                  info = abs( iinfo )
                  GO TO 20
               END IF
            ELSE IF( imat.EQ.2 ) THEN
               r = min( p, m-p, q, m-q )
               DO i = 1, r
                  theta(i) = piover2 * slarnd( 1, iseed )
               END DO
               CALL slacsg( m, p, q, theta, iseed, x, ldx, work )
               DO i = 1, m
                  DO j = 1, m
                     x(i+(j-1)*ldx) = x(i+(j-1)*ldx) +
     $                                orth*slarnd(2,iseed)
                  END DO
               END DO
            ELSE IF( imat.EQ.3 ) THEN
               r = min( p, m-p, q, m-q )
               DO i = 1, r+1
                  theta(i) = ten**(-slarnd(1,iseed)*gapdigit)
               END DO
               DO i = 2, r+1
                  theta(i) = theta(i-1) + theta(i)
               END DO
               DO i = 1, r
                  theta(i) = piover2 * theta(i) / theta(r+1)
               END DO
               CALL slacsg( m, p, q, theta, iseed, x, ldx, work )
            ELSE
               CALL slaset( 'F', m, m, zero, one, x, ldx )
               DO i = 1, m
                  j = int( slaran( iseed ) * m ) + 1
                  IF( j .NE. i ) THEN
                     CALL srot( m, x(1+(i-1)*ldx), 1, x(1+(j-1)*ldx), 1,
     $                 zero, one )
                  END IF
               END DO
            END IF
*
            nt = 15
*
            CALL scsdts( m, p, q, x, xf, ldx, u1, ldu1, u2, ldu2, v1t,
     $                   ldv1t, v2t, ldv2t, theta, iwork, work, lwork,
     $                   rwork, result )
*
*           Print information about the tests that did not
*           pass the threshold.
*
            DO 10 i = 1, nt
               IF( result( i ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. firstt ) THEN
                     firstt = .false.
                     CALL alahdg( nout, path )
                  END IF
                  WRITE( nout, fmt = 9998 )m, p, q, imat, i,
     $               result( i )
                  nfail = nfail + 1
               END IF
   10       CONTINUE
            nrun = nrun + nt
   20    CONTINUE
   30 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, 0 )
*
 9999 FORMAT( ' SLAROR in SCKCSD: M = ', i5, ', INFO = ', i15 )
 9998 FORMAT( ' M=', i4, ' P=', i4, ', Q=', i4, ', type ', i2,
     $      ', test ', i2, ', ratio=', g13.6 )
      RETURN
*
*     End of SCKCSD
*

Here is the call graph for this function:

Here is the caller graph for this function: