subroutine zlauu2	(	character	UPLO,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		integer	INFO
	)

ZLAUU2 computes the product UUH or LHL, where U and L are upper or lower triangular matrices (unblocked algorithm).

Download ZLAUU2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAUU2 computes the product U * U**H or L**H * L, where the triangular
 factor U or L is stored in the upper or lower triangular part of
 the array A.

 If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
 overwriting the factor U in A.
 If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
 overwriting the factor L in A.

 This is the unblocked form of the algorithm, calling Level 2 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the triangular factor stored in the array A is upper or lower triangular: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the triangular factor U or L. N >= 0.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the triangular factor U or L. On exit, if UPLO = 'U', the upper triangle of A is overwritten with the upper triangle of the product U * U**H; if UPLO = 'L', the lower triangle of A is overwritten with the lower triangle of the product L**H * L.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 104 of file zlauu2.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         one
      parameter                ( one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            i
      DOUBLE PRECISION   aii
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      COMPLEX*16         zdotc
      EXTERNAL           lsame, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdscal, zgemv, zlacgv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZLAUU2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the product U * U**H.
*
         DO 10 i = 1, n
            aii = a( i, i )
            IF( i.LT.n ) THEN
               a( i, i ) = aii*aii + dble( zdotc( n-i, a( i, i+1 ), lda,
     $                     a( i, i+1 ), lda ) )
               CALL zlacgv( n-i, a( i, i+1 ), lda )
               CALL zgemv( 'No transpose', i-1, n-i, one, a( 1, i+1 ),
     $                     lda, a( i, i+1 ), lda, dcmplx( aii ),
     $                     a( 1, i ), 1 )
               CALL zlacgv( n-i, a( i, i+1 ), lda )
            ELSE
               CALL zdscal( i, aii, a( 1, i ), 1 )
            END IF
   10    CONTINUE
*
      ELSE
*
*        Compute the product L**H * L.
*
         DO 20 i = 1, n
            aii = a( i, i )
            IF( i.LT.n ) THEN
               a( i, i ) = aii*aii + dble( zdotc( n-i, a( i+1, i ), 1,
     $                     a( i+1, i ), 1 ) )
               CALL zlacgv( i-1, a( i, 1 ), lda )
               CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
     $                     a( i+1, 1 ), lda, a( i+1, i ), 1,
     $                     dcmplx( aii ), a( i, 1 ), lda )
               CALL zlacgv( i-1, a( i, 1 ), lda )
            ELSE
               CALL zdscal( i, aii, a( i, 1 ), lda )
            END IF
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of ZLAUU2
*

Here is the call graph for this function:

Here is the caller graph for this function: