subroutine cspt01	(	character	UPLO,
		integer	N,
		complex, dimension( * )	A,
		complex, dimension( * )	AFAC,
		integer, dimension( * )	IPIV,
		complex, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( * )	RWORK,
		real	RESID
	)

CSPT01

Purpose:

 CSPT01 reconstructs a symmetric indefinite packed matrix A from its
 diagonal pivoting factorization A = U*D*U' or A = L*D*L' and computes
 the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix and EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (N*(N+1)/2) The original symmetric matrix A, stored as a packed triangular matrix.
[in]	AFAC	AFAC is COMPLEX array, dimension (N*(N+1)/2) The factored form of the matrix A, stored as a packed triangular matrix. AFAC contains the block diagonal matrix D and the multipliers used to obtain the factor L or U from the L*D*L' or U*D*U' factorization as computed by CSPTRF.
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from CSPTRF.
[out]	C	C is COMPLEX array, dimension (LDC,N)
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESID	RESID is REAL If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 114 of file cspt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldc, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      REAL               rwork( * )
      COMPLEX            a( * ), afac( * ), c( ldc, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            czero, cone
      parameter                ( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j, jc
      REAL               anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clansp, clansy, slamch
      EXTERNAL           lsame, clansp, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clavsp, claset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clansp( '1', uplo, n, a, rwork )
*
*     Initialize C to the identity matrix.
*
      CALL claset( 'Full', n, n, czero, cone, c, ldc )
*
*     Call CLAVSP to form the product D * U' (or D * L' ).
*
      CALL clavsp( uplo, 'Transpose', 'Non-unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Call CLAVSP again to multiply by U ( or L ).
*
      CALL clavsp( uplo, 'No transpose', 'Unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         jc = 0
         DO 20 j = 1, n
            DO 10 i = 1, j
               c( i, j ) = c( i, j ) - a( jc+i )
   10       CONTINUE
            jc = jc + j
   20    CONTINUE
      ELSE
         jc = 1
         DO 40 j = 1, n
            DO 30 i = j, n
               c( i, j ) = c( i, j ) - a( jc+i-j )
   30       CONTINUE
            jc = jc + n - j + 1
   40    CONTINUE
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clansy( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid/REAL( N ) )/anorm ) / eps
      END IF
*
      RETURN
*
*     End of CSPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: