subroutine cqrt16	(	character	TRANS,
		integer	M,
		integer	N,
		integer	NRHS,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldx, * )	X,
		integer	LDX,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		real, dimension( * )	RWORK,
		real	RESID
	)

CQRT16

Purpose:

 CQRT16 computes the residual for a solution of a system of linear
 equations  A*x = b  or  A'*x = b:
    RESID = norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A *x = b = 'T': A^T*x = b, where A^T is the transpose of A = 'C': A^H*x = b, where A^H is the conjugate transpose of A
[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of columns of B, the matrix of right hand sides. NRHS >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The original M x N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in]	X	X is COMPLEX array, dimension (LDX,NRHS) The computed solution vectors for the system of linear equations.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M).
[in,out]	B	B is COMPLEX array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - A*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. IF TRANS = 'N', LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESID	RESID is REAL The maximum over the number of right hand sides of norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 135 of file cqrt16.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            lda, ldb, ldx, m, n, nrhs
      REAL               resid
*     ..
*     .. Array Arguments ..
      REAL               rwork( * )
      COMPLEX            a( lda, * ), b( ldb, * ), x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            cone
      parameter                ( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            j, n1, n2
      REAL               anorm, bnorm, eps, xnorm
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clange, scasum, slamch
      EXTERNAL           lsame, clange, scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0 or NRHS = 0
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.EQ.0 ) THEN
         resid = zero
         RETURN
      END IF
*
      IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
         anorm = clange( 'I', m, n, a, lda, rwork )
         n1 = n
         n2 = m
      ELSE
         anorm = clange( '1', m, n, a, lda, rwork )
         n1 = m
         n2 = n
      END IF
*
      eps = slamch( 'Epsilon' )
*
*     Compute  B - A*X  (or  B - A'*X ) and store in B.
*
      CALL cgemm( trans, 'No transpose', n1, nrhs, n2, -cone, a, lda, x,
     $            ldx, cone, b, ldb )
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ) .
*
      resid = zero
      DO 10 j = 1, nrhs
         bnorm = scasum( n1, b( 1, j ), 1 )
         xnorm = scasum( n2, x( 1, j ), 1 )
         IF( anorm.EQ.zero .AND. bnorm.EQ.zero ) THEN
            resid = zero
         ELSE IF( anorm.LE.zero .OR. xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) /
     $              ( max( m, n )*eps ) )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of CQRT16
*

Here is the call graph for this function:

Here is the caller graph for this function: