subroutine zlaswp	(	integer	N,
		complex16, dimension( lda, )	A,
		integer	LDA,
		integer	K1,
		integer	K2,
		integer, dimension( * )	IPIV,
		integer	INCX
	)

ZLASWP performs a series of row interchanges on a general rectangular matrix.

Download ZLASWP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLASWP performs a series of row interchanges on the matrix A.
 One row interchange is initiated for each of rows K1 through K2 of A.

Parameters

[in]	N	N is INTEGER The number of columns of the matrix A.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the matrix of column dimension N to which the row interchanges will be applied. On exit, the permuted matrix.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	K1	K1 is INTEGER The first element of IPIV for which a row interchange will be done.
[in]	K2	K2 is INTEGER The last element of IPIV for which a row interchange will be done.
[in]	IPIV	IPIV is INTEGER array, dimension (K2*abs(INCX)) The vector of pivot indices. Only the elements in positions K1 through K2 of IPIV are accessed. IPIV(K) = L implies rows K and L are to be interchanged.
[in]	INCX	INCX is INTEGER The increment between successive values of IPIV. If IPIV is negative, the pivots are applied in reverse order.

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Date: September 2012

Further Details:

  Modified by
   R. C. Whaley, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Definition at line 116 of file zlaswp.f.

 *
 *  -- LAPACK auxiliary routine (version 3.4.2) --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *     September 2012
 *
 *     .. Scalar Arguments ..
       INTEGER            incx, k1, k2, lda, n
 *     ..
 *     .. Array Arguments ..
       INTEGER            ipiv( * )
       COMPLEX*16         a( lda, * )
 *     ..
 *
 * =====================================================================
 *
 *     .. Local Scalars ..
       INTEGER            i, i1, i2, inc, ip, ix, ix0, j, k, n32
       COMPLEX*16         temp
 *     ..
 *     .. Executable Statements ..
 *
 *     Interchange row I with row IPIV(I) for each of rows K1 through K2.
 *
       IF( incx.GT.0 ) THEN
          ix0 = k1
          i1 = k1
          i2 = k2
          inc = 1
       ELSE IF( incx.LT.0 ) THEN
          ix0 = 1 + ( 1-k2 )*incx
          i1 = k2
          i2 = k1
          inc = -1
       ELSE
          RETURN
       END IF
 *
       n32 = ( n / 32 )*32
       IF( n32.NE.0 ) THEN
          DO 30 j = 1, n32, 32
             ix = ix0
             DO 20 i = i1, i2, inc
                ip = ipiv( ix )
                IF( ip.NE.i ) THEN
                   DO 10 k = j, j + 31
                      temp = a( i, k )
                      a( i, k ) = a( ip, k )
                      a( ip, k ) = temp
    10             CONTINUE
                END IF
                ix = ix + incx
    20       CONTINUE
    30    CONTINUE
       END IF
       IF( n32.NE.n ) THEN
          n32 = n32 + 1
          ix = ix0
          DO 50 i = i1, i2, inc
             ip = ipiv( ix )
             IF( ip.NE.i ) THEN
                DO 40 k = n32, n
                   temp = a( i, k )
                   a( i, k ) = a( ip, k )
                   a( ip, k ) = temp
    40          CONTINUE
             END IF
             ix = ix + incx
    50    CONTINUE
       END IF
 *
       RETURN
 *
 *     End of ZLASWP
 *

Here is the caller graph for this function: