subroutine zpbtf2	(	character	UPLO,
		integer	N,
		integer	KD,
		complex*16, dimension( ldab, * )	AB,
		integer	LDAB,
		integer	INFO
	)

ZPBTF2 computes the Cholesky factorization of a symmetric/Hermitian positive definite band matrix (unblocked algorithm).

Download ZPBTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZPBTF2 computes the Cholesky factorization of a complex Hermitian
 positive definite band matrix A.

 The factorization has the form
    A = U**H * U ,  if UPLO = 'U', or
    A = L  * L**H,  if UPLO = 'L',
 where U is an upper triangular matrix, U**H is the conjugate transpose
 of U, and L is lower triangular.

 This is the unblocked version of the algorithm, calling Level 2 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of super-diagonals of the matrix A if UPLO = 'U', or the number of sub-diagonals if UPLO = 'L'. KD >= 0.
[in,out]	AB	AB is COMPLEX*16 array, dimension (LDAB,N) On entry, the upper or lower triangle of the Hermitian band matrix A, stored in the first KD+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). On exit, if INFO = 0, the triangular factor U or L from the Cholesky factorization A = U**H *U or A = L*L**H of the band matrix A, in the same storage format as A.
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value > 0: if INFO = k, the leading minor of order k is not positive definite, and the factorization could not be completed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Further Details:

  The band storage scheme is illustrated by the following example, when
  N = 6, KD = 2, and UPLO = 'U':

  On entry:                       On exit:

      *    *   a13  a24  a35  a46      *    *   u13  u24  u35  u46
      *   a12  a23  a34  a45  a56      *   u12  u23  u34  u45  u56
     a11  a22  a33  a44  a55  a66     u11  u22  u33  u44  u55  u66

  Similarly, if UPLO = 'L' the format of A is as follows:

  On entry:                       On exit:

     a11  a22  a33  a44  a55  a66     l11  l22  l33  l44  l55  l66
     a21  a32  a43  a54  a65   *      l21  l32  l43  l54  l65   *
     a31  a42  a53  a64   *    *      l31  l42  l53  l64   *    *

  Array elements marked * are not used by the routine.

Definition at line 144 of file zpbtf2.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, kd, ldab, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         ab( ldab, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            j, kld, kn
      DOUBLE PRECISION   ajj
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdscal, zher, zlacgv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kd.LT.0 ) THEN
         info = -3
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPBTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      kld = max( 1, ldab-1 )
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization A = U**H * U.
*
         DO 10 j = 1, n
*
*           Compute U(J,J) and test for non-positive-definiteness.
*
            ajj = dble( ab( kd+1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( kd+1, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            ab( kd+1, j ) = ajj
*
*           Compute elements J+1:J+KN of row J and update the
*           trailing submatrix within the band.
*
            kn = min( kd, n-j )
            IF( kn.GT.0 ) THEN
               CALL zdscal( kn, one / ajj, ab( kd, j+1 ), kld )
               CALL zlacgv( kn, ab( kd, j+1 ), kld )
               CALL zher( 'Upper', kn, -one, ab( kd, j+1 ), kld,
     $                    ab( kd+1, j+1 ), kld )
               CALL zlacgv( kn, ab( kd, j+1 ), kld )
            END IF
   10    CONTINUE
      ELSE
*
*        Compute the Cholesky factorization A = L*L**H.
*
         DO 20 j = 1, n
*
*           Compute L(J,J) and test for non-positive-definiteness.
*
            ajj = dble( ab( 1, j ) )
            IF( ajj.LE.zero ) THEN
               ab( 1, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            ab( 1, j ) = ajj
*
*           Compute elements J+1:J+KN of column J and update the
*           trailing submatrix within the band.
*
            kn = min( kd, n-j )
            IF( kn.GT.0 ) THEN
               CALL zdscal( kn, one / ajj, ab( 2, j ), 1 )
               CALL zher( 'Lower', kn, -one, ab( 2, j ), 1,
     $                    ab( 1, j+1 ), kld )
            END IF
   20    CONTINUE
      END IF
      RETURN
*
   30 CONTINUE
      info = j
      RETURN
*
*     End of ZPBTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: