subroutine sorghr	(	integer	N,
		integer	ILO,
		integer	IHI,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( * )	WORK,
		integer	LWORK,
		integer	INFO
	)

SORGHR

Download SORGHR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SORGHR generates a real orthogonal matrix Q which is defined as the
 product of IHI-ILO elementary reflectors of order N, as returned by
 SGEHRD:

 Q = H(ilo) H(ilo+1) . . . H(ihi-1).

Parameters

[in]	N	N is INTEGER The order of the matrix Q. N >= 0.
[in]	ILO	ILO is INTEGER
[in]	IHI	IHI is INTEGER ILO and IHI must have the same values as in the previous call of SGEHRD. Q is equal to the unit matrix except in the submatrix Q(ilo+1:ihi,ilo+1:ihi). 1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the vectors which define the elementary reflectors, as returned by SGEHRD. On exit, the N-by-N orthogonal matrix Q.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	TAU	TAU is REAL array, dimension (N-1) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SGEHRD.
[out]	WORK	WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= IHI-ILO. For optimum performance LWORK >= (IHI-ILO)*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 128 of file sorghr.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            ihi, ilo, info, lda, lwork, n
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            lquery
      INTEGER            i, iinfo, j, lwkopt, nb, nh
*     ..
*     .. External Subroutines ..
      EXTERNAL           sorgqr, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ilaenv 
      EXTERNAL           ilaenv 
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      nh = ihi - ilo
      lquery = ( lwork.EQ.-1 )
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
         info = -2
      ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( lwork.LT.max( 1, nh ) .AND. .NOT.lquery ) THEN
         info = -8
      END IF
*
      IF( info.EQ.0 ) THEN
         nb = ilaenv( 1, 'SORGQR', ' ', nh, nh, nh, -1 )
         lwkopt = max( 1, nh )*nb
         work( 1 ) = lwkopt
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORGHR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
*     Shift the vectors which define the elementary reflectors one
*     column to the right, and set the first ilo and the last n-ihi
*     rows and columns to those of the unit matrix
*
      DO 40 j = ihi, ilo + 1, -1
         DO 10 i = 1, j - 1
            a( i, j ) = zero
   10    CONTINUE
         DO 20 i = j + 1, ihi
            a( i, j ) = a( i, j-1 )
   20    CONTINUE
         DO 30 i = ihi + 1, n
            a( i, j ) = zero
   30    CONTINUE
   40 CONTINUE
      DO 60 j = 1, ilo
         DO 50 i = 1, n
            a( i, j ) = zero
   50    CONTINUE
         a( j, j ) = one
   60 CONTINUE
      DO 80 j = ihi + 1, n
         DO 70 i = 1, n
            a( i, j ) = zero
   70    CONTINUE
         a( j, j ) = one
   80 CONTINUE
*
      IF( nh.GT.0 ) THEN
*
*        Generate Q(ilo+1:ihi,ilo+1:ihi)
*
         CALL sorgqr( nh, nh, nh, a( ilo+1, ilo+1 ), lda, tau( ilo ),
     $                work, lwork, iinfo )
      END IF
      work( 1 ) = lwkopt
      RETURN
*
*     End of SORGHR
*

Here is the call graph for this function:

Here is the caller graph for this function: