LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine dorgl2 ( integer M, integer N, integer K, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) TAU, double precision, dimension( * ) WORK, integer INFO )

DORGL2

Purpose:
``` DORGL2 generates an m by n real matrix Q with orthonormal rows,
which is defined as the first m rows of a product of k elementary
reflectors of order n

Q  =  H(k) . . . H(2) H(1)

as returned by DGELQF.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix Q. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix Q. N >= M.``` [in] K ``` K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.``` [in,out] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the i-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by DGELQF in the first k rows of its array argument A. On exit, the m-by-n matrix Q.``` [in] LDA ``` LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).``` [in] TAU ``` TAU is DOUBLE PRECISION array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by DGELQF.``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (M)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value```
Date
November 2011

Definition at line 115 of file dorgl2.f.

115 *
116 * -- LAPACK computational routine (version 3.4.0) --
117 * -- LAPACK is a software package provided by Univ. of Tennessee, --
118 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119 * November 2011
120 *
121 * .. Scalar Arguments ..
122  INTEGER info, k, lda, m, n
123 * ..
124 * .. Array Arguments ..
125  DOUBLE PRECISION a( lda, * ), tau( * ), work( * )
126 * ..
127 *
128 * =====================================================================
129 *
130 * .. Parameters ..
131  DOUBLE PRECISION one, zero
132  parameter ( one = 1.0d+0, zero = 0.0d+0 )
133 * ..
134 * .. Local Scalars ..
135  INTEGER i, j, l
136 * ..
137 * .. External Subroutines ..
138  EXTERNAL dlarf, dscal, xerbla
139 * ..
140 * .. Intrinsic Functions ..
141  INTRINSIC max
142 * ..
143 * .. Executable Statements ..
144 *
145 * Test the input arguments
146 *
147  info = 0
148  IF( m.LT.0 ) THEN
149  info = -1
150  ELSE IF( n.LT.m ) THEN
151  info = -2
152  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
153  info = -3
154  ELSE IF( lda.LT.max( 1, m ) ) THEN
155  info = -5
156  END IF
157  IF( info.NE.0 ) THEN
158  CALL xerbla( 'DORGL2', -info )
159  RETURN
160  END IF
161 *
162 * Quick return if possible
163 *
164  IF( m.LE.0 )
165  \$ RETURN
166 *
167  IF( k.LT.m ) THEN
168 *
169 * Initialise rows k+1:m to rows of the unit matrix
170 *
171  DO 20 j = 1, n
172  DO 10 l = k + 1, m
173  a( l, j ) = zero
174  10 CONTINUE
175  IF( j.GT.k .AND. j.LE.m )
176  \$ a( j, j ) = one
177  20 CONTINUE
178  END IF
179 *
180  DO 40 i = k, 1, -1
181 *
182 * Apply H(i) to A(i:m,i:n) from the right
183 *
184  IF( i.LT.n ) THEN
185  IF( i.LT.m ) THEN
186  a( i, i ) = one
187  CALL dlarf( 'Right', m-i, n-i+1, a( i, i ), lda,
188  \$ tau( i ), a( i+1, i ), lda, work )
189  END IF
190  CALL dscal( n-i, -tau( i ), a( i, i+1 ), lda )
191  END IF
192  a( i, i ) = one - tau( i )
193 *
194 * Set A(i,1:i-1) to zero
195 *
196  DO 30 l = 1, i - 1
197  a( i, l ) = zero
198  30 CONTINUE
199  40 CONTINUE
200  RETURN
201 *
202 * End of DORGL2
203 *
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:55

Here is the call graph for this function:

Here is the caller graph for this function: