subroutine dtpqrt	(	integer	M,
		integer	N,
		integer	L,
		integer	NB,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision, dimension( ldt, * )	T,
		integer	LDT,
		double precision, dimension( * )	WORK,
		integer	INFO
	)

DTPQRT

Download DTPQRT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DTPQRT computes a blocked QR factorization of a real 
 "triangular-pentagonal" matrix C, which is composed of a 
 triangular block A and pentagonal block B, using the compact 
 WY representation for Q.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix B. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix B, and the order of the triangular matrix A. N >= 0.
[in]	L	L is INTEGER The number of rows of the upper trapezoidal part of B. MIN(M,N) >= L >= 0. See Further Details.
[in]	NB	NB is INTEGER The block size to be used in the blocked QR. N >= NB >= 1.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the upper triangular N-by-N matrix A. On exit, the elements on and above the diagonal of the array contain the upper triangular matrix R.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in,out]	B	B is DOUBLE PRECISION array, dimension (LDB,N) On entry, the pentagonal M-by-N matrix B. The first M-L rows are rectangular, and the last L rows are upper trapezoidal. On exit, B contains the pentagonal matrix V. See Further Details.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[out]	T	T is DOUBLE PRECISION array, dimension (LDT,N) The upper triangular block reflectors stored in compact form as a sequence of upper triangular blocks. See Further Details.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= NB.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (NB*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2013

Further Details:

  The input matrix C is a (N+M)-by-N matrix  

               C = [ A ]
                   [ B ]        

  where A is an upper triangular N-by-N matrix, and B is M-by-N pentagonal
  matrix consisting of a (M-L)-by-N rectangular matrix B1 on top of a L-by-N
  upper trapezoidal matrix B2:

               B = [ B1 ]  <- (M-L)-by-N rectangular
                   [ B2 ]  <-     L-by-N upper trapezoidal.

  The upper trapezoidal matrix B2 consists of the first L rows of a
  N-by-N upper triangular matrix, where 0 <= L <= MIN(M,N).  If L=0, 
  B is rectangular M-by-N; if M=L=N, B is upper triangular.  

  The matrix W stores the elementary reflectors H(i) in the i-th column
  below the diagonal (of A) in the (N+M)-by-N input matrix C

               C = [ A ]  <- upper triangular N-by-N
                   [ B ]  <- M-by-N pentagonal

  so that W can be represented as

               W = [ I ]  <- identity, N-by-N
                   [ V ]  <- M-by-N, same form as B.

  Thus, all of information needed for W is contained on exit in B, which
  we call V above.  Note that V has the same form as B; that is, 

               V = [ V1 ] <- (M-L)-by-N rectangular
                   [ V2 ] <-     L-by-N upper trapezoidal.

  The columns of V represent the vectors which define the H(i)'s.  

  The number of blocks is B = ceiling(N/NB), where each
  block is of order NB except for the last block, which is of order 
  IB = N - (B-1)*NB.  For each of the B blocks, a upper triangular block
  reflector factor is computed: T1, T2, ..., TB.  The NB-by-NB (and IB-by-IB 
  for the last block) T's are stored in the NB-by-N matrix T as

               T = [T1 T2 ... TB].

Definition at line 191 of file dtpqrt.f.

*
*  -- LAPACK computational routine (version 3.5.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2013
*
*     .. Scalar Arguments ..
      INTEGER info, lda, ldb, ldt, n, m, l, nb
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION a( lda, * ), b( ldb, * ), t( ldt, * ), work( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      INTEGER    i, ib, lb, mb, iinfo
*     ..
*     .. External Subroutines ..
      EXTERNAL   dtpqrt2, dtprfb, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( l.LT.0 .OR. (l.GT.min(m,n) .AND. min(m,n).GE.0)) THEN
         info = -3
      ELSE IF( nb.LT.1 .OR. (nb.GT.n .AND. n.GT.0)) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -8
      ELSE IF( ldt.LT.nb ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DTPQRT', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) RETURN
*
      DO i = 1, n, nb
*     
*     Compute the QR factorization of the current block
*
         ib = min( n-i+1, nb )
         mb = min( m-l+i+ib-1, m )
         IF( i.GE.l ) THEN
            lb = 0
         ELSE
            lb = mb-m+l-i+1
         END IF
*
         CALL dtpqrt2( mb, ib, lb, a(i,i), lda, b( 1, i ), ldb, 
     $                 t(1, i ), ldt, iinfo )
*
*     Update by applying H**T to B(:,I+IB:N) from the left
*
         IF( i+ib.LE.n ) THEN
            CALL dtprfb( 'L', 'T', 'F', 'C', mb, n-i-ib+1, ib, lb,
     $                    b( 1, i ), ldb, t( 1, i ), ldt, 
     $                    a( i, i+ib ), lda, b( 1, i+ib ), ldb, 
     $                    work, ib )
         END IF
      END DO
      RETURN
*     
*     End of DTPQRT
*

Here is the call graph for this function:

Here is the caller graph for this function: