subroutine dstect	(	integer	N,
		double precision, dimension( * )	A,
		double precision, dimension( * )	B,
		double precision	SHIFT,
		integer	NUM
	)

DSTECT

Purpose:

    DSTECT counts the number NUM of eigenvalues of a tridiagonal
    matrix T which are less than or equal to SHIFT. T has
    diagonal entries A(1), ... , A(N), and offdiagonal entries
    B(1), ..., B(N-1).
    See W. Kahan "Accurate Eigenvalues of a Symmetric Tridiagonal
    Matrix", Report CS41, Computer Science Dept., Stanford
    University, July 21, 1966

Parameters

[in]	N	N is INTEGER The dimension of the tridiagonal matrix T.
[in]	A	A is DOUBLE PRECISION array, dimension (N) The diagonal entries of the tridiagonal matrix T.
[in]	B	B is DOUBLE PRECISION array, dimension (N-1) The offdiagonal entries of the tridiagonal matrix T.
[in]	SHIFT	SHIFT is DOUBLE PRECISION The shift, used as described under Purpose.
[out]	NUM	NUM is INTEGER The number of eigenvalues of T less than or equal to SHIFT.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 84 of file dstect.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            n, num
      DOUBLE PRECISION   shift
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( * ), b( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one, three
      parameter                ( zero = 0.0d0, one = 1.0d0, three = 3.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      DOUBLE PRECISION   m1, m2, mx, ovfl, sov, sshift, ssun, sun, tmp,
     $                   tom, u, unfl
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Get machine constants
*
      unfl = dlamch( 'Safe minimum' )
      ovfl = dlamch( 'Overflow' )
*
*     Find largest entry
*
      mx = abs( a( 1 ) )
      DO 10 i = 1, n - 1
         mx = max( mx, abs( a( i+1 ) ), abs( b( i ) ) )
   10 CONTINUE
*
*     Handle easy cases, including zero matrix
*
      IF( shift.GE.three*mx ) THEN
         num = n
         RETURN
      END IF
      IF( shift.LT.-three*mx ) THEN
         num = 0
         RETURN
      END IF
*
*     Compute scale factors as in Kahan's report
*     At this point, MX .NE. 0 so we can divide by it
*
      sun = sqrt( unfl )
      ssun = sqrt( sun )
      sov = sqrt( ovfl )
      tom = ssun*sov
      IF( mx.LE.one ) THEN
         m1 = one / mx
         m2 = tom
      ELSE
         m1 = one
         m2 = tom / mx
      END IF
*
*     Begin counting
*
      num = 0
      sshift = ( shift*m1 )*m2
      u = ( a( 1 )*m1 )*m2 - sshift
      IF( u.LE.sun ) THEN
         IF( u.LE.zero ) THEN
            num = num + 1
            IF( u.GT.-sun )
     $         u = -sun
         ELSE
            u = sun
         END IF
      END IF
      DO 20 i = 2, n
         tmp = ( b( i-1 )*m1 )*m2
         u = ( ( a( i )*m1 )*m2-tmp*( tmp / u ) ) - sshift
         IF( u.LE.sun ) THEN
            IF( u.LE.zero ) THEN
               num = num + 1
               IF( u.GT.-sun )
     $            u = -sun
            ELSE
               u = sun
            END IF
         END IF
   20 CONTINUE
      RETURN
*
*     End of DSTECT
*

Here is the caller graph for this function: