dsgt01.f

Go to the documentation of this file.

*> \brief \b DSGT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DSGT01( ITYPE, UPLO, N, M, A, LDA, B, LDB, Z, LDZ, D,
*                          WORK, RESULT )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            ITYPE, LDA, LDB, LDZ, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), D( * ), RESULT( * ),
*      $                   WORK( * ), Z( LDZ, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DDGT01 checks a decomposition of the form
*>
*>    A Z   =  B Z D or
*>    A B Z =  Z D or
*>    B A Z =  Z D
*>
*> where A is a symmetric matrix, B is
*> symmetric positive definite, Z is orthogonal, and D is diagonal.
*>
*> One of the following test ratios is computed:
*>
*> ITYPE = 1:  RESULT(1) = | A Z - B Z D | / ( |A| |Z| n ulp )
*>
*> ITYPE = 2:  RESULT(1) = | A B Z - Z D | / ( |A| |Z| n ulp )
*>
*> ITYPE = 3:  RESULT(1) = | B A Z - Z D | / ( |A| |Z| n ulp )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ITYPE
*> \verbatim
*>          ITYPE is INTEGER
*>          The form of the symmetric generalized eigenproblem.
*>          = 1:  A*z = (lambda)*B*z
*>          = 2:  A*B*z = (lambda)*z
*>          = 3:  B*A*z = (lambda)*z
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrices A and B is stored.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of eigenvalues found.  0 <= M <= N.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA, N)
*>          The original symmetric matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB, N)
*>          The original symmetric positive definite matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (LDZ, M)
*>          The computed eigenvectors of the generalized eigenproblem.
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDZ >= max(1,N).
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (M)
*>          The computed eigenvalues of the generalized eigenproblem.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (N*N)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (1)
*>          The test ratio as described above.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dsgt01( ITYPE, UPLO, N, M, A, LDA, B, LDB, Z, LDZ, D,
     $                   work, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            itype, lda, ldb, ldz, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), d( * ), result( * ),
     $                   work( * ), z( ldz, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      DOUBLE PRECISION   anorm, ulp
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange, dlansy
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dsymm
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      IF( n.LE.0 )
     $   return
*
      ulp = dlamch( 'Epsilon' )
*
*     Compute product of 1-norms of A and Z.
*
      anorm = dlansy( '1', uplo, n, a, lda, work )*
     $        dlange( '1', n, m, z, ldz, work )
      IF( anorm.EQ.zero )
     $   anorm = one
*
      IF( itype.EQ.1 ) THEN
*
*        Norm of AZ - BZD
*
         CALL dsymm( 'Left', uplo, n, m, one, a, lda, z, ldz, zero,
     $               work, n )
         DO 10 i = 1, m
            CALL dscal( n, d( i ), z( 1, i ), 1 )
   10    continue
         CALL dsymm( 'Left', uplo, n, m, one, b, ldb, z, ldz, -one,
     $               work, n )
*
         result( 1 ) = ( dlange( '1', n, m, work, n, work ) / anorm ) /
     $                 ( n*ulp )
*
      ELSE IF( itype.EQ.2 ) THEN
*
*        Norm of ABZ - ZD
*
         CALL dsymm( 'Left', uplo, n, m, one, b, ldb, z, ldz, zero,
     $               work, n )
         DO 20 i = 1, m
            CALL dscal( n, d( i ), z( 1, i ), 1 )
   20    continue
         CALL dsymm( 'Left', uplo, n, m, one, a, lda, work, n, -one, z,
     $               ldz )
*
         result( 1 ) = ( dlange( '1', n, m, z, ldz, work ) / anorm ) /
     $                 ( n*ulp )
*
      ELSE IF( itype.EQ.3 ) THEN
*
*        Norm of BAZ - ZD
*
         CALL dsymm( 'Left', uplo, n, m, one, a, lda, z, ldz, zero,
     $               work, n )
         DO 30 i = 1, m
            CALL dscal( n, d( i ), z( 1, i ), 1 )
   30    continue
         CALL dsymm( 'Left', uplo, n, m, one, b, ldb, work, n, -one, z,
     $               ldz )
*
         result( 1 ) = ( dlange( '1', n, m, z, ldz, work ) / anorm ) /
     $                 ( n*ulp )
      END IF
*
      return
*
*     End of DDGT01
*
      END