subroutine cgetf2	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( * )	IPIV,
		integer	INFO
	)

CGETF2 computes the LU factorization of a general m-by-n matrix using partial pivoting with row interchanges (unblocked algorithm).

Download CGETF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CGETF2 computes an LU factorization of a general m-by-n matrix A
 using partial pivoting with row interchanges.

 The factorization has the form
    A = P * L * U
 where P is a permutation matrix, L is lower triangular with unit
 diagonal elements (lower trapezoidal if m > n), and U is upper
 triangular (upper trapezoidal if m < n).

 This is the right-looking Level 2 BLAS version of the algorithm.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the m by n matrix to be factored. On exit, the factors L and U from the factorization A = P*L*U; the unit diagonal elements of L are not stored.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	IPIV	IPIV is INTEGER array, dimension (min(M,N)) The pivot indices; for 1 <= i <= min(M,N), row i of the matrix was interchanged with row IPIV(i).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value > 0: if INFO = k, U(k,k) is exactly zero. The factorization has been completed, but the factor U is exactly singular, and division by zero will occur if it is used to solve a system of equations.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 110 of file cgetf2.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, m, n
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      COMPLEX            a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            one, zero
      parameter                ( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      REAL               sfmin
      INTEGER            i, j, jp
*     ..
*     .. External Functions ..
      REAL               slamch
      INTEGER            icamax
      EXTERNAL           slamch, icamax
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgeru, cscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGETF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Compute machine safe minimum
*
      sfmin = slamch('S') 
*
      DO 10 j = 1, min( m, n )
*
*        Find pivot and test for singularity.
*
         jp = j - 1 + icamax( m-j+1, a( j, j ), 1 )
         ipiv( j ) = jp
         IF( a( jp, j ).NE.zero ) THEN
*
*           Apply the interchange to columns 1:N.
*
            IF( jp.NE.j )
     $         CALL cswap( n, a( j, 1 ), lda, a( jp, 1 ), lda )
*
*           Compute elements J+1:M of J-th column.
*
            IF( j.LT.m ) THEN
               IF( abs(a( j, j )) .GE. sfmin ) THEN
                  CALL cscal( m-j, one / a( j, j ), a( j+1, j ), 1 )
               ELSE
                  DO 20 i = 1, m-j
                     a( j+i, j ) = a( j+i, j ) / a( j, j )
   20             CONTINUE
               END IF
            END IF
*
         ELSE IF( info.EQ.0 ) THEN
*
            info = j
         END IF
*
         IF( j.LT.min( m, n ) ) THEN
*
*           Update trailing submatrix.
*
            CALL cgeru( m-j, n-j, -one, a( j+1, j ), 1, a( j, j+1 ),
     $                  lda, a( j+1, j+1 ), lda )
         END IF
   10 CONTINUE
      RETURN
*
*     End of CGETF2
*

Here is the call graph for this function:

Here is the caller graph for this function: