subroutine dbdt03	(	character	UPLO,
		integer	N,
		integer	KD,
		double precision, dimension( * )	D,
		double precision, dimension( * )	E,
		double precision, dimension( ldu, * )	U,
		integer	LDU,
		double precision, dimension( * )	S,
		double precision, dimension( ldvt, * )	VT,
		integer	LDVT,
		double precision, dimension( * )	WORK,
		double precision	RESID
	)

DBDT03

Purpose:

 DBDT03 reconstructs a bidiagonal matrix B from its SVD:
    S = U' * B * V
 where U and V are orthogonal matrices and S is diagonal.

 The test ratio to test the singular value decomposition is
    RESID = norm( B - U * S * VT ) / ( n * norm(B) * EPS )
 where VT = V' and EPS is the machine precision.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the matrix B is upper or lower bidiagonal. = 'U': Upper bidiagonal = 'L': Lower bidiagonal
[in]	N	N is INTEGER The order of the matrix B.
[in]	KD	KD is INTEGER The bandwidth of the bidiagonal matrix B. If KD = 1, the matrix B is bidiagonal, and if KD = 0, B is diagonal and E is not referenced. If KD is greater than 1, it is assumed to be 1, and if KD is less than 0, it is assumed to be 0.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The n diagonal elements of the bidiagonal matrix B.
[in]	E	E is DOUBLE PRECISION array, dimension (N-1) The (n-1) superdiagonal elements of the bidiagonal matrix B if UPLO = 'U', or the (n-1) subdiagonal elements of B if UPLO = 'L'.
[in]	U	U is DOUBLE PRECISION array, dimension (LDU,N) The n by n orthogonal matrix U in the reduction B = U'*A*P.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,N)
[in]	S	S is DOUBLE PRECISION array, dimension (N) The singular values from the SVD of B, sorted in decreasing order.
[in]	VT	VT is DOUBLE PRECISION array, dimension (LDVT,N) The n by n orthogonal matrix V' in the reduction B = U * S * V'.
[in]	LDVT	LDVT is INTEGER The leading dimension of the array VT.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N)
[out]	RESID	RESID is DOUBLE PRECISION The test ratio: norm(B - U * S * V') / ( n * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 137 of file dbdt03.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            kd, ldu, ldvt, n
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   d( * ), e( * ), s( * ), u( ldu, * ),
     $                   vt( ldvt, * ), work( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      DOUBLE PRECISION   bnorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            idamax
      DOUBLE PRECISION   dasum, dlamch
      EXTERNAL           lsame, idamax, dasum, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      resid = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Compute B - U * S * V' one column at a time.
*
      bnorm = zero
      IF( kd.GE.1 ) THEN
*
*        B is bidiagonal.
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           B is upper bidiagonal.
*
            DO 20 j = 1, n
               DO 10 i = 1, n
                  work( n+i ) = s( i )*vt( i, j )
   10          CONTINUE
               CALL dgemv( 'No transpose', n, n, -one, u, ldu,
     $                     work( n+1 ), 1, zero, work, 1 )
               work( j ) = work( j ) + d( j )
               IF( j.GT.1 ) THEN
                  work( j-1 ) = work( j-1 ) + e( j-1 )
                  bnorm = max( bnorm, abs( d( j ) )+abs( e( j-1 ) ) )
               ELSE
                  bnorm = max( bnorm, abs( d( j ) ) )
               END IF
               resid = max( resid, dasum( n, work, 1 ) )
   20       CONTINUE
         ELSE
*
*           B is lower bidiagonal.
*
            DO 40 j = 1, n
               DO 30 i = 1, n
                  work( n+i ) = s( i )*vt( i, j )
   30          CONTINUE
               CALL dgemv( 'No transpose', n, n, -one, u, ldu,
     $                     work( n+1 ), 1, zero, work, 1 )
               work( j ) = work( j ) + d( j )
               IF( j.LT.n ) THEN
                  work( j+1 ) = work( j+1 ) + e( j )
                  bnorm = max( bnorm, abs( d( j ) )+abs( e( j ) ) )
               ELSE
                  bnorm = max( bnorm, abs( d( j ) ) )
               END IF
               resid = max( resid, dasum( n, work, 1 ) )
   40       CONTINUE
         END IF
      ELSE
*
*        B is diagonal.
*
         DO 60 j = 1, n
            DO 50 i = 1, n
               work( n+i ) = s( i )*vt( i, j )
   50       CONTINUE
            CALL dgemv( 'No transpose', n, n, -one, u, ldu, work( n+1 ),
     $                  1, zero, work, 1 )
            work( j ) = work( j ) + d( j )
            resid = max( resid, dasum( n, work, 1 ) )
   60    CONTINUE
         j = idamax( n, d, 1 )
         bnorm = abs( d( j ) )
      END IF
*
*     Compute norm(B - U * S * V') / ( n * norm(B) * EPS )
*
      eps = dlamch( 'Precision' )
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( dble( n )*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, dble( n )*bnorm ) / bnorm ) /
     $                 ( dble( n )*eps )
            ELSE
               resid = min( resid / bnorm, dble( n ) ) /
     $                 ( dble( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of DBDT03
*

Here is the call graph for this function:

Here is the caller graph for this function: