subroutine dpstf2	(	character	UPLO,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( n )	PIV,
		integer	RANK,
		double precision	TOL,
		double precision, dimension( 2*n )	WORK,
		integer	INFO
	)

DPSTF2 computes the Cholesky factorization with complete pivoting of a real symmetric positive semidefinite matrix.

Download DPSTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DPSTF2 computes the Cholesky factorization with complete
 pivoting of a real symmetric positive semidefinite matrix A.

 The factorization has the form
    P**T * A * P = U**T * U ,  if UPLO = 'U',
    P**T * A * P = L  * L**T,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular, and
 P is stored as vector PIV.

 This algorithm does not attempt to check that A is positive
 semidefinite. This version of the algorithm calls level 2 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading n by n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the factor U or L from the Cholesky factorization as above.
[out]	PIV	PIV is INTEGER array, dimension (N) PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
[out]	RANK	RANK is INTEGER The rank of A given by the number of steps the algorithm completed.
[in]	TOL	TOL is DOUBLE PRECISION User defined tolerance. If TOL < 0, then N*U*MAX( A( K,K ) ) will be used. The algorithm terminates at the (K-1)st step if the pivot <= TOL.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N) Work space.
[out]	INFO	INFO is INTEGER < 0: If INFO = -K, the K-th argument had an illegal value, = 0: algorithm completed successfully, and > 0: the matrix A is either rank deficient with computed rank as returned in RANK, or is not positive semidefinite. See Section 7 of LAPACK Working Note #161 for further information.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2015

Definition at line 143 of file dpstf2.f.

*
*  -- LAPACK computational routine (version 3.6.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2015
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   tol
      INTEGER            info, lda, n, rank
      CHARACTER          uplo
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), work( 2*n )
      INTEGER            piv( n )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ajj, dstop, dtemp
      INTEGER            i, itemp, j, pvt
      LOGICAL            upper
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      LOGICAL            lsame, disnan
      EXTERNAL           dlamch, lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv, dscal, dswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt, maxloc
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPSTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Initialize PIV
*
      DO 100 i = 1, n
         piv( i ) = i
  100 CONTINUE
*
*     Compute stopping value
*
      pvt = 1
      ajj = a( pvt, pvt )
      DO i = 2, n
         IF( a( i, i ).GT.ajj ) THEN
            pvt = i
            ajj = a( pvt, pvt )
         END IF
      END DO
      IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
         rank = 0
         info = 1
         GO TO 170
      END IF
*
*     Compute stopping value if not supplied
*
      IF( tol.LT.zero ) THEN
         dstop = n * dlamch( 'Epsilon' ) * ajj
      ELSE
         dstop = tol
      END IF
*
*     Set first half of WORK to zero, holds dot products
*
      DO 110 i = 1, n
         work( i ) = 0
  110 CONTINUE
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization P**T * A * P = U**T * U
*
         DO 130 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 120 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) + a( j-1, i )**2
               END IF
               work( n+i ) = a( i, i ) - work( i )
*
  120       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 160
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL dswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
               IF( pvt.LT.n )
     $            CALL dswap( n-pvt, a( j, pvt+1 ), lda,
     $                        a( pvt, pvt+1 ), lda )
               CALL dswap( pvt-j-1, a( j, j+1 ), lda, a( j+1, pvt ), 1 )
*
*              Swap dot products and PIV
*
               dtemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = dtemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J
*
            IF( j.LT.n ) THEN
               CALL dgemv( 'Trans', j-1, n-j, -one, a( 1, j+1 ), lda,
     $                     a( 1, j ), 1, one, a( j, j+1 ), lda )
               CALL dscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
*
  130    CONTINUE
*
      ELSE
*
*        Compute the Cholesky factorization P**T * A * P = L * L**T
*
         DO 150 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 140 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) + a( i, j-1 )**2
               END IF
               work( n+i ) = a( i, i ) - work( i )
*
  140       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 160
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL dswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
               IF( pvt.LT.n )
     $            CALL dswap( n-pvt, a( pvt+1, j ), 1, a( pvt+1, pvt ),
     $                        1 )
               CALL dswap( pvt-j-1, a( j+1, j ), 1, a( pvt, j+1 ), lda )
*
*              Swap dot products and PIV
*
               dtemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = dtemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J
*
            IF( j.LT.n ) THEN
               CALL dgemv( 'No Trans', n-j, j-1, -one, a( j+1, 1 ), lda,
     $                     a( j, 1 ), lda, one, a( j+1, j ), 1 )
               CALL dscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
*
  150    CONTINUE
*
      END IF
*
*     Ran to completion, A has full rank
*
      rank = n
*
      GO TO 170
  160 CONTINUE
*
*     Rank is number of steps completed.  Set INFO = 1 to signal
*     that the factorization cannot be used to solve a system.
*
      rank = j - 1
      info = 1
*
  170 CONTINUE
      RETURN
*
*     End of DPSTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: