sdrvgg.f

Go to the documentation of this file.

*> \brief \b SDRVGG
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SDRVGG( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          THRSHN, NOUNIT, A, LDA, B, S, T, S2, T2, Q,
*                          LDQ, Z, ALPHR1, ALPHI1, BETA1, ALPHR2, ALPHI2,
*                          BETA2, VL, VR, WORK, LWORK, RESULT, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDQ, LWORK, NOUNIT, NSIZES, NTYPES
*       REAL               THRESH, THRSHN
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            ISEED( 4 ), NN( * )
*       REAL               A( LDA, * ), ALPHI1( * ), ALPHI2( * ),
*      $                   ALPHR1( * ), ALPHR2( * ), B( LDA, * ),
*      $                   BETA1( * ), BETA2( * ), Q( LDQ, * ),
*      $                   RESULT( * ), S( LDA, * ), S2( LDA, * ),
*      $                   T( LDA, * ), T2( LDA, * ), VL( LDQ, * ),
*      $                   VR( LDQ, * ), WORK( * ), Z( LDQ, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SDRVGG  checks the nonsymmetric generalized eigenvalue driver
*> routines.
*>                               T          T        T
*> SGEGS factors A and B as Q S Z  and Q T Z , where   means
*> transpose, T is upper triangular, S is in generalized Schur form
*> (block upper triangular, with 1x1 and 2x2 blocks on the diagonal,
*> the 2x2 blocks corresponding to complex conjugate pairs of
*> generalized eigenvalues), and Q and Z are orthogonal.  It also
*> computes the generalized eigenvalues (alpha(1),beta(1)), ...,
*> (alpha(n),beta(n)), where alpha(j)=S(j,j) and beta(j)=P(j,j) --
*> thus, w(j) = alpha(j)/beta(j) is a root of the generalized
*> eigenvalue problem
*>
*>     det( A - w(j) B ) = 0
*>
*> and m(j) = beta(j)/alpha(j) is a root of the essentially equivalent
*> problem
*>
*>     det( m(j) A - B ) = 0
*>
*> SGEGV computes the generalized eigenvalues (alpha(1),beta(1)), ...,
*> (alpha(n),beta(n)), the matrix L whose columns contain the
*> generalized left eigenvectors l, and the matrix R whose columns
*> contain the generalized right eigenvectors r for the pair (A,B).
*>
*> When SDRVGG is called, a number of matrix "sizes" ("n's") and a
*> number of matrix "types" are specified.  For each size ("n")
*> and each type of matrix, one matrix will be generated and used
*> to test the nonsymmetric eigenroutines.  For each matrix, 7
*> tests will be performed and compared with the threshhold THRESH:
*>
*> Results from SGEGS:
*>
*>                  T
*> (1)   | A - Q S Z  | / ( |A| n ulp )
*>
*>                  T
*> (2)   | B - Q T Z  | / ( |B| n ulp )
*>
*>               T
*> (3)   | I - QQ  | / ( n ulp )
*>
*>               T
*> (4)   | I - ZZ  | / ( n ulp )
*>
*> (5)   maximum over j of D(j)  where:
*>
*> if alpha(j) is real:
*>                     |alpha(j) - S(j,j)|        |beta(j) - T(j,j)|
*>           D(j) = ------------------------ + -----------------------
*>                  max(|alpha(j)|,|S(j,j)|)   max(|beta(j)|,|T(j,j)|)
*>
*> if alpha(j) is complex:
*>                                 | det( s S - w T ) |
*>           D(j) = ---------------------------------------------------
*>                  ulp max( s norm(S), |w| norm(T) )*norm( s S - w T )
*>
*>           and S and T are here the 2 x 2 diagonal blocks of S and T
*>           corresponding to the j-th eigenvalue.
*>
*> Results from SGEGV:
*>
*> (6)   max over all left eigenvalue/-vector pairs (beta/alpha,l) of
*>
*>    | l**H * (beta A - alpha B) | / ( ulp max( |beta A|, |alpha B| ) )
*>
*>       where l**H is the conjugate tranpose of l.
*>
*> (7)   max over all right eigenvalue/-vector pairs (beta/alpha,r) of
*>
*>       | (beta A - alpha B) r | / ( ulp max( |beta A|, |alpha B| ) )
*>
*> Test Matrices
*> ---- --------
*>
*> The sizes of the test matrices are specified by an array
*> NN(1:NSIZES); the value of each element NN(j) specifies one size.
*> The "types" are specified by a logical array DOTYPE( 1:NTYPES ); if
*> DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*> Currently, the list of possible types is:
*>
*> (1)  ( 0, 0 )         (a pair of zero matrices)
*>
*> (2)  ( I, 0 )         (an identity and a zero matrix)
*>
*> (3)  ( 0, I )         (an identity and a zero matrix)
*>
*> (4)  ( I, I )         (a pair of identity matrices)
*>
*>         t   t
*> (5)  ( J , J  )       (a pair of transposed Jordan blocks)
*>
*>                                     t                ( I   0  )
*> (6)  ( X, Y )         where  X = ( J   0  )  and Y = (      t )
*>                                  ( 0   I  )          ( 0   J  )
*>                       and I is a k x k identity and J a (k+1)x(k+1)
*>                       Jordan block; k=(N-1)/2
*>
*> (7)  ( D, I )         where D is diag( 0, 1,..., N-1 ) (a diagonal
*>                       matrix with those diagonal entries.)
*> (8)  ( I, D )
*>
*> (9)  ( big*D, small*I ) where "big" is near overflow and small=1/big
*>
*> (10) ( small*D, big*I )
*>
*> (11) ( big*I, small*D )
*>
*> (12) ( small*I, big*D )
*>
*> (13) ( big*D, big*I )
*>
*> (14) ( small*D, small*I )
*>
*> (15) ( D1, D2 )        where D1 is diag( 0, 0, 1, ..., N-3, 0 ) and
*>                        D2 is diag( 0, N-3, N-4,..., 1, 0, 0 )
*>           t   t
*> (16) Q ( J , J ) Z     where Q and Z are random orthogonal matrices.
*>
*> (17) Q ( T1, T2 ) Z    where T1 and T2 are upper triangular matrices
*>                        with random O(1) entries above the diagonal
*>                        and diagonal entries diag(T1) =
*>                        ( 0, 0, 1, ..., N-3, 0 ) and diag(T2) =
*>                        ( 0, N-3, N-4,..., 1, 0, 0 )
*>
*> (18) Q ( T1, T2 ) Z    diag(T1) = ( 0, 0, 1, 1, s, ..., s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1,..., 1, 0 )
*>                        s = machine precision.
*>
*> (19) Q ( T1, T2 ) Z    diag(T1)=( 0,0,1,1, 1-d, ..., 1-(N-5)*d=s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0 )
*>
*>                                                        N-5
*> (20) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, 1, a, ..., a   =s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>
*> (21) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, r1, r2, ..., r(N-4), 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>                        where r1,..., r(N-4) are random.
*>
*> (22) Q ( big*T1, small*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (23) Q ( small*T1, big*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (24) Q ( small*T1, small*T2 ) Z  diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (25) Q ( big*T1, big*T2 ) Z      diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (26) Q ( T1, T2 ) Z     where T1 and T2 are random upper-triangular
*>                         matrices.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of sizes of matrices to use.  If it is zero,
*>          SDRVGG does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER array, dimension (NSIZES)
*>          An array containing the sizes to be used for the matrices.
*>          Zero values will be skipped.  The values must be at least
*>          zero.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, SDRVGG
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated.  If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096.  Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to SDRVGG to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error is
*>          scaled to be O(1), so THRESH should be a reasonably small
*>          multiple of 1, e.g., 10 or 100.  In particular, it should
*>          not depend on the precision (single vs. double) or the size
*>          of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] THRSHN
*> \verbatim
*>          THRSHN is REAL
*>          Threshhold for reporting eigenvector normalization error.
*>          If the normalization of any eigenvector differs from 1 by
*>          more than THRSHN*ulp, then a special error message will be
*>          printed.  (This is handled separately from the other tests,
*>          since only a compiler or programming error should cause an
*>          error message, at least if THRSHN is at least 5--10.)
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns IINFO not equal to 0.)
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is REAL array, dimension
*>                            (LDA, max(NN))
*>          Used to hold the original A matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, B, S, T, S2, and T2.
*>          It must be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension
*>                            (LDA, max(NN))
*>          Used to hold the original B matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is REAL array, dimension (LDA, max(NN))
*>          The Schur form matrix computed from A by SGEGS.  On exit, S
*>          contains the Schur form matrix corresponding to the matrix
*>          in A.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is REAL array, dimension (LDA, max(NN))
*>          The upper triangular matrix computed from B by SGEGS.
*> \endverbatim
*>
*> \param[out] S2
*> \verbatim
*>          S2 is REAL array, dimension (LDA, max(NN))
*>          The matrix computed from A by SGEGV.  This will be the
*>          Schur form of some matrix related to A, but will not, in
*>          general, be the same as S.
*> \endverbatim
*>
*> \param[out] T2
*> \verbatim
*>          T2 is REAL array, dimension (LDA, max(NN))
*>          The matrix computed from B by SGEGV.  This will be the
*>          Schur form of some matrix related to B, but will not, in
*>          general, be the same as T.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is REAL array, dimension (LDQ, max(NN))
*>          The (left) orthogonal matrix computed by SGEGS.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>          The leading dimension of Q, Z, VL, and VR.  It must
*>          be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is REAL array of
*>                             dimension( LDQ, max(NN) )
*>          The (right) orthogonal matrix computed by SGEGS.
*> \endverbatim
*>
*> \param[out] ALPHR1
*> \verbatim
*>          ALPHR1 is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] ALPHI1
*> \verbatim
*>          ALPHI1 is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA1
*> \verbatim
*>          BETA1 is REAL array, dimension (max(NN))
*>
*>          The generalized eigenvalues of (A,B) computed by SGEGS.
*>          ( ALPHR1(k)+ALPHI1(k)*i ) / BETA1(k) is the k-th
*>          generalized eigenvalue of the matrices in A and B.
*> \endverbatim
*>
*> \param[out] ALPHR2
*> \verbatim
*>          ALPHR2 is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] ALPHI2
*> \verbatim
*>          ALPHI2 is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA2
*> \verbatim
*>          BETA2 is REAL array, dimension (max(NN))
*>
*>          The generalized eigenvalues of (A,B) computed by SGEGV.
*>          ( ALPHR2(k)+ALPHI2(k)*i ) / BETA2(k) is the k-th
*>          generalized eigenvalue of the matrices in A and B.
*> \endverbatim
*>
*> \param[out] VL
*> \verbatim
*>          VL is REAL array, dimension (LDQ, max(NN))
*>          The (block lower triangular) left eigenvector matrix for
*>          the matrices in A and B.  (See STGEVC for the format.)
*> \endverbatim
*>
*> \param[out] VR
*> \verbatim
*>          VR is REAL array, dimension (LDQ, max(NN))
*>          The (block upper triangular) right eigenvector matrix for
*>          the matrices in A and B.  (See STGEVC for the format.)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The number of entries in WORK.  This must be at least
*>          2*N + MAX( 6*N, N*(NB+1), (k+1)*(2*k+N+1) ), where
*>          "k" is the sum of the blocksize and number-of-shifts for
*>          SHGEQZ, and NB is the greatest of the blocksizes for
*>          SGEQRF, SORMQR, and SORGQR.  (The blocksizes and the
*>          number-of-shifts are retrieved through calls to ILAENV.)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (15)
*>          The values computed by the tests described above.
*>          The values are currently limited to 1/ulp, to avoid
*>          overflow.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  A routine returned an error code.  INFO is the
*>                absolute value of the INFO value returned.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE sdrvgg( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   thrshn, nounit, a, lda, b, s, t, s2, t2, q,
     $                   ldq, z, alphr1, alphi1, beta1, alphr2, alphi2,
     $                   beta2, vl, vr, work, lwork, result, info )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, ldq, lwork, nounit, nsizes, ntypes
      REAL               thresh, thrshn
*     ..
*     .. Array Arguments ..
      LOGICAL            dotype( * )
      INTEGER            iseed( 4 ), nn( * )
      REAL               a( lda, * ), alphi1( * ), alphi2( * ),
     $                   alphr1( * ), alphr2( * ), b( lda, * ),
     $                   beta1( * ), beta2( * ), q( ldq, * ),
     $                   result( * ), s( lda, * ), s2( lda, * ),
     $                   t( lda, * ), t2( lda, * ), vl( ldq, * ),
     $                   vr( ldq, * ), work( * ), z( ldq, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0, one = 1.0 )
      INTEGER            maxtyp
      parameter( maxtyp = 26 )
*     ..
*     .. Local Scalars ..
      LOGICAL            badnn, ilabad
      INTEGER            i1, iadd, iinfo, in, j, jc, jr, jsize, jtype,
     $                   lwkopt, mtypes, n, n1, nb, nbz, nerrs, nmats,
     $                   nmax, ns, ntest, ntestt
      REAL               safmax, safmin, temp1, temp2, ulp, ulpinv
*     ..
*     .. Local Arrays ..
      INTEGER            iasign( maxtyp ), ibsign( maxtyp ),
     $                   ioldsd( 4 ), kadd( 6 ), kamagn( maxtyp ),
     $                   katype( maxtyp ), kazero( maxtyp ),
     $                   kbmagn( maxtyp ), kbtype( maxtyp ),
     $                   kbzero( maxtyp ), kclass( maxtyp ),
     $                   ktrian( maxtyp ), kz1( 6 ), kz2( 6 )
      REAL               dumma( 4 ), rmagn( 0: 3 )
*     ..
*     .. External Functions ..
      INTEGER            ilaenv
      REAL               slamch, slarnd
      EXTERNAL           ilaenv, slamch, slarnd
*     ..
*     .. External Subroutines ..
      EXTERNAL           alasvm, sgegs, sgegv, sget51, sget52, sget53,
     $                   slabad, slacpy, slarfg, slaset, slatm4, sorm2r,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, REAL, sign
*     ..
*     .. Data statements ..
      DATA               kclass / 15*1, 10*2, 1*3 /
      DATA               kz1 / 0, 1, 2, 1, 3, 3 /
      DATA               kz2 / 0, 0, 1, 2, 1, 1 /
      DATA               kadd / 0, 0, 0, 0, 3, 2 /
      DATA               katype / 0, 1, 0, 1, 2, 3, 4, 1, 4, 4, 1, 1, 4,
     $                   4, 4, 2, 4, 5, 8, 7, 9, 4*4, 0 /
      DATA               kbtype / 0, 0, 1, 1, 2, -3, 1, 4, 1, 1, 4, 4,
     $                   1, 1, -4, 2, -4, 8*8, 0 /
      DATA               kazero / 6*1, 2, 1, 2*2, 2*1, 2*2, 3, 1, 3,
     $                   4*5, 4*3, 1 /
      DATA               kbzero / 6*1, 1, 2, 2*1, 2*2, 2*1, 4, 1, 4,
     $                   4*6, 4*4, 1 /
      DATA               kamagn / 8*1, 2, 3, 2, 3, 2, 3, 7*1, 2, 3, 3,
     $                   2, 1 /
      DATA               kbmagn / 8*1, 3, 2, 3, 2, 2, 3, 7*1, 3, 2, 3,
     $                   2, 1 /
      DATA               ktrian / 16*0, 10*1 /
      DATA               iasign / 6*0, 2, 0, 2*2, 2*0, 3*2, 0, 2, 3*0,
     $                   5*2, 0 /
      DATA               ibsign / 7*0, 2, 2*0, 2*2, 2*0, 2, 0, 2, 9*0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badnn = .false.
      nmax = 1
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 continue
*
*     Maximum blocksize and shift -- we assume that blocksize and number
*     of shifts are monotone increasing functions of N.
*
      nb = max( 1, ilaenv( 1, 'SGEQRF', ' ', nmax, nmax, -1, -1 ),
     $     ilaenv( 1, 'SORMQR', 'LT', nmax, nmax, nmax, -1 ),
     $     ilaenv( 1, 'SORGQR', ' ', nmax, nmax, nmax, -1 ) )
      nbz = ilaenv( 1, 'SHGEQZ', 'SII', nmax, 1, nmax, 0 )
      ns = ilaenv( 4, 'SHGEQZ', 'SII', nmax, 1, nmax, 0 )
      i1 = nbz + ns
      lwkopt = 2*nmax + max( 6*nmax, nmax*( nb+1 ),
     $         ( 2*i1+nmax+1 )*( i1+1 ) )
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -10
      ELSE IF( ldq.LE.1 .OR. ldq.LT.nmax ) THEN
         info = -19
      ELSE IF( lwkopt.GT.lwork ) THEN
         info = -30
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SDRVGG', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   return
*
      safmin = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
      safmin = safmin / ulp
      safmax = one / safmin
      CALL slabad( safmin, safmax )
      ulpinv = one / ulp
*
*     The values RMAGN(2:3) depend on N, see below.
*
      rmagn( 0 ) = zero
      rmagn( 1 ) = one
*
*     Loop over sizes, types
*
      ntestt = 0
      nerrs = 0
      nmats = 0
*
      DO 170 jsize = 1, nsizes
         n = nn( jsize )
         n1 = max( 1, n )
         rmagn( 2 ) = safmax*ulp / REAL( n1 )
         rmagn( 3 ) = safmin*ulpinv*n1
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 160 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         go to 160
            nmats = nmats + 1
            ntest = 0
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       continue
*
*           Initialize RESULT
*
            DO 30 j = 1, 15
               result( j ) = zero
   30       continue
*
*           Compute A and B
*
*           Description of control parameters:
*
*           KCLASS: =1 means w/o rotation, =2 means w/ rotation,
*                   =3 means random.
*           KATYPE: the "type" to be passed to SLATM4 for computing A.
*           KAZERO: the pattern of zeros on the diagonal for A:
*                   =1: ( xxx ), =2: (0, xxx ) =3: ( 0, 0, xxx, 0 ),
*                   =4: ( 0, xxx, 0, 0 ), =5: ( 0, 0, 1, xxx, 0 ),
*                   =6: ( 0, 1, 0, xxx, 0 ).  (xxx means a string of
*                   non-zero entries.)
*           KAMAGN: the magnitude of the matrix: =0: zero, =1: O(1),
*                   =2: large, =3: small.
*           IASIGN: 1 if the diagonal elements of A are to be
*                   multiplied by a random magnitude 1 number, =2 if
*                   randomly chosen diagonal blocks are to be rotated
*                   to form 2x2 blocks.
*           KBTYPE, KBZERO, KBMAGN, IBSIGN: the same, but for B.
*           KTRIAN: =0: don't fill in the upper triangle, =1: do.
*           KZ1, KZ2, KADD: used to implement KAZERO and KBZERO.
*           RMAGN: used to implement KAMAGN and KBMAGN.
*
            IF( mtypes.GT.maxtyp )
     $         go to 110
            iinfo = 0
            IF( kclass( jtype ).LT.3 ) THEN
*
*              Generate A (w/o rotation)
*
               IF( abs( katype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL slaset( 'Full', n, n, zero, zero, a, lda )
               ELSE
                  in = n
               END IF
               CALL slatm4( katype( jtype ), in, kz1( kazero( jtype ) ),
     $                      kz2( kazero( jtype ) ), iasign( jtype ),
     $                      rmagn( kamagn( jtype ) ), ulp,
     $                      rmagn( ktrian( jtype )*kamagn( jtype ) ), 2,
     $                      iseed, a, lda )
               iadd = kadd( kazero( jtype ) )
               IF( iadd.GT.0 .AND. iadd.LE.n )
     $            a( iadd, iadd ) = one
*
*              Generate B (w/o rotation)
*
               IF( abs( kbtype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL slaset( 'Full', n, n, zero, zero, b, lda )
               ELSE
                  in = n
               END IF
               CALL slatm4( kbtype( jtype ), in, kz1( kbzero( jtype ) ),
     $                      kz2( kbzero( jtype ) ), ibsign( jtype ),
     $                      rmagn( kbmagn( jtype ) ), one,
     $                      rmagn( ktrian( jtype )*kbmagn( jtype ) ), 2,
     $                      iseed, b, lda )
               iadd = kadd( kbzero( jtype ) )
               IF( iadd.NE.0 .AND. iadd.LE.n )
     $            b( iadd, iadd ) = one
*
               IF( kclass( jtype ).EQ.2 .AND. n.GT.0 ) THEN
*
*                 Include rotations
*
*                 Generate Q, Z as Householder transformations times
*                 a diagonal matrix.
*
                  DO 50 jc = 1, n - 1
                     DO 40 jr = jc, n
                        q( jr, jc ) = slarnd( 3, iseed )
                        z( jr, jc ) = slarnd( 3, iseed )
   40                continue
                     CALL slarfg( n+1-jc, q( jc, jc ), q( jc+1, jc ), 1,
     $                            work( jc ) )
                     work( 2*n+jc ) = sign( one, q( jc, jc ) )
                     q( jc, jc ) = one
                     CALL slarfg( n+1-jc, z( jc, jc ), z( jc+1, jc ), 1,
     $                            work( n+jc ) )
                     work( 3*n+jc ) = sign( one, z( jc, jc ) )
                     z( jc, jc ) = one
   50             continue
                  q( n, n ) = one
                  work( n ) = zero
                  work( 3*n ) = sign( one, slarnd( 2, iseed ) )
                  z( n, n ) = one
                  work( 2*n ) = zero
                  work( 4*n ) = sign( one, slarnd( 2, iseed ) )
*
*                 Apply the diagonal matrices
*
                  DO 70 jc = 1, n
                     DO 60 jr = 1, n
                        a( jr, jc ) = work( 2*n+jr )*work( 3*n+jc )*
     $                                a( jr, jc )
                        b( jr, jc ) = work( 2*n+jr )*work( 3*n+jc )*
     $                                b( jr, jc )
   60                continue
   70             continue
                  CALL sorm2r( 'L', 'N', n, n, n-1, q, ldq, work, a,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               go to 100
                  CALL sorm2r( 'R', 'T', n, n, n-1, z, ldq, work( n+1 ),
     $                         a, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               go to 100
                  CALL sorm2r( 'L', 'N', n, n, n-1, q, ldq, work, b,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               go to 100
                  CALL sorm2r( 'R', 'T', n, n, n-1, z, ldq, work( n+1 ),
     $                         b, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               go to 100
               END IF
            ELSE
*
*              Random matrices
*
               DO 90 jc = 1, n
                  DO 80 jr = 1, n
                     a( jr, jc ) = rmagn( kamagn( jtype ) )*
     $                             slarnd( 2, iseed )
                     b( jr, jc ) = rmagn( kbmagn( jtype ) )*
     $                             slarnd( 2, iseed )
   80             continue
   90          continue
            END IF
*
  100       continue
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               return
            END IF
*
  110       continue
*
*           Call SGEGS to compute H, T, Q, Z, alpha, and beta.
*
            CALL slacpy( ' ', n, n, a, lda, s, lda )
            CALL slacpy( ' ', n, n, b, lda, t, lda )
            ntest = 1
            result( 1 ) = ulpinv
*
            CALL sgegs( 'V', 'V', n, s, lda, t, lda, alphr1, alphi1,
     $                  beta1, q, ldq, z, ldq, work, lwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'SGEGS', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               go to 140
            END IF
*
            ntest = 4
*
*           Do tests 1--4
*
            CALL sget51( 1, n, a, lda, s, lda, q, ldq, z, ldq, work,
     $                   result( 1 ) )
            CALL sget51( 1, n, b, lda, t, lda, q, ldq, z, ldq, work,
     $                   result( 2 ) )
            CALL sget51( 3, n, b, lda, t, lda, q, ldq, q, ldq, work,
     $                   result( 3 ) )
            CALL sget51( 3, n, b, lda, t, lda, z, ldq, z, ldq, work,
     $                   result( 4 ) )
*
*           Do test 5: compare eigenvalues with diagonals.
*           Also check Schur form of A.
*
            temp1 = zero
*
            DO 120 j = 1, n
               ilabad = .false.
               IF( alphi1( j ).EQ.zero ) THEN
                  temp2 = ( abs( alphr1( j )-s( j, j ) ) /
     $                    max( safmin, abs( alphr1( j ) ), abs( s( j,
     $                    j ) ) )+abs( beta1( j )-t( j, j ) ) /
     $                    max( safmin, abs( beta1( j ) ), abs( t( j,
     $                    j ) ) ) ) / ulp
                  IF( j.LT.n ) THEN
                     IF( s( j+1, j ).NE.zero )
     $                  ilabad = .true.
                  END IF
                  IF( j.GT.1 ) THEN
                     IF( s( j, j-1 ).NE.zero )
     $                  ilabad = .true.
                  END IF
               ELSE
                  IF( alphi1( j ).GT.zero ) THEN
                     i1 = j
                  ELSE
                     i1 = j - 1
                  END IF
                  IF( i1.LE.0 .OR. i1.GE.n ) THEN
                     ilabad = .true.
                  ELSE IF( i1.LT.n-1 ) THEN
                     IF( s( i1+2, i1+1 ).NE.zero )
     $                  ilabad = .true.
                  ELSE IF( i1.GT.1 ) THEN
                     IF( s( i1, i1-1 ).NE.zero )
     $                  ilabad = .true.
                  END IF
                  IF( .NOT.ilabad ) THEN
                     CALL sget53( s( i1, i1 ), lda, t( i1, i1 ), lda,
     $                            beta1( j ), alphr1( j ), alphi1( j ),
     $                            temp2, iinfo )
                     IF( iinfo.GE.3 ) THEN
                        WRITE( nounit, fmt = 9997 )iinfo, j, n, jtype,
     $                     ioldsd
                        info = abs( iinfo )
                     END IF
                  ELSE
                     temp2 = ulpinv
                  END IF
               END IF
               temp1 = max( temp1, temp2 )
               IF( ilabad ) THEN
                  WRITE( nounit, fmt = 9996 )j, n, jtype, ioldsd
               END IF
  120       continue
            result( 5 ) = temp1
*
*           Call SGEGV to compute S2, T2, VL, and VR, do tests.
*
*           Eigenvalues and Eigenvectors
*
            CALL slacpy( ' ', n, n, a, lda, s2, lda )
            CALL slacpy( ' ', n, n, b, lda, t2, lda )
            ntest = 6
            result( 6 ) = ulpinv
*
            CALL sgegv( 'V', 'V', n, s2, lda, t2, lda, alphr2, alphi2,
     $                  beta2, vl, ldq, vr, ldq, work, lwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'SGEGV', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               go to 140
            END IF
*
            ntest = 7
*
*           Do Tests 6 and 7
*
            CALL sget52( .true., n, a, lda, b, lda, vl, ldq, alphr2,
     $                   alphi2, beta2, work, dumma( 1 ) )
            result( 6 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thrshn ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'SGEGV', dumma( 2 ),
     $            n, jtype, ioldsd
            END IF
*
            CALL sget52( .false., n, a, lda, b, lda, vr, ldq, alphr2,
     $                   alphi2, beta2, work, dumma( 1 ) )
            result( 7 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'SGEGV', dumma( 2 ),
     $            n, jtype, ioldsd
            END IF
*
*           Check form of Complex eigenvalues.
*
            DO 130 j = 1, n
               ilabad = .false.
               IF( alphi2( j ).GT.zero ) THEN
                  IF( j.EQ.n ) THEN
                     ilabad = .true.
                  ELSE IF( alphi2( j+1 ).GE.zero ) THEN
                     ilabad = .true.
                  END IF
               ELSE IF( alphi2( j ).LT.zero ) THEN
                  IF( j.EQ.1 ) THEN
                     ilabad = .true.
                  ELSE IF( alphi2( j-1 ).LE.zero ) THEN
                     ilabad = .true.
                  END IF
               END IF
               IF( ilabad ) THEN
                  WRITE( nounit, fmt = 9996 )j, n, jtype, ioldsd
               END IF
  130       continue
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  140       continue
*
            ntestt = ntestt + ntest
*
*           Print out tests which fail.
*
            DO 150 jr = 1, ntest
               IF( result( jr ).GE.thresh ) THEN
*
*                 If this is the first test to fail,
*                 print a header to the data file.
*
                  IF( nerrs.EQ.0 ) THEN
                     WRITE( nounit, fmt = 9995 )'SGG'
*
*                    Matrix types
*
                     WRITE( nounit, fmt = 9994 )
                     WRITE( nounit, fmt = 9993 )
                     WRITE( nounit, fmt = 9992 )'Orthogonal'
*
*                    Tests performed
*
                     WRITE( nounit, fmt = 9991 )'orthogonal', '''',
     $                  'transpose', ( '''', j = 1, 5 )
*
                  END IF
                  nerrs = nerrs + 1
                  IF( result( jr ).LT.10000.0 ) THEN
                     WRITE( nounit, fmt = 9990 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  ELSE
                     WRITE( nounit, fmt = 9989 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  END IF
               END IF
  150       continue
*
  160    continue
  170 continue
*
*     Summary
*
      CALL alasvm( 'SGG', nounit, nerrs, ntestt, 0 )
      return
*
 9999 format( ' SDRVGG: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
 9998 format( ' SDRVGG: ', a, ' Eigenvectors from ', a, ' incorrectly ',
     $      'normalized.', / ' Bits of error=', 0p, g10.3, ',', 9x,
     $      'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5,
     $      ')' )
*
 9997 format( ' SDRVGG: SGET53 returned INFO=', i1, ' for eigenvalue ',
     $      i6, '.', / 9x, 'N=', i6, ', JTYPE=', i6, ', ISEED=(',
     $      3( i5, ',' ), i5, ')' )
*
 9996 format( ' SDRVGG: S not in Schur form at eigenvalue ', i6, '.',
     $      / 9x, 'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ),
     $      i5, ')' )
*
 9995 format( / 1x, a3, ' -- Real Generalized eigenvalue problem driver'
     $       )
*
 9994 format( ' Matrix types (see SDRVGG for details): ' )
*
 9993 format( ' Special Matrices:', 23x,
     $      '(J''=transposed Jordan block)',
     $      / '   1=(0,0)  2=(I,0)  3=(0,I)  4=(I,I)  5=(J'',J'')  ',
     $      '6=(diag(J'',I), diag(I,J''))', / ' Diagonal Matrices:  ( ',
     $      'D=diag(0,1,2,...) )', / '   7=(D,I)   9=(large*D, small*I',
     $      ')  11=(large*I, small*D)  13=(large*D, large*I)', /
     $      '   8=(I,D)  10=(small*D, large*I)  12=(small*I, large*D) ',
     $      ' 14=(small*D, small*I)', / '  15=(D, reversed D)' )
 9992 format( ' Matrices Rotated by Random ', a, ' Matrices U, V:',
     $      / '  16=Transposed Jordan Blocks             19=geometric ',
     $      'alpha, beta=0,1', / '  17=arithm. alpha&beta             ',
     $      '      20=arithmetic alpha, beta=0,1', / '  18=clustered ',
     $      'alpha, beta=0,1            21=random alpha, beta=0,1',
     $      / ' Large & Small Matrices:', / '  22=(large, small)   ',
     $      '23=(small,large)    24=(small,small)    25=(large,large)',
     $      / '  26=random O(1) matrices.' )
*
 9991 format( / ' Tests performed:  (S is Schur, T is triangular, ',
     $      'Q and Z are ', a, ',', / 20x,
     $      'l and r are the appropriate left and right', / 19x,
     $      'eigenvectors, resp., a is alpha, b is beta, and', / 19x, a,
     $      ' means ', a, '.)', / ' 1 = | A - Q S Z', a,
     $      ' | / ( |A| n ulp )      2 = | B - Q T Z', a,
     $      ' | / ( |B| n ulp )', / ' 3 = | I - QQ', a,
     $      ' | / ( n ulp )             4 = | I - ZZ', a,
     $      ' | / ( n ulp )', /
     $      ' 5 = difference between (alpha,beta) and diagonals of',
     $      ' (S,T)', / ' 6 = max | ( b A - a B )', a,
     $      ' l | / const.   7 = max | ( b A - a B ) r | / const.',
     $      / 1x )
 9990 format( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i3, ' is', 0p, f8.2 )
 9989 format( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i3, ' is', 1p, e10.3 )
*
*     End of SDRVGG
*
      END