subroutine clarzt	(	character	DIRECT,
		character	STOREV,
		integer	N,
		integer	K,
		complex, dimension( ldv, * )	V,
		integer	LDV,
		complex, dimension( * )	TAU,
		complex, dimension( ldt, * )	T,
		integer	LDT
	)

CLARZT forms the triangular factor T of a block reflector H = I - vtvH.

Download CLARZT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLARZT forms the triangular factor T of a complex block reflector
 H of order > n, which is defined as a product of k elementary
 reflectors.

 If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;

 If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.

 If STOREV = 'C', the vector which defines the elementary reflector
 H(i) is stored in the i-th column of the array V, and

    H  =  I - V * T * V**H

 If STOREV = 'R', the vector which defines the elementary reflector
 H(i) is stored in the i-th row of the array V, and

    H  =  I - V**H * T * V

 Currently, only STOREV = 'R' and DIRECT = 'B' are supported.

Parameters

[in]	DIRECT	DIRECT is CHARACTER*1 Specifies the order in which the elementary reflectors are multiplied to form the block reflector: = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet) = 'B': H = H(k) . . . H(2) H(1) (Backward)
[in]	STOREV	STOREV is CHARACTER*1 Specifies how the vectors which define the elementary reflectors are stored (see also Further Details): = 'C': columnwise (not supported yet) = 'R': rowwise
[in]	N	N is INTEGER The order of the block reflector H. N >= 0.
[in]	K	K is INTEGER The order of the triangular factor T (= the number of elementary reflectors). K >= 1.
[in,out]	V	V is COMPLEX array, dimension (LDV,K) if STOREV = 'C' (LDV,N) if STOREV = 'R' The matrix V. See further details.
[in]	LDV	LDV is INTEGER The leading dimension of the array V. If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
[in]	TAU	TAU is COMPLEX array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i).
[out]	T	T is COMPLEX array, dimension (LDT,K) The k by k triangular factor T of the block reflector. If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is lower triangular. The rest of the array is not used.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= K.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Contributors:

A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Further Details:

  The shape of the matrix V and the storage of the vectors which define
  the H(i) is best illustrated by the following example with n = 5 and
  k = 3. The elements equal to 1 are not stored; the corresponding
  array elements are modified but restored on exit. The rest of the
  array is not used.

  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':

                                              ______V_____
         ( v1 v2 v3 )                        /            \
         ( v1 v2 v3 )                      ( v1 v1 v1 v1 v1 . . . . 1 )
     V = ( v1 v2 v3 )                      ( v2 v2 v2 v2 v2 . . . 1   )
         ( v1 v2 v3 )                      ( v3 v3 v3 v3 v3 . . 1     )
         ( v1 v2 v3 )
            .  .  .
            .  .  .
            1  .  .
               1  .
                  1

  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':

                                                        ______V_____
            1                                          /            \
            .  1                           ( 1 . . . . v1 v1 v1 v1 v1 )
            .  .  1                        ( . 1 . . . v2 v2 v2 v2 v2 )
            .  .  .                        ( . . 1 . . v3 v3 v3 v3 v3 )
            .  .  .
         ( v1 v2 v3 )
         ( v1 v2 v3 )
     V = ( v1 v2 v3 )
         ( v1 v2 v3 )
         ( v1 v2 v3 )

Definition at line 187 of file clarzt.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          direct, storev
      INTEGER            k, ldt, ldv, n
*     ..
*     .. Array Arguments ..
      COMPLEX            t( ldt, * ), tau( * ), v( ldv, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            zero
      parameter                ( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, clacgv, ctrmv, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Check for currently supported options
*
      info = 0
      IF( .NOT.lsame( direct, 'B' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( storev, 'R' ) ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLARZT', -info )
         RETURN
      END IF
*
      DO 20 i = k, 1, -1
         IF( tau( i ).EQ.zero ) THEN
*
*           H(i)  =  I
*
            DO 10 j = i, k
               t( j, i ) = zero
   10       CONTINUE
         ELSE
*
*           general case
*
            IF( i.LT.k ) THEN
*
*              T(i+1:k,i) = - tau(i) * V(i+1:k,1:n) * V(i,1:n)**H
*
               CALL clacgv( n, v( i, 1 ), ldv )
               CALL cgemv( 'No transpose', k-i, n, -tau( i ),
     $                     v( i+1, 1 ), ldv, v( i, 1 ), ldv, zero,
     $                     t( i+1, i ), 1 )
               CALL clacgv( n, v( i, 1 ), ldv )
*
*              T(i+1:k,i) = T(i+1:k,i+1:k) * T(i+1:k,i)
*
               CALL ctrmv( 'Lower', 'No transpose', 'Non-unit', k-i,
     $                     t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
            END IF
            t( i, i ) = tau( i )
         END IF
   20 CONTINUE
      RETURN
*
*     End of CLARZT
*

Here is the call graph for this function:

Here is the caller graph for this function: