subroutine clqt02	(	integer	M,
		integer	N,
		integer	K,
		complex, dimension( lda, * )	A,
		complex, dimension( lda, * )	AF,
		complex, dimension( lda, * )	Q,
		complex, dimension( lda, * )	L,
		integer	LDA,
		complex, dimension( * )	TAU,
		complex, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( * )	RWORK,
		real, dimension( * )	RESULT
	)

CLQT02

Purpose:

 CLQT02 tests CUNGLQ, which generates an m-by-n matrix Q with
 orthonornmal rows that is defined as the product of k elementary
 reflectors.

 Given the LQ factorization of an m-by-n matrix A, CLQT02 generates
 the orthogonal matrix Q defined by the factorization of the first k
 rows of A; it compares L(1:k,1:m) with A(1:k,1:n)*Q(1:m,1:n)', and
 checks that the rows of Q are orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. N >= M >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A which was factorized by CLQT01.
[in]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the LQ factorization of A, as returned by CGELQF. See CGELQF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N)
[out]	L	L is COMPLEX array, dimension (LDA,M)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= N.
[in]	TAU	TAU is COMPLEX array, dimension (M) The scalar factors of the elementary reflectors corresponding to the LQ factorization in AF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS ) RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 137 of file clqt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               result( * ), rwork( * )
      COMPLEX            a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            rogue
      parameter                ( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               clange, clansy, slamch
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clacpy, claset, cunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL claset( 'Full', m, n, rogue, rogue, q, lda )
      CALL clacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'CUNGLQ'
      CALL cunglq( m, n, k, q, lda, tau, work, lwork, info )
*
*     Copy L(1:k,1:m)
*
      CALL claset( 'Full', k, m, cmplx( zero ), cmplx( zero ), l, lda )
      CALL clacpy( 'Lower', k, m, af, lda, l, lda )
*
*     Compute L(1:k,1:m) - A(1:k,1:n) * Q(1:m,1:n)'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', k, m, n,
     $            cmplx( -one ), a, lda, q, lda, cmplx( one ), l, lda )
*
*     Compute norm( L - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = clange( '1', k, n, a, lda, rwork )
      resid = clange( '1', k, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, N ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', m, m, cmplx( zero ), cmplx( one ), l, lda )
      CALL cherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = clansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, N ) ) ) / eps
*
      RETURN
*
*     End of CLQT02
*

Here is the call graph for this function:

Here is the caller graph for this function: