LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dsygvx ( integer  ITYPE,
character  JOBZ,
character  RANGE,
character  UPLO,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision  VL,
double precision  VU,
integer  IL,
integer  IU,
double precision  ABSTOL,
integer  M,
double precision, dimension( * )  W,
double precision, dimension( ldz, * )  Z,
integer  LDZ,
double precision, dimension( * )  WORK,
integer  LWORK,
integer, dimension( * )  IWORK,
integer, dimension( * )  IFAIL,
integer  INFO 
)

DSYGVX

Download DSYGVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DSYGVX computes selected eigenvalues, and optionally, eigenvectors
 of a real generalized symmetric-definite eigenproblem, of the form
 A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.  Here A
 and B are assumed to be symmetric and B is also positive definite.
 Eigenvalues and eigenvectors can be selected by specifying either a
 range of values or a range of indices for the desired eigenvalues.
Parameters
[in]ITYPE
          ITYPE is INTEGER
          Specifies the problem type to be solved:
          = 1:  A*x = (lambda)*B*x
          = 2:  A*B*x = (lambda)*x
          = 3:  B*A*x = (lambda)*x
[in]JOBZ
          JOBZ is CHARACTER*1
          = 'N':  Compute eigenvalues only;
          = 'V':  Compute eigenvalues and eigenvectors.
[in]RANGE
          RANGE is CHARACTER*1
          = 'A': all eigenvalues will be found.
          = 'V': all eigenvalues in the half-open interval (VL,VU]
                 will be found.
          = 'I': the IL-th through IU-th eigenvalues will be found.
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A and B are stored;
          = 'L':  Lower triangle of A and B are stored.
[in]N
          N is INTEGER
          The order of the matrix pencil (A,B).  N >= 0.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA, N)
          On entry, the symmetric matrix A.  If UPLO = 'U', the
          leading N-by-N upper triangular part of A contains the
          upper triangular part of the matrix A.  If UPLO = 'L',
          the leading N-by-N lower triangular part of A contains
          the lower triangular part of the matrix A.

          On exit, the lower triangle (if UPLO='L') or the upper
          triangle (if UPLO='U') of A, including the diagonal, is
          destroyed.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is DOUBLE PRECISION array, dimension (LDB, N)
          On entry, the symmetric matrix B.  If UPLO = 'U', the
          leading N-by-N upper triangular part of B contains the
          upper triangular part of the matrix B.  If UPLO = 'L',
          the leading N-by-N lower triangular part of B contains
          the lower triangular part of the matrix B.

          On exit, if INFO <= N, the part of B containing the matrix is
          overwritten by the triangular factor U or L from the Cholesky
          factorization B = U**T*U or B = L*L**T.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[in]VL
          VL is DOUBLE PRECISION
          If RANGE='V', the lower bound of the interval to
          be searched for eigenvalues. VL < VU.
          Not referenced if RANGE = 'A' or 'I'.
[in]VU
          VU is DOUBLE PRECISION
          If RANGE='V', the upper bound of the interval to
          be searched for eigenvalues. VL < VU.
          Not referenced if RANGE = 'A' or 'I'.
[in]IL
          IL is INTEGER
          If RANGE='I', the index of the
          smallest eigenvalue to be returned.
          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
          Not referenced if RANGE = 'A' or 'V'.
[in]IU
          IU is INTEGER
          If RANGE='I', the index of the
          largest eigenvalue to be returned.
          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
          Not referenced if RANGE = 'A' or 'V'.
[in]ABSTOL
          ABSTOL is DOUBLE PRECISION
          The absolute error tolerance for the eigenvalues.
          An approximate eigenvalue is accepted as converged
          when it is determined to lie in an interval [a,b]
          of width less than or equal to

                  ABSTOL + EPS *   max( |a|,|b| ) ,

          where EPS is the machine precision.  If ABSTOL is less than
          or equal to zero, then  EPS*|T|  will be used in its place,
          where |T| is the 1-norm of the tridiagonal matrix obtained
          by reducing C to tridiagonal form, where C is the symmetric
          matrix of the standard symmetric problem to which the
          generalized problem is transformed.

          Eigenvalues will be computed most accurately when ABSTOL is
          set to twice the underflow threshold 2*DLAMCH('S'), not zero.
          If this routine returns with INFO>0, indicating that some
          eigenvectors did not converge, try setting ABSTOL to
          2*DLAMCH('S').
[out]M
          M is INTEGER
          The total number of eigenvalues found.  0 <= M <= N.
          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
[out]W
          W is DOUBLE PRECISION array, dimension (N)
          On normal exit, the first M elements contain the selected
          eigenvalues in ascending order.
[out]Z
          Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M))
          If JOBZ = 'N', then Z is not referenced.
          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
          contain the orthonormal eigenvectors of the matrix A
          corresponding to the selected eigenvalues, with the i-th
          column of Z holding the eigenvector associated with W(i).
          The eigenvectors are normalized as follows:
          if ITYPE = 1 or 2, Z**T*B*Z = I;
          if ITYPE = 3, Z**T*inv(B)*Z = I.

          If an eigenvector fails to converge, then that column of Z
          contains the latest approximation to the eigenvector, and the
          index of the eigenvector is returned in IFAIL.
          Note: the user must ensure that at least max(1,M) columns are
          supplied in the array Z; if RANGE = 'V', the exact value of M
          is not known in advance and an upper bound must be used.
[in]LDZ
          LDZ is INTEGER
          The leading dimension of the array Z.  LDZ >= 1, and if
          JOBZ = 'V', LDZ >= max(1,N).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The length of the array WORK.  LWORK >= max(1,8*N).
          For optimal efficiency, LWORK >= (NB+3)*N,
          where NB is the blocksize for DSYTRD returned by ILAENV.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]IWORK
          IWORK is INTEGER array, dimension (5*N)
[out]IFAIL
          IFAIL is INTEGER array, dimension (N)
          If JOBZ = 'V', then if INFO = 0, the first M elements of
          IFAIL are zero.  If INFO > 0, then IFAIL contains the
          indices of the eigenvectors that failed to converge.
          If JOBZ = 'N', then IFAIL is not referenced.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  DPOTRF or DSYEVX returned an error code:
             <= N:  if INFO = i, DSYEVX failed to converge;
                    i eigenvectors failed to converge.  Their indices
                    are stored in array IFAIL.
             > N:   if INFO = N + i, for 1 <= i <= N, then the leading
                    minor of order i of B is not positive definite.
                    The factorization of B could not be completed and
                    no eigenvalues or eigenvectors were computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016
Contributors:
Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA

Definition at line 299 of file dsygvx.f.

299 *
300 * -- LAPACK driver routine (version 3.6.1) --
301 * -- LAPACK is a software package provided by Univ. of Tennessee, --
302 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
303 * June 2016
304 *
305 * .. Scalar Arguments ..
306  CHARACTER jobz, range, uplo
307  INTEGER il, info, itype, iu, lda, ldb, ldz, lwork, m, n
308  DOUBLE PRECISION abstol, vl, vu
309 * ..
310 * .. Array Arguments ..
311  INTEGER ifail( * ), iwork( * )
312  DOUBLE PRECISION a( lda, * ), b( ldb, * ), w( * ), work( * ),
313  $ z( ldz, * )
314 * ..
315 *
316 * =====================================================================
317 *
318 * .. Parameters ..
319  DOUBLE PRECISION one
320  parameter ( one = 1.0d+0 )
321 * ..
322 * .. Local Scalars ..
323  LOGICAL alleig, indeig, lquery, upper, valeig, wantz
324  CHARACTER trans
325  INTEGER lwkmin, lwkopt, nb
326 * ..
327 * .. External Functions ..
328  LOGICAL lsame
329  INTEGER ilaenv
330  EXTERNAL lsame, ilaenv
331 * ..
332 * .. External Subroutines ..
333  EXTERNAL dpotrf, dsyevx, dsygst, dtrmm, dtrsm, xerbla
334 * ..
335 * .. Intrinsic Functions ..
336  INTRINSIC max, min
337 * ..
338 * .. Executable Statements ..
339 *
340 * Test the input parameters.
341 *
342  upper = lsame( uplo, 'U' )
343  wantz = lsame( jobz, 'V' )
344  alleig = lsame( range, 'A' )
345  valeig = lsame( range, 'V' )
346  indeig = lsame( range, 'I' )
347  lquery = ( lwork.EQ.-1 )
348 *
349  info = 0
350  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
351  info = -1
352  ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
353  info = -2
354  ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
355  info = -3
356  ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
357  info = -4
358  ELSE IF( n.LT.0 ) THEN
359  info = -5
360  ELSE IF( lda.LT.max( 1, n ) ) THEN
361  info = -7
362  ELSE IF( ldb.LT.max( 1, n ) ) THEN
363  info = -9
364  ELSE
365  IF( valeig ) THEN
366  IF( n.GT.0 .AND. vu.LE.vl )
367  $ info = -11
368  ELSE IF( indeig ) THEN
369  IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
370  info = -12
371  ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
372  info = -13
373  END IF
374  END IF
375  END IF
376  IF (info.EQ.0) THEN
377  IF (ldz.LT.1 .OR. (wantz .AND. ldz.LT.n)) THEN
378  info = -18
379  END IF
380  END IF
381 *
382  IF( info.EQ.0 ) THEN
383  lwkmin = max( 1, 8*n )
384  nb = ilaenv( 1, 'DSYTRD', uplo, n, -1, -1, -1 )
385  lwkopt = max( lwkmin, ( nb + 3 )*n )
386  work( 1 ) = lwkopt
387 *
388  IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
389  info = -20
390  END IF
391  END IF
392 *
393  IF( info.NE.0 ) THEN
394  CALL xerbla( 'DSYGVX', -info )
395  RETURN
396  ELSE IF( lquery ) THEN
397  RETURN
398  END IF
399 *
400 * Quick return if possible
401 *
402  m = 0
403  IF( n.EQ.0 ) THEN
404  RETURN
405  END IF
406 *
407 * Form a Cholesky factorization of B.
408 *
409  CALL dpotrf( uplo, n, b, ldb, info )
410  IF( info.NE.0 ) THEN
411  info = n + info
412  RETURN
413  END IF
414 *
415 * Transform problem to standard eigenvalue problem and solve.
416 *
417  CALL dsygst( itype, uplo, n, a, lda, b, ldb, info )
418  CALL dsyevx( jobz, range, uplo, n, a, lda, vl, vu, il, iu, abstol,
419  $ m, w, z, ldz, work, lwork, iwork, ifail, info )
420 *
421  IF( wantz ) THEN
422 *
423 * Backtransform eigenvectors to the original problem.
424 *
425  IF( info.GT.0 )
426  $ m = info - 1
427  IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
428 *
429 * For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
430 * backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
431 *
432  IF( upper ) THEN
433  trans = 'N'
434  ELSE
435  trans = 'T'
436  END IF
437 *
438  CALL dtrsm( 'Left', uplo, trans, 'Non-unit', n, m, one, b,
439  $ ldb, z, ldz )
440 *
441  ELSE IF( itype.EQ.3 ) THEN
442 *
443 * For B*A*x=(lambda)*x;
444 * backtransform eigenvectors: x = L*y or U**T*y
445 *
446  IF( upper ) THEN
447  trans = 'T'
448  ELSE
449  trans = 'N'
450  END IF
451 *
452  CALL dtrmm( 'Left', uplo, trans, 'Non-unit', n, m, one, b,
453  $ ldb, z, ldz )
454  END IF
455  END IF
456 *
457 * Set WORK(1) to optimal workspace size.
458 *
459  work( 1 ) = lwkopt
460 *
461  RETURN
462 *
463 * End of DSYGVX
464 *
subroutine dtrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRSM
Definition: dtrsm.f:183
subroutine dpotrf(UPLO, N, A, LDA, INFO)
DPOTRF
Definition: dpotrf.f:109
subroutine dtrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRMM
Definition: dtrmm.f:179
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dsyevx(JOBZ, RANGE, UPLO, N, A, LDA, VL, VU, IL, IU, ABSTOL, M, W, Z, LDZ, WORK, LWORK, IWORK, IFAIL, INFO)
DSYEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matrices ...
Definition: dsyevx.f:255
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
Definition: tstiee.f:83
subroutine dsygst(ITYPE, UPLO, N, A, LDA, B, LDB, INFO)
DSYGST
Definition: dsygst.f:129
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: