cgesc2.f

Go to the documentation of this file.

*> \brief \b CGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed by sgetc2.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CGESC2 + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgesc2.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgesc2.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgesc2.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGESC2( N, A, LDA, RHS, IPIV, JPIV, SCALE )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, N
*       REAL               SCALE
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * ), JPIV( * )
*       COMPLEX            A( LDA, * ), RHS( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGESC2 solves a system of linear equations
*>
*>           A * X = scale* RHS
*>
*> with a general N-by-N matrix A using the LU factorization with
*> complete pivoting computed by CGETC2.
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA, N)
*>          On entry, the  LU part of the factorization of the n-by-n
*>          matrix A computed by CGETC2:  A = P * L * U * Q
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1, N).
*> \endverbatim
*>
*> \param[in,out] RHS
*> \verbatim
*>          RHS is COMPLEX array, dimension N.
*>          On entry, the right hand side vector b.
*>          On exit, the solution vector X.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= i <= N, row i of the
*>          matrix has been interchanged with row IPIV(i).
*> \endverbatim
*>
*> \param[in] JPIV
*> \verbatim
*>          JPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= j <= N, column j of the
*>          matrix has been interchanged with column JPIV(j).
*> \endverbatim
*>
*> \param[out] SCALE
*> \verbatim
*>          SCALE is REAL
*>           On exit, SCALE contains the scale factor. SCALE is chosen
*>           0 <= SCALE <= 1 to prevent owerflow in the solution.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup complexGEauxiliary
*
*> \par Contributors:
*  ==================
*>
*>     Bo Kagstrom and Peter Poromaa, Department of Computing Science,
*>     Umea University, S-901 87 Umea, Sweden.
*
*  =====================================================================
      SUBROUTINE cgesc2( N, A, LDA, RHS, IPIV, JPIV, SCALE )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            lda, n
      REAL               scale
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * ), jpiv( * )
      COMPLEX            a( lda, * ), rhs( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one, two
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      REAL               bignum, eps, smlnum
      COMPLEX            temp
*     ..
*     .. External Subroutines ..
      EXTERNAL           claswp, cscal, slabad
*     ..
*     .. External Functions ..
      INTEGER            icamax
      REAL               slamch
      EXTERNAL           icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, real
*     ..
*     .. Executable Statements ..
*
*     Set constant to control overflow
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' ) / eps
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Apply permutations IPIV to RHS
*
      CALL claswp( 1, rhs, lda, 1, n-1, ipiv, 1 )
*
*     Solve for L part
*
      DO 20 i = 1, n - 1
         DO 10 j = i + 1, n
            rhs( j ) = rhs( j ) - a( j, i )*rhs( i )
   10    continue
   20 continue
*
*     Solve for U part
*
      scale = one
*
*     Check for scaling
*
      i = icamax( n, rhs, 1 )
      IF( two*smlnum*abs( rhs( i ) ).GT.abs( a( n, n ) ) ) THEN
         temp = cmplx( one / two, zero ) / abs( rhs( i ) )
         CALL cscal( n, temp, rhs( 1 ), 1 )
         scale = scale*REAL( temp )
      END IF
      DO 40 i = n, 1, -1
         temp = cmplx( one, zero ) / a( i, i )
         rhs( i ) = rhs( i )*temp
         DO 30 j = i + 1, n
            rhs( i ) = rhs( i ) - rhs( j )*( a( i, j )*temp )
   30    continue
   40 continue
*
*     Apply permutations JPIV to the solution (RHS)
*
      CALL claswp( 1, rhs, lda, 1, n-1, jpiv, -1 )
      return
*
*     End of CGESC2
*
      END