subroutine dbdt04	(	character	UPLO,
		integer	N,
		double precision, dimension( * )	D,
		double precision, dimension( * )	E,
		double precision, dimension( * )	S,
		integer	NS,
		double precision, dimension( ldu, * )	U,
		integer	LDU,
		double precision, dimension( ldvt, * )	VT,
		integer	LDVT,
		double precision, dimension( * )	WORK,
		double precision	RESID
	)

Purpose:

DBDT04 reconstructs a bidiagonal matrix B from its (partial) SVD: S = U' * B * V where U and V are orthogonal matrices and S is diagonal.

The test ratio to test the singular value decomposition is RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS ) where VT = V' and EPS is the machine precision.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the matrix B is upper or lower bidiagonal. = 'U': Upper bidiagonal = 'L': Lower bidiagonal
[in]	N	N is INTEGER The order of the matrix B.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The n diagonal elements of the bidiagonal matrix B.
[in]	E	E is DOUBLE PRECISION array, dimension (N-1) The (n-1) superdiagonal elements of the bidiagonal matrix B if UPLO = 'U', or the (n-1) subdiagonal elements of B if UPLO = 'L'.
[in]	S	S is DOUBLE PRECISION array, dimension (NS) The singular values from the (partial) SVD of B, sorted in decreasing order.
[in]	NS	NS is INTEGER The number of singular values/vectors from the (partial) SVD of B.
[in]	U	U is DOUBLE PRECISION array, dimension (LDU,NS) The n by ns orthogonal matrix U in S = U' * B * V.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,N)
[in]	VT	VT is DOUBLE PRECISION array, dimension (LDVT,N) The n by ns orthogonal matrix V in S = U' * B * V.
[in]	LDVT	LDVT is INTEGER The leading dimension of the array VT.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N)
[out]	RESID	RESID is DOUBLE PRECISION The test ratio: norm(S - U' * B * V) / ( n * norm(B) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 132 of file dbdt04.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldu, ldvt, n, ns
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   d( * ), e( * ), s( * ), u( ldu, * ),
     $                   vt( ldvt, * ), work( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      DOUBLE PRECISION   bnorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            idamax
      DOUBLE PRECISION   dasum, dlamch
      EXTERNAL           lsame, idamax, dasum, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      resid = zero
      IF( n.LE.0 .OR. ns.LE.0 )
     $   RETURN
*
      eps = dlamch( 'Precision' )
*
*     Compute S - U' * B * V.
*
      bnorm = zero
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        B is upper bidiagonal.
*
         k = 0
         DO 20 i = 1, ns
            DO 10 j = 1, n-1
               k = k + 1
               work( k ) = d( j )*vt( i, j ) + e( j )*vt( i, j+1 )
   10       CONTINUE
            k = k + 1
            work( k ) = d( n )*vt( i, n )
   20    CONTINUE
         bnorm = abs( d( 1 ) )
         DO 30 i = 2, n
            bnorm = max( bnorm, abs( d( i ) )+abs( e( i-1 ) ) )
   30    CONTINUE
      ELSE
*
*        B is lower bidiagonal.
*
         k = 0
         DO 50 i = 1, ns
            k = k + 1
            work( k ) = d( 1 )*vt( i, 1 )
            DO 40 j = 1, n-1
               k = k + 1
               work( k ) = e( j )*vt( i, j ) + d( j+1 )*vt( i, j+1 )
   40       CONTINUE
   50    CONTINUE
         bnorm = abs( d( n ) )
         DO 60 i = 1, n-1
            bnorm = max( bnorm, abs( d( i ) )+abs( e( i ) ) )
   60    CONTINUE
      END IF
*
      CALL dgemm( 'T', 'N', ns, ns, n, -one, u, ldu, work( 1 ),
     $            n, zero, work( 1+n*ns ), ns )
*
*     norm(S - U' * B * V)
*
      k = n*ns
      DO 70 i = 1, ns
         work( k+i ) =  work( k+i ) + s( i )
         resid = max( resid, dasum( ns, work( k+1 ), 1 ) )
         k = k + ns
   70 CONTINUE
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( dble( n )*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, dble( n )*bnorm ) / bnorm ) /
     $                 ( dble( n )*eps )
            ELSE
               resid = min( resid / bnorm, dble( n ) ) /
     $                 ( dble( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of DBDT04
*

Here is the call graph for this function:

Here is the caller graph for this function: