subroutine zgelq2	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( * )	WORK,
		integer	INFO
	)

ZGELQ2 computes the LQ factorization of a general rectangular matrix using an unblocked algorithm.

Download ZGELQ2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZGELQ2 computes an LQ factorization of a complex m by n matrix A:
 A = L * Q.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the m by n matrix A. On exit, the elements on and below the diagonal of the array contain the m by min(m,n) lower trapezoidal matrix L (L is lower triangular if m <= n); the elements above the diagonal, with the array TAU, represent the unitary matrix Q as a product of elementary reflectors (see Further Details).
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	TAU	TAU is COMPLEX*16 array, dimension (min(M,N)) The scalar factors of the elementary reflectors (see Further Details).
[out]	WORK	WORK is COMPLEX*16 array, dimension (M)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Further Details:

  The matrix Q is represented as a product of elementary reflectors

     Q = H(k)**H . . . H(2)**H H(1)**H, where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i-1) = 0 and v(i) = 1; conjg(v(i+1:n)) is stored on exit in
  A(i,i+1:n), and tau in TAU(i).

Definition at line 123 of file zgelq2.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         one
      parameter                ( one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, k
      COMPLEX*16         alpha
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlacgv, zlarf, zlarfg
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGELQ2', -info )
         RETURN
      END IF
*
      k = min( m, n )
*
      DO 10 i = 1, k
*
*        Generate elementary reflector H(i) to annihilate A(i,i+1:n)
*
         CALL zlacgv( n-i+1, a( i, i ), lda )
         alpha = a( i, i )
         CALL zlarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
     $                tau( i ) )
         IF( i.LT.m ) THEN
*
*           Apply H(i) to A(i+1:m,i:n) from the right
*
            a( i, i ) = one
            CALL zlarf( 'Right', m-i, n-i+1, a( i, i ), lda, tau( i ),
     $                  a( i+1, i ), lda, work )
         END IF
         a( i, i ) = alpha
         CALL zlacgv( n-i+1, a( i, i ), lda )
   10 CONTINUE
      RETURN
*
*     End of ZGELQ2
*

Here is the call graph for this function:

Here is the caller graph for this function: