subroutine zpbstf	(	character	UPLO,
		integer	N,
		integer	KD,
		complex*16, dimension( ldab, * )	AB,
		integer	LDAB,
		integer	INFO
	)

ZPBSTF

Download ZPBSTF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZPBSTF computes a split Cholesky factorization of a complex
 Hermitian positive definite band matrix A.

 This routine is designed to be used in conjunction with ZHBGST.

 The factorization has the form  A = S**H*S  where S is a band matrix
 of the same bandwidth as A and the following structure:

   S = ( U    )
       ( M  L )

 where U is upper triangular of order m = (n+kd)/2, and L is lower
 triangular of order n-m.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of superdiagonals of the matrix A if UPLO = 'U', or the number of subdiagonals if UPLO = 'L'. KD >= 0.
[in,out]	AB	AB is COMPLEX*16 array, dimension (LDAB,N) On entry, the upper or lower triangle of the Hermitian band matrix A, stored in the first kd+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). On exit, if INFO = 0, the factor S from the split Cholesky factorization A = S**H*S. See Further Details.
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the factorization could not be completed, because the updated element a(i,i) was negative; the matrix A is not positive definite.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Further Details:

  The band storage scheme is illustrated by the following example, when
  N = 7, KD = 2:

  S = ( s11  s12  s13                     )
      (      s22  s23  s24                )
      (           s33  s34                )
      (                s44                )
      (           s53  s54  s55           )
      (                s64  s65  s66      )
      (                     s75  s76  s77 )

  If UPLO = 'U', the array AB holds:

  on entry:                          on exit:

   *    *   a13  a24  a35  a46  a57   *    *   s13  s24  s53**H s64**H s75**H
   *   a12  a23  a34  a45  a56  a67   *   s12  s23  s34  s54**H s65**H s76**H
  a11  a22  a33  a44  a55  a66  a77  s11  s22  s33  s44  s55    s66    s77

  If UPLO = 'L', the array AB holds:

  on entry:                          on exit:

  a11  a22  a33  a44  a55  a66  a77  s11    s22    s33    s44  s55  s66  s77
  a21  a32  a43  a54  a65  a76   *   s12**H s23**H s34**H s54  s65  s76   *
  a31  a42  a53  a64  a64   *    *   s13**H s24**H s53    s64  s75   *    *

  Array elements marked * are not used by the routine; s12**H denotes
  conjg(s12); the diagonal elements of S are real.

Definition at line 155 of file zpbstf.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, kd, ldab, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         ab( ldab, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            j, kld, km, m
      DOUBLE PRECISION   ajj
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdscal, zher, zlacgv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kd.LT.0 ) THEN
         info = -3
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPBSTF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      kld = max( 1, ldab-1 )
*
*     Set the splitting point m.
*
      m = ( n+kd ) / 2
*
      IF( upper ) THEN
*
*        Factorize A(m+1:n,m+1:n) as L**H*L, and update A(1:m,1:m).
*
         DO 10 j = n, m + 1, -1
*
*           Compute s(j,j) and test for non-positive-definiteness.
*
            ajj = dble( ab( kd+1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( kd+1, j ) = ajj
               GO TO 50
            END IF
            ajj = sqrt( ajj )
            ab( kd+1, j ) = ajj
            km = min( j-1, kd )
*
*           Compute elements j-km:j-1 of the j-th column and update the
*           the leading submatrix within the band.
*
            CALL zdscal( km, one / ajj, ab( kd+1-km, j ), 1 )
            CALL zher( 'Upper', km, -one, ab( kd+1-km, j ), 1,
     $                 ab( kd+1, j-km ), kld )
   10    CONTINUE
*
*        Factorize the updated submatrix A(1:m,1:m) as U**H*U.
*
         DO 20 j = 1, m
*
*           Compute s(j,j) and test for non-positive-definiteness.
*
            ajj = dble( ab( kd+1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( kd+1, j ) = ajj
               GO TO 50
            END IF
            ajj = sqrt( ajj )
            ab( kd+1, j ) = ajj
            km = min( kd, m-j )
*
*           Compute elements j+1:j+km of the j-th row and update the
*           trailing submatrix within the band.
*
            IF( km.GT.0 ) THEN
               CALL zdscal( km, one / ajj, ab( kd, j+1 ), kld )
               CALL zlacgv( km, ab( kd, j+1 ), kld )
               CALL zher( 'Upper', km, -one, ab( kd, j+1 ), kld,
     $                    ab( kd+1, j+1 ), kld )
               CALL zlacgv( km, ab( kd, j+1 ), kld )
            END IF
   20    CONTINUE
      ELSE
*
*        Factorize A(m+1:n,m+1:n) as L**H*L, and update A(1:m,1:m).
*
         DO 30 j = n, m + 1, -1
*
*           Compute s(j,j) and test for non-positive-definiteness.
*
            ajj = dble( ab( 1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( 1, j ) = ajj
               GO TO 50
            END IF
            ajj = sqrt( ajj )
            ab( 1, j ) = ajj
            km = min( j-1, kd )
*
*           Compute elements j-km:j-1 of the j-th row and update the
*           trailing submatrix within the band.
*
            CALL zdscal( km, one / ajj, ab( km+1, j-km ), kld )
            CALL zlacgv( km, ab( km+1, j-km ), kld )
            CALL zher( 'Lower', km, -one, ab( km+1, j-km ), kld,
     $                 ab( 1, j-km ), kld )
            CALL zlacgv( km, ab( km+1, j-km ), kld )
   30    CONTINUE
*
*        Factorize the updated submatrix A(1:m,1:m) as U**H*U.
*
         DO 40 j = 1, m
*
*           Compute s(j,j) and test for non-positive-definiteness.
*
            ajj = dble( ab( 1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( 1, j ) = ajj
               GO TO 50
            END IF
            ajj = sqrt( ajj )
            ab( 1, j ) = ajj
            km = min( kd, m-j )
*
*           Compute elements j+1:j+km of the j-th column and update the
*           trailing submatrix within the band.
*
            IF( km.GT.0 ) THEN
               CALL zdscal( km, one / ajj, ab( 2, j ), 1 )
               CALL zher( 'Lower', km, -one, ab( 2, j ), 1,
     $                    ab( 1, j+1 ), kld )
            END IF
   40    CONTINUE
      END IF
      RETURN
*
   50 CONTINUE
      info = j
      RETURN
*
*     End of ZPBSTF
*

Here is the call graph for this function:

Here is the caller graph for this function: