subroutine crqt01	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		complex, dimension( lda, * )	AF,
		complex, dimension( lda, * )	Q,
		complex, dimension( lda, * )	R,
		integer	LDA,
		complex, dimension( * )	TAU,
		complex, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( * )	RWORK,
		real, dimension( * )	RESULT
	)

CRQT01

Purpose:

 CRQT01 tests CGERQF, which computes the RQ factorization of an m-by-n
 matrix A, and partially tests CUNGRQ which forms the n-by-n
 orthogonal matrix Q.

 CRQT01 compares R with A*Q', and checks that Q is orthogonal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A.
[out]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the RQ factorization of A, as returned by CGERQF. See CGERQF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N) The n-by-n orthogonal matrix Q.
[out]	R	R is COMPLEX array, dimension (LDA,max(M,N))
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= max(M,N).
[out]	TAU	TAU is COMPLEX array, dimension (min(M,N)) The scalar factors of the elementary reflectors, as returned by CGERQF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (max(M,N))
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS ) RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 128 of file crqt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               result( * ), rwork( * )
      COMPLEX            a( lda, * ), af( lda, * ), q( lda, * ),
     $                   r( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            rogue
      parameter                ( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info, minmn
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               clange, clansy, slamch
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cgerqf, cherk, clacpy, claset, cungrq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'CGERQF'
      CALL cgerqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL claset( 'Full', n, n, rogue, rogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL clacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL clacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL clacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'CUNGRQ'
      CALL cungrq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy R
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( zero ), r, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 )
     $      CALL clacpy( 'Upper', m, m, af( 1, n-m+1 ), lda,
     $                   r( 1, n-m+1 ), lda )
      ELSE
         IF( m.GT.n .AND. n.GT.0 )
     $      CALL clacpy( 'Full', m-n, n, af, lda, r, lda )
         IF( n.GT.0 )
     $      CALL clacpy( 'Upper', n, n, af( m-n+1, 1 ), lda,
     $                   r( m-n+1, 1 ), lda )
      END IF
*
*     Compute R - A*Q'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', m, n, n,
     $            cmplx( -one ), a, lda, q, lda, cmplx( one ), r, lda )
*
*     Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = clange( '1', m, n, a, lda, rwork )
      resid = clange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, N ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), r, lda )
      CALL cherk( 'Upper', 'No transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = clansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, N ) ) ) / eps
*
      RETURN
*
*     End of CRQT01
*

Here is the call graph for this function:

Here is the caller graph for this function: