zlartg.f

Go to the documentation of this file.

*> \brief \b ZLARTG generates a plane rotation with real cosine and complex sine.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download ZLARTG + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlartg.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlartg.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlartg.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLARTG( F, G, CS, SN, R )
* 
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   CS
*       COMPLEX*16         F, G, R, SN
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLARTG generates a plane rotation so that
*>
*>    [  CS  SN  ]     [ F ]     [ R ]
*>    [  __      ]  .  [   ]  =  [   ]   where CS**2 + |SN|**2 = 1.
*>    [ -SN  CS  ]     [ G ]     [ 0 ]
*>
*> This is a faster version of the BLAS1 routine ZROTG, except for
*> the following differences:
*>    F and G are unchanged on return.
*>    If G=0, then CS=1 and SN=0.
*>    If F=0, then CS=0 and SN is chosen so that R is real.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] F
*> \verbatim
*>          F is COMPLEX*16
*>          The first component of vector to be rotated.
*> \endverbatim
*>
*> \param[in] G
*> \verbatim
*>          G is COMPLEX*16
*>          The second component of vector to be rotated.
*> \endverbatim
*>
*> \param[out] CS
*> \verbatim
*>          CS is DOUBLE PRECISION
*>          The cosine of the rotation.
*> \endverbatim
*>
*> \param[out] SN
*> \verbatim
*>          SN is COMPLEX*16
*>          The sine of the rotation.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is COMPLEX*16
*>          The nonzero component of the rotated vector.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup complex16OTHERauxiliary
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  3-5-96 - Modified with a new algorithm by W. Kahan and J. Demmel
*>
*>  This version has a few statements commented out for thread safety
*>  (machine parameters are computed on each entry). 10 feb 03, SJH.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE zlartg( F, G, CS, SN, R )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   cs
      COMPLEX*16         f, g, r, sn
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   two, one, zero
      parameter( two = 2.0d+0, one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         czero
      parameter( czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
*     LOGICAL            FIRST
      INTEGER            count, i
      DOUBLE PRECISION   d, di, dr, eps, f2, f2s, g2, g2s, safmin,
     $                   safmn2, safmx2, scale
      COMPLEX*16         ff, fs, gs
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlapy2
      EXTERNAL           dlamch, dlapy2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dconjg, dimag, int, log,
     $                   max, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   abs1, abssq
*     ..
*     .. Save statement ..
*     SAVE               FIRST, SAFMX2, SAFMIN, SAFMN2
*     ..
*     .. Data statements ..
*     DATA               FIRST / .TRUE. /
*     ..
*     .. Statement Function definitions ..
      abs1( ff ) = max( abs( dble( ff ) ), abs( dimag( ff ) ) )
      abssq( ff ) = dble( ff )**2 + dimag( ff )**2
*     ..
*     .. Executable Statements ..
*
*     IF( FIRST ) THEN
         safmin = dlamch( 'S' )
         eps = dlamch( 'E' )
         safmn2 = dlamch( 'B' )**int( log( safmin / eps ) /
     $            log( dlamch( 'B' ) ) / two )
         safmx2 = one / safmn2
*        FIRST = .FALSE.
*     END IF
      scale = max( abs1( f ), abs1( g ) )
      fs = f
      gs = g
      count = 0
      IF( scale.GE.safmx2 ) THEN
   10    continue
         count = count + 1
         fs = fs*safmn2
         gs = gs*safmn2
         scale = scale*safmn2
         IF( scale.GE.safmx2 )
     $      go to 10
      ELSE IF( scale.LE.safmn2 ) THEN
         IF( g.EQ.czero ) THEN
            cs = one
            sn = czero
            r = f
            return
         END IF
   20    continue
         count = count - 1
         fs = fs*safmx2
         gs = gs*safmx2
         scale = scale*safmx2
         IF( scale.LE.safmn2 )
     $      go to 20
      END IF
      f2 = abssq( fs )
      g2 = abssq( gs )
      IF( f2.LE.max( g2, one )*safmin ) THEN
*
*        This is a rare case: F is very small.
*
         IF( f.EQ.czero ) THEN
            cs = zero
            r = dlapy2( dble( g ), dimag( g ) )
*           Do complex/real division explicitly with two real divisions
            d = dlapy2( dble( gs ), dimag( gs ) )
            sn = dcmplx( dble( gs ) / d, -dimag( gs ) / d )
            return
         END IF
         f2s = dlapy2( dble( fs ), dimag( fs ) )
*        G2 and G2S are accurate
*        G2 is at least SAFMIN, and G2S is at least SAFMN2
         g2s = sqrt( g2 )
*        Error in CS from underflow in F2S is at most
*        UNFL / SAFMN2 .lt. sqrt(UNFL*EPS) .lt. EPS
*        If MAX(G2,ONE)=G2, then F2 .lt. G2*SAFMIN,
*        and so CS .lt. sqrt(SAFMIN)
*        If MAX(G2,ONE)=ONE, then F2 .lt. SAFMIN
*        and so CS .lt. sqrt(SAFMIN)/SAFMN2 = sqrt(EPS)
*        Therefore, CS = F2S/G2S / sqrt( 1 + (F2S/G2S)**2 ) = F2S/G2S
         cs = f2s / g2s
*        Make sure abs(FF) = 1
*        Do complex/real division explicitly with 2 real divisions
         IF( abs1( f ).GT.one ) THEN
            d = dlapy2( dble( f ), dimag( f ) )
            ff = dcmplx( dble( f ) / d, dimag( f ) / d )
         ELSE
            dr = safmx2*dble( f )
            di = safmx2*dimag( f )
            d = dlapy2( dr, di )
            ff = dcmplx( dr / d, di / d )
         END IF
         sn = ff*dcmplx( dble( gs ) / g2s, -dimag( gs ) / g2s )
         r = cs*f + sn*g
      ELSE
*
*        This is the most common case.
*        Neither F2 nor F2/G2 are less than SAFMIN
*        F2S cannot overflow, and it is accurate
*
         f2s = sqrt( one+g2 / f2 )
*        Do the F2S(real)*FS(complex) multiply with two real multiplies
         r = dcmplx( f2s*dble( fs ), f2s*dimag( fs ) )
         cs = one / f2s
         d = f2 + g2
*        Do complex/real division explicitly with two real divisions
         sn = dcmplx( dble( r ) / d, dimag( r ) / d )
         sn = sn*dconjg( gs )
         IF( count.NE.0 ) THEN
            IF( count.GT.0 ) THEN
               DO 30 i = 1, count
                  r = r*safmx2
   30          continue
            ELSE
               DO 40 i = 1, -count
                  r = r*safmn2
   40          continue
            END IF
         END IF
      END IF
      return
*
*     End of ZLARTG
*
      END