subroutine stest	(	integer	LEN,
		real, dimension(len)	SCOMP,
		real, dimension(len)	STRUE,
		real, dimension(len)	SSIZE,
		real	SFAC
	)

Definition at line 891 of file sblat1.f.

*     ********************************* STEST **************************
*
*     THIS SUBR COMPARES ARRAYS  SCOMP() AND STRUE() OF LENGTH LEN TO
*     SEE IF THE TERM BY TERM DIFFERENCES, MULTIPLIED BY SFAC, ARE
*     NEGLIGIBLE.
*
*     C. L. LAWSON, JPL, 1974 DEC 10
*
*     .. Parameters ..
      INTEGER          nout
      REAL             zero
      parameter            (nout=6, zero=0.0e0)
*     .. Scalar Arguments ..
      REAL             sfac
      INTEGER          len
*     .. Array Arguments ..
      REAL             scomp(len), ssize(len), strue(len)
*     .. Scalars in Common ..
      INTEGER          icase, incx, incy, n
      LOGICAL          pass
*     .. Local Scalars ..
      REAL             sd
      INTEGER          i
*     .. External Functions ..
      REAL             sdiff
      EXTERNAL         sdiff
*     .. Intrinsic Functions ..
      INTRINSIC        abs
*     .. Common blocks ..
      COMMON           /combla/icase, n, incx, incy, pass
*     .. Executable Statements ..
*
      DO 40 i = 1, len
         sd = scomp(i) - strue(i)
         IF (abs(sfac*sd) .LE. abs(ssize(i))*epsilon(zero))
     +       GO TO 40
*
*                             HERE    SCOMP(I) IS NOT CLOSE TO STRUE(I).
*
         IF ( .NOT. pass) GO TO 20
*                             PRINT FAIL MESSAGE AND HEADER.
         pass = .false.
         WRITE (nout,99999)
         WRITE (nout,99998)
   20    WRITE (nout,99997) icase, n, incx, incy, i, scomp(i),
     +     strue(i), sd, ssize(i)
   40 CONTINUE
      RETURN
*
99999 FORMAT ('                                       FAIL')
99998 FORMAT (/' CASE  N INCX INCY  I                            ',
     +       ' COMP(I)                             TRUE(I)  DIFFERENCE',
     +       '     SIZE(I)',/1x)
99997 FORMAT (1x,i4,i3,2i5,i3,2e36.8,2e12.4)