subroutine dmmch	(	character*1	TRANSA,
		character*1	TRANSB,
		integer	M,
		integer	N,
		integer	KK,
		double precision	ALPHA,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision	BETA,
		double precision, dimension( ldc, * )	C,
		integer	LDC,
		double precision, dimension( * )	CT,
		double precision, dimension( * )	G,
		double precision, dimension( ldcc, * )	CC,
		integer	LDCC,
		double precision	EPS,
		double precision	ERR,
		logical	FATAL,
		integer	NOUT,
		logical	MV
	)

Definition at line 2199 of file c_dblat3.f.

*
*  Checks the results of the computational tests.
*
*  Auxiliary routine for test program for Level 3 Blas.
*
*  -- Written on 8-February-1989.
*     Jack Dongarra, Argonne National Laboratory.
*     Iain Duff, AERE Harwell.
*     Jeremy Du Croz, Numerical Algorithms Group Ltd.
*     Sven Hammarling, Numerical Algorithms Group Ltd.
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d0, one = 1.0d0 )
*     .. Scalar Arguments ..
      DOUBLE PRECISION   alpha, beta, eps, err
      INTEGER            kk, lda, ldb, ldc, ldcc, m, n, nout
      LOGICAL            fatal, mv
      CHARACTER*1        transa, transb
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), c( ldc, * ),
     $                   cc( ldcc, * ), ct( * ), g( * )
*     .. Local Scalars ..
      DOUBLE PRECISION   erri
      INTEGER            i, j, k
      LOGICAL            trana, tranb
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     .. Executable Statements ..
      trana = transa.EQ.'T'.OR.transa.EQ.'C'
      tranb = transb.EQ.'T'.OR.transb.EQ.'C'
*
*     Compute expected result, one column at a time, in CT using data
*     in A, B and C.
*     Compute gauges in G.
*
      DO 120 j = 1, n
*
         DO 10 i = 1, m
            ct( i ) = zero
            g( i ) = zero
   10    CONTINUE
         IF( .NOT.trana.AND..NOT.tranb )THEN
            DO 30 k = 1, kk
               DO 20 i = 1, m
                  ct( i ) = ct( i ) + a( i, k )*b( k, j )
                  g( i ) = g( i ) + abs( a( i, k ) )*abs( b( k, j ) )
   20          CONTINUE
   30       CONTINUE
         ELSE IF( trana.AND..NOT.tranb )THEN
            DO 50 k = 1, kk
               DO 40 i = 1, m
                  ct( i ) = ct( i ) + a( k, i )*b( k, j )
                  g( i ) = g( i ) + abs( a( k, i ) )*abs( b( k, j ) )
   40          CONTINUE
   50       CONTINUE
         ELSE IF( .NOT.trana.AND.tranb )THEN
            DO 70 k = 1, kk
               DO 60 i = 1, m
                  ct( i ) = ct( i ) + a( i, k )*b( j, k )
                  g( i ) = g( i ) + abs( a( i, k ) )*abs( b( j, k ) )
   60          CONTINUE
   70       CONTINUE
         ELSE IF( trana.AND.tranb )THEN
            DO 90 k = 1, kk
               DO 80 i = 1, m
                  ct( i ) = ct( i ) + a( k, i )*b( j, k )
                  g( i ) = g( i ) + abs( a( k, i ) )*abs( b( j, k ) )
   80          CONTINUE
   90       CONTINUE
         END IF
         DO 100 i = 1, m
            ct( i ) = alpha*ct( i ) + beta*c( i, j )
            g( i ) = abs( alpha )*g( i ) + abs( beta )*abs( c( i, j ) )
  100    CONTINUE
*
*        Compute the error ratio for this result.
*
         err = zero
         DO 110 i = 1, m
            erri = abs( ct( i ) - cc( i, j ) )/eps
            IF( g( i ).NE.zero )
     $         erri = erri/g( i )
            err = max( err, erri )
            IF( err*sqrt( eps ).GE.one )
     $         GO TO 130
  110    CONTINUE
*
  120 CONTINUE
*
*     If the loop completes, all results are at least half accurate.
      GO TO 150
*
*     Report fatal error.
*
  130 fatal = .true.
      WRITE( nout, fmt = 9999 )
      DO 140 i = 1, m
         IF( mv )THEN
            WRITE( nout, fmt = 9998 )i, ct( i ), cc( i, j )
         ELSE
            WRITE( nout, fmt = 9998 )i, cc( i, j ), ct( i )
         END IF
  140 CONTINUE
      IF( n.GT.1 )
     $   WRITE( nout, fmt = 9997 )j
*
  150 CONTINUE
      RETURN
*
 9999 FORMAT( ' ******* FATAL ERROR - COMPUTED RESULT IS LESS THAN HAL',
     $      'F ACCURATE *******', /'           EXPECTED RESULT   COMPU',
     $      'TED RESULT' )
 9998 FORMAT( 1x, i7, 2g18.6 )
 9997 FORMAT( '      THESE ARE THE RESULTS FOR COLUMN ', i3 )
*
*     End of DMMCH.
*