LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine zggsvd3 ( character JOBU, character JOBV, character JOBQ, integer M, integer N, integer P, integer K, integer L, complex*16, dimension( lda, * ) A, integer LDA, complex*16, dimension( ldb, * ) B, integer LDB, double precision, dimension( * ) ALPHA, double precision, dimension( * ) BETA, complex*16, dimension( ldu, * ) U, integer LDU, complex*16, dimension( ldv, * ) V, integer LDV, complex*16, dimension( ldq, * ) Q, integer LDQ, complex*16, dimension( * ) WORK, integer LWORK, double precision, dimension( * ) RWORK, integer, dimension( * ) IWORK, integer INFO )

ZGGSVD3 computes the singular value decomposition (SVD) for OTHER matrices

Download ZGGSVD3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` ZGGSVD3 computes the generalized singular value decomposition (GSVD)
of an M-by-N complex matrix A and P-by-N complex matrix B:

U**H*A*Q = D1*( 0 R ),    V**H*B*Q = D2*( 0 R )

where U, V and Q are unitary matrices.
Let K+L = the effective numerical rank of the
matrix (A**H,B**H)**H, then R is a (K+L)-by-(K+L) nonsingular upper
triangular matrix, D1 and D2 are M-by-(K+L) and P-by-(K+L) "diagonal"
matrices and of the following structures, respectively:

If M-K-L >= 0,

K  L
D1 =     K ( I  0 )
L ( 0  C )
M-K-L ( 0  0 )

K  L
D2 =   L ( 0  S )
P-L ( 0  0 )

N-K-L  K    L
( 0 R ) = K (  0   R11  R12 )
L (  0    0   R22 )
where

C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
S = diag( BETA(K+1),  ... , BETA(K+L) ),
C**2 + S**2 = I.

R is stored in A(1:K+L,N-K-L+1:N) on exit.

If M-K-L < 0,

K M-K K+L-M
D1 =   K ( I  0    0   )
M-K ( 0  C    0   )

K M-K K+L-M
D2 =   M-K ( 0  S    0  )
K+L-M ( 0  0    I  )
P-L ( 0  0    0  )

N-K-L  K   M-K  K+L-M
( 0 R ) =     K ( 0    R11  R12  R13  )
M-K ( 0     0   R22  R23  )
K+L-M ( 0     0    0   R33  )

where

C = diag( ALPHA(K+1), ... , ALPHA(M) ),
S = diag( BETA(K+1),  ... , BETA(M) ),
C**2 + S**2 = I.

(R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N), and R33 is stored
( 0  R22 R23 )
in B(M-K+1:L,N+M-K-L+1:N) on exit.

The routine computes C, S, R, and optionally the unitary
transformation matrices U, V and Q.

In particular, if B is an N-by-N nonsingular matrix, then the GSVD of
A and B implicitly gives the SVD of A*inv(B):
A*inv(B) = U*(D1*inv(D2))*V**H.
If ( A**H,B**H)**H has orthonormal columns, then the GSVD of A and B is also
equal to the CS decomposition of A and B. Furthermore, the GSVD can
be used to derive the solution of the eigenvalue problem:
A**H*A x = lambda* B**H*B x.
In some literature, the GSVD of A and B is presented in the form
U**H*A*X = ( 0 D1 ),   V**H*B*X = ( 0 D2 )
where U and V are orthogonal and X is nonsingular, and D1 and D2 are
``diagonal''.  The former GSVD form can be converted to the latter
form by taking the nonsingular matrix X as

X = Q*(  I   0    )
(  0 inv(R) )```
Parameters
 [in] JOBU ``` JOBU is CHARACTER*1 = 'U': Unitary matrix U is computed; = 'N': U is not computed.``` [in] JOBV ``` JOBV is CHARACTER*1 = 'V': Unitary matrix V is computed; = 'N': V is not computed.``` [in] JOBQ ``` JOBQ is CHARACTER*1 = 'Q': Unitary matrix Q is computed; = 'N': Q is not computed.``` [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrices A and B. N >= 0.``` [in] P ``` P is INTEGER The number of rows of the matrix B. P >= 0.``` [out] K ` K is INTEGER` [out] L ``` L is INTEGER On exit, K and L specify the dimension of the subblocks described in Purpose. K + L = effective numerical rank of (A**H,B**H)**H.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, A contains the triangular matrix R, or part of R. See Purpose for details.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [in,out] B ``` B is COMPLEX*16 array, dimension (LDB,N) On entry, the P-by-N matrix B. On exit, B contains part of the triangular matrix R if M-K-L < 0. See Purpose for details.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,P).``` [out] ALPHA ` ALPHA is DOUBLE PRECISION array, dimension (N)` [out] BETA ``` BETA is DOUBLE PRECISION array, dimension (N) On exit, ALPHA and BETA contain the generalized singular value pairs of A and B; ALPHA(1:K) = 1, BETA(1:K) = 0, and if M-K-L >= 0, ALPHA(K+1:K+L) = C, BETA(K+1:K+L) = S, or if M-K-L < 0, ALPHA(K+1:M)=C, ALPHA(M+1:K+L)=0 BETA(K+1:M) =S, BETA(M+1:K+L) =1 and ALPHA(K+L+1:N) = 0 BETA(K+L+1:N) = 0``` [out] U ``` U is COMPLEX*16 array, dimension (LDU,M) If JOBU = 'U', U contains the M-by-M unitary matrix U. If JOBU = 'N', U is not referenced.``` [in] LDU ``` LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M) if JOBU = 'U'; LDU >= 1 otherwise.``` [out] V ``` V is COMPLEX*16 array, dimension (LDV,P) If JOBV = 'V', V contains the P-by-P unitary matrix V. If JOBV = 'N', V is not referenced.``` [in] LDV ``` LDV is INTEGER The leading dimension of the array V. LDV >= max(1,P) if JOBV = 'V'; LDV >= 1 otherwise.``` [out] Q ``` Q is COMPLEX*16 array, dimension (LDQ,N) If JOBQ = 'Q', Q contains the N-by-N unitary matrix Q. If JOBQ = 'N', Q is not referenced.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N) if JOBQ = 'Q'; LDQ >= 1 otherwise.``` [out] WORK ``` WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] RWORK ` RWORK is DOUBLE PRECISION array, dimension (2*N)` [out] IWORK ``` IWORK is INTEGER array, dimension (N) On exit, IWORK stores the sorting information. More precisely, the following loop will sort ALPHA for I = K+1, min(M,K+L) swap ALPHA(I) and ALPHA(IWORK(I)) endfor such that ALPHA(1) >= ALPHA(2) >= ... >= ALPHA(N).``` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, the Jacobi-type procedure failed to converge. For further details, see subroutine ZTGSJA.```
Internal Parameters:
```  TOLA    DOUBLE PRECISION
TOLB    DOUBLE PRECISION
TOLA and TOLB are the thresholds to determine the effective
rank of (A**H,B**H)**H. Generally, they are set to
TOLA = MAX(M,N)*norm(A)*MACHEPS,
TOLB = MAX(P,N)*norm(B)*MACHEPS.
The size of TOLA and TOLB may affect the size of backward
errors of the decomposition.```
Date
August 2015
Contributors:
Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA
Further Details:
ZGGSVD3 replaces the deprecated subroutine ZGGSVD.

Definition at line 355 of file zggsvd3.f.

355 *
356 * -- LAPACK driver routine (version 3.6.1) --
357 * -- LAPACK is a software package provided by Univ. of Tennessee, --
358 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
359 * August 2015
360 *
361 * .. Scalar Arguments ..
362  CHARACTER jobq, jobu, jobv
363  INTEGER info, k, l, lda, ldb, ldq, ldu, ldv, m, n, p,
364  \$ lwork
365 * ..
366 * .. Array Arguments ..
367  INTEGER iwork( * )
368  DOUBLE PRECISION alpha( * ), beta( * ), rwork( * )
369  COMPLEX*16 a( lda, * ), b( ldb, * ), q( ldq, * ),
370  \$ u( ldu, * ), v( ldv, * ), work( * )
371 * ..
372 *
373 * =====================================================================
374 *
375 * .. Local Scalars ..
376  LOGICAL wantq, wantu, wantv, lquery
377  INTEGER i, ibnd, isub, j, ncycle, lwkopt
378  DOUBLE PRECISION anorm, bnorm, smax, temp, tola, tolb, ulp, unfl
379 * ..
380 * .. External Functions ..
381  LOGICAL lsame
382  DOUBLE PRECISION dlamch, zlange
383  EXTERNAL lsame, dlamch, zlange
384 * ..
385 * .. External Subroutines ..
386  EXTERNAL dcopy, xerbla, zggsvp3, ztgsja
387 * ..
388 * .. Intrinsic Functions ..
389  INTRINSIC max, min
390 * ..
391 * .. Executable Statements ..
392 *
393 * Decode and test the input parameters
394 *
395  wantu = lsame( jobu, 'U' )
396  wantv = lsame( jobv, 'V' )
397  wantq = lsame( jobq, 'Q' )
398  lquery = ( lwork.EQ.-1 )
399  lwkopt = 1
400 *
401 * Test the input arguments
402 *
403  info = 0
404  IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
405  info = -1
406  ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
407  info = -2
408  ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
409  info = -3
410  ELSE IF( m.LT.0 ) THEN
411  info = -4
412  ELSE IF( n.LT.0 ) THEN
413  info = -5
414  ELSE IF( p.LT.0 ) THEN
415  info = -6
416  ELSE IF( lda.LT.max( 1, m ) ) THEN
417  info = -10
418  ELSE IF( ldb.LT.max( 1, p ) ) THEN
419  info = -12
420  ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
421  info = -16
422  ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
423  info = -18
424  ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
425  info = -20
426  ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
427  info = -24
428  END IF
429 *
430 * Compute workspace
431 *
432  IF( info.EQ.0 ) THEN
433  CALL zggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola,
434  \$ tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, rwork,
435  \$ work, work, -1, info )
436  lwkopt = n + int( work( 1 ) )
437  lwkopt = max( 2*n, lwkopt )
438  lwkopt = max( 1, lwkopt )
439  work( 1 ) = dcmplx( lwkopt )
440  END IF
441 *
442  IF( info.NE.0 ) THEN
443  CALL xerbla( 'ZGGSVD3', -info )
444  RETURN
445  END IF
446  IF( lquery ) THEN
447  RETURN
448  ENDIF
449 *
450 * Compute the Frobenius norm of matrices A and B
451 *
452  anorm = zlange( '1', m, n, a, lda, rwork )
453  bnorm = zlange( '1', p, n, b, ldb, rwork )
454 *
455 * Get machine precision and set up threshold for determining
456 * the effective numerical rank of the matrices A and B.
457 *
458  ulp = dlamch( 'Precision' )
459  unfl = dlamch( 'Safe Minimum' )
460  tola = max( m, n )*max( anorm, unfl )*ulp
461  tolb = max( p, n )*max( bnorm, unfl )*ulp
462 *
463  CALL zggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola,
464  \$ tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, rwork,
465  \$ work, work( n+1 ), lwork-n, info )
466 *
467 * Compute the GSVD of two upper "triangular" matrices
468 *
469  CALL ztgsja( jobu, jobv, jobq, m, p, n, k, l, a, lda, b, ldb,
470  \$ tola, tolb, alpha, beta, u, ldu, v, ldv, q, ldq,
471  \$ work, ncycle, info )
472 *
473 * Sort the singular values and store the pivot indices in IWORK
474 * Copy ALPHA to RWORK, then sort ALPHA in RWORK
475 *
476  CALL dcopy( n, alpha, 1, rwork, 1 )
477  ibnd = min( l, m-k )
478  DO 20 i = 1, ibnd
479 *
480 * Scan for largest ALPHA(K+I)
481 *
482  isub = i
483  smax = rwork( k+i )
484  DO 10 j = i + 1, ibnd
485  temp = rwork( k+j )
486  IF( temp.GT.smax ) THEN
487  isub = j
488  smax = temp
489  END IF
490  10 CONTINUE
491  IF( isub.NE.i ) THEN
492  rwork( k+isub ) = rwork( k+i )
493  rwork( k+i ) = smax
494  iwork( k+i ) = k + isub
495  ELSE
496  iwork( k+i ) = k + i
497  END IF
498  20 CONTINUE
499 *
500  work( 1 ) = dcmplx( lwkopt )
501  RETURN
502 *
503 * End of ZGGSVD3
504 *
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:53
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
double precision function zlange(NORM, M, N, A, LDA, WORK)
ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlange.f:117
subroutine ztgsja(JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B, LDB, TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ, WORK, NCYCLE, INFO)
ZTGSJA
Definition: ztgsja.f:381
subroutine zggsvp3(JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB, TOLA, TOLB, K, L, U, LDU, V, LDV, Q, LDQ, IWORK, RWORK, TAU, WORK, LWORK, INFO)
ZGGSVP3
Definition: zggsvp3.f:280
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: