stzt02.f

Go to the documentation of this file.

*> \brief \b STZT02
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION STZT02( M, N, AF, LDA, TAU, WORK,
*                        LWORK )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       REAL               AF( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> STZT02 returns
*>      || I - Q'*Q || / ( M * eps)
*> where the matrix Q is defined by the Householder transformations
*> generated by STZRQF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix AF.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix AF.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is REAL array, dimension (LDA,N)
*>          The output of STZRQF.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array AF.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is REAL array, dimension (M)
*>          Details of the Householder transformations as returned by
*>          STZRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          length of WORK array. Must be >= N*N+N
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_lin
*
*  =====================================================================
      REAL             FUNCTION stzt02( M, N, AF, LDA, TAU, WORK,
     $                 lwork )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               af( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
*     ..
*     .. Local Arrays ..
      REAL               rwork( 1 )
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           slatzm, slaset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Executable Statements ..
*
      stzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'STZT02', 7 )
         return
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   return
*
*     Q := I
*
      CALL slaset( 'Full', n, n, zero, one, work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      DO 10 i = m, 1, -1
         CALL slatzm( 'Left', n-m+1, n, af( i, m+1 ), lda, tau( i ),
     $                work( i ), work( m+1 ), n, work( n*n+1 ) )
   10 continue
*
*     Q := P(m) * ... * P(1) * Q
*
      DO 20 i = 1, m
         CALL slatzm( 'Left', n-m+1, n, af( i, m+1 ), lda, tau( i ),
     $                work( i ), work( m+1 ), n, work( n*n+1 ) )
   20 continue
*
*     Q := Q - I
*
      DO 30 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   30 continue
*
      stzt02 = slange( 'One-norm', n, n, work, n, rwork ) /
     $         ( slamch( 'Epsilon' )*REAL( MAX( M, N ) ) )
      return
*
*     End of STZT02
*
      END