subroutine cqrt13	(	integer	SCALE,
		integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		real	NORMA,
		integer, dimension( 4 )	ISEED
	)

CQRT13

Purpose:

 CQRT13 generates a full-rank matrix that may be scaled to have large
 or small norm.

Parameters

[in]	SCALE	SCALE is INTEGER SCALE = 1: normally scaled matrix SCALE = 2: matrix scaled up SCALE = 3: matrix scaled down
[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	N	N is INTEGER The number of columns of A.
[out]	A	A is COMPLEX array, dimension (LDA,N) The M-by-N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[out]	NORMA	NORMA is REAL The one-norm of A.
[in,out]	ISEED	ISEED is integer array, dimension (4) Seed for random number generator

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 93 of file cqrt13.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, m, n, scale
      REAL               norma
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
      COMPLEX            a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one
      parameter                ( one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
      REAL               bignum, smlnum
*     ..
*     .. External Functions ..
      REAL               clange, scasum, slamch
      EXTERNAL           clange, scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarnv, clascl, slabad
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, REAL, sign
*     ..
*     .. Local Arrays ..
      REAL               dummy( 1 )
*     ..
*     .. Executable Statements ..
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     benign matrix
*
      DO 10 j = 1, n
         CALL clarnv( 2, iseed, m, a( 1, j ) )
         IF( j.LE.m ) THEN
            a( j, j ) = a( j, j ) + cmplx( sign( scasum( m, a( 1, j ),
     $                  1 ), REAL( A( J, J ) ) ) )
         END IF
   10 CONTINUE
*
*     scaled versions
*
      IF( scale.NE.1 ) THEN
         norma = clange( 'Max', m, n, a, lda, dummy )
         smlnum = slamch( 'Safe minimum' )
         bignum = one / smlnum
         CALL slabad( smlnum, bignum )
         smlnum = smlnum / slamch( 'Epsilon' )
         bignum = one / smlnum
*
         IF( scale.EQ.2 ) THEN
*
*           matrix scaled up
*
            CALL clascl( 'General', 0, 0, norma, bignum, m, n, a, lda,
     $                   info )
         ELSE IF( scale.EQ.3 ) THEN
*
*           matrix scaled down
*
            CALL clascl( 'General', 0, 0, norma, smlnum, m, n, a, lda,
     $                   info )
         END IF
      END IF
*
      norma = clange( 'One-norm', m, n, a, lda, dummy )
      RETURN
*
*     End of CQRT13
*

Here is the call graph for this function:

Here is the caller graph for this function: