subroutine dget51	(	integer	ITYPE,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision, dimension( ldu, * )	U,
		integer	LDU,
		double precision, dimension( ldv, * )	V,
		integer	LDV,
		double precision, dimension( * )	WORK,
		double precision	RESULT
	)

DGET51

Purpose:

      DGET51  generally checks a decomposition of the form

              A = U B V'

      where ' means transpose and U and V are orthogonal.

      Specifically, if ITYPE=1

              RESULT = | A - U B V' | / ( |A| n ulp )

      If ITYPE=2, then:

              RESULT = | A - B | / ( |A| n ulp )

      If ITYPE=3, then:

              RESULT = | I - UU' | / ( n ulp )

Parameters

[in]	ITYPE	ITYPE is INTEGER Specifies the type of tests to be performed. =1: RESULT = | A - U B V' | / ( |A| n ulp ) =2: RESULT = | A - B | / ( |A| n ulp ) =3: RESULT = | I - UU' | / ( n ulp )
[in]	N	N is INTEGER The size of the matrix. If it is zero, DGET51 does nothing. It must be at least zero.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA, N) The original (unfactored) matrix.
[in]	LDA	LDA is INTEGER The leading dimension of A. It must be at least 1 and at least N.
[in]	B	B is DOUBLE PRECISION array, dimension (LDB, N) The factored matrix.
[in]	LDB	LDB is INTEGER The leading dimension of B. It must be at least 1 and at least N.
[in]	U	U is DOUBLE PRECISION array, dimension (LDU, N) The orthogonal matrix on the left-hand side in the decomposition. Not referenced if ITYPE=2
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N and at least 1.
[in]	V	V is DOUBLE PRECISION array, dimension (LDV, N) The orthogonal matrix on the left-hand side in the decomposition. Not referenced if ITYPE=2
[in]	LDV	LDV is INTEGER The leading dimension of V. LDV must be at least N and at least 1.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N**2)
[out]	RESULT	RESULT is DOUBLE PRECISION The values computed by the test specified by ITYPE. The value is currently limited to 1/ulp, to avoid overflow. Errors are flagged by RESULT=10/ulp.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 151 of file dget51.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            itype, lda, ldb, ldu, ldv, n
      DOUBLE PRECISION   result
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), u( ldu, * ),
     $                   v( ldv, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one, ten
      parameter                ( zero = 0.0d0, one = 1.0d0, ten = 10.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            jcol, jdiag, jrow
      DOUBLE PRECISION   anorm, ulp, unfl, wnorm
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      result = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Constants
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
*     Some Error Checks
*
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         result = ten / ulp
         RETURN
      END IF
*
      IF( itype.LE.2 ) THEN
*
*        Tests scaled by the norm(A)
*
         anorm = max( dlange( '1', n, n, a, lda, work ), unfl )
*
         IF( itype.EQ.1 ) THEN
*
*           ITYPE=1: Compute W = A - UBV'
*
            CALL dlacpy( ' ', n, n, a, lda, work, n )
            CALL dgemm( 'N', 'N', n, n, n, one, u, ldu, b, ldb, zero,
     $                  work( n**2+1 ), n )
*
            CALL dgemm( 'N', 'C', n, n, n, -one, work( n**2+1 ), n, v,
     $                  ldv, one, work, n )
*
         ELSE
*
*           ITYPE=2: Compute W = A - B
*
            CALL dlacpy( ' ', n, n, b, ldb, work, n )
*
            DO 20 jcol = 1, n
               DO 10 jrow = 1, n
                  work( jrow+n*( jcol-1 ) ) = work( jrow+n*( jcol-1 ) )
     $                - a( jrow, jcol )
   10          CONTINUE
   20       CONTINUE
         END IF
*
*        Compute norm(W)/ ( ulp*norm(A) )
*
         wnorm = dlange( '1', n, n, work, n, work( n**2+1 ) )
*
         IF( anorm.GT.wnorm ) THEN
            result = ( wnorm / anorm ) / ( n*ulp )
         ELSE
            IF( anorm.LT.one ) THEN
               result = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
            ELSE
               result = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
            END IF
         END IF
*
      ELSE
*
*        Tests not scaled by norm(A)
*
*        ITYPE=3: Compute  UU' - I
*
         CALL dgemm( 'N', 'C', n, n, n, one, u, ldu, u, ldu, zero, work,
     $               n )
*
         DO 30 jdiag = 1, n
            work( ( n+1 )*( jdiag-1 )+1 ) = work( ( n+1 )*( jdiag-1 )+
     $         1 ) - one
   30    CONTINUE
*
         result = min( dlange( '1', n, n, work, n, work( n**2+1 ) ),
     $            dble( n ) ) / ( n*ulp )
      END IF
*
      RETURN
*
*     End of DGET51
*

Here is the call graph for this function:

Here is the caller graph for this function: