sgetrf.f

Go to the documentation of this file.

C> \brief \b SGETRF VARIANT: Crout Level 3 BLAS version of the algorithm.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SGETRF ( M, N, A, LDA, IPIV, INFO)
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, M, N
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       REAL               A( LDA, * )
*       ..
*  
*  Purpose
*  =======
*
C>\details \b Purpose:
C>\verbatim
C>
C> SGETRF computes an LU factorization of a general M-by-N matrix A
C> using partial pivoting with row interchanges.
C>
C> The factorization has the form
C>    A = P * L * U
C> where P is a permutation matrix, L is lower triangular with unit
C> diagonal elements (lower trapezoidal if m > n), and U is upper
C> triangular (upper trapezoidal if m < n).
C>
C> This is the Crout Level 3 BLAS version of the algorithm.
C>
C>\endverbatim
*
*  Arguments:
*  ==========
*
C> \param[in] M
C> \verbatim
C>          M is INTEGER
C>          The number of rows of the matrix A.  M >= 0.
C> \endverbatim
C>
C> \param[in] N
C> \verbatim
C>          N is INTEGER
C>          The number of columns of the matrix A.  N >= 0.
C> \endverbatim
C>
C> \param[in,out] A
C> \verbatim
C>          A is REAL array, dimension (LDA,N)
C>          On entry, the M-by-N matrix to be factored.
C>          On exit, the factors L and U from the factorization
C>          A = P*L*U; the unit diagonal elements of L are not stored.
C> \endverbatim
C>
C> \param[in] LDA
C> \verbatim
C>          LDA is INTEGER
C>          The leading dimension of the array A.  LDA >= max(1,M).
C> \endverbatim
C>
C> \param[out] IPIV
C> \verbatim
C>          IPIV is INTEGER array, dimension (min(M,N))
C>          The pivot indices; for 1 <= i <= min(M,N), row i of the
C>          matrix was interchanged with row IPIV(i).
C> \endverbatim
C>
C> \param[out] INFO
C> \verbatim
C>          INFO is INTEGER
C>          = 0:  successful exit
C>          < 0:  if INFO = -i, the i-th argument had an illegal value
C>          > 0:  if INFO = i, U(i,i) is exactly zero. The factorization
C>                has been completed, but the factor U is exactly
C>                singular, and division by zero will occur if it is used
C>                to solve a system of equations.
C> \endverbatim
C>
*
*  Authors:
*  ========
*
C> \author Univ. of Tennessee 
C> \author Univ. of California Berkeley 
C> \author Univ. of Colorado Denver 
C> \author NAG Ltd. 
*
C> \date November 2011
*
C> \ingroup variantsGEcomputational
*
*  =====================================================================
      SUBROUTINE sgetrf ( M, N, A, LDA, IPIV, INFO)
*
*  -- LAPACK computational routine (version 3.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               A( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter                ( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IINFO, J, JB, NB
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, sgetf2, slaswp, strsm, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      EXTERNAL           ilaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGETRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'SGETRF', ' ', m, n, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.min( m, n ) ) THEN
*
*        Use unblocked code.
*
         CALL sgetf2( m, n, a, lda, ipiv, info )
      ELSE
*
*        Use blocked code.
*
         DO 20 j = 1, min( m, n ), nb
            jb = min( min( m, n )-j+1, nb )
*
*           Update current block.
*
            CALL sgemm( 'No transpose', 'No transpose', 
     $                 m-j+1, jb, j-1, -one, 
     $                 a( j, 1 ), lda, a( 1, j ), lda, one,
     $                 a( j, j ), lda )
            
*
*           Factor diagonal and subdiagonal blocks and test for exact
*           singularity.
*
            CALL sgetf2( m-j+1, jb, a( j, j ), lda, ipiv( j ), iinfo )
*
*           Adjust INFO and the pivot indices.
*
            IF( info.EQ.0 .AND. iinfo.GT.0 )
     $         info = iinfo + j - 1
            DO 10 i = j, min( m, j+jb-1 )
               ipiv( i ) = j - 1 + ipiv( i )
   10       CONTINUE
*            
*           Apply interchanges to column 1:J-1            
*
            CALL slaswp( j-1, a, lda, j, j+jb-1, ipiv, 1 )
*
            IF ( j+jb.LE.n ) THEN
*            
*              Apply interchanges to column J+JB:N            
*
               CALL slaswp( n-j-jb+1, a( 1, j+jb ), lda, j, j+jb-1, 
     $                     ipiv, 1 )
*               
               CALL sgemm( 'No transpose', 'No transpose', 
     $                    jb, n-j-jb+1, j-1, -one, 
     $                    a( j, 1 ), lda, a( 1, j+jb ), lda, one,
     $                    a( j, j+jb ), lda )
*
*              Compute block row of U.
*
               CALL strsm( 'Left', 'Lower', 'No transpose', 'Unit',
     $                    jb, n-j-jb+1, one, a( j, j ), lda, 
     $                    a( j, j+jb ), lda )
            END IF

   20    CONTINUE

      END IF
      RETURN
*
*     End of SGETRF
*
      END