zget36.f

Go to the documentation of this file.

*> \brief \b ZGET36
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGET36( RMAX, LMAX, NINFO, KNT, NIN )
* 
*       .. Scalar Arguments ..
*       INTEGER            KNT, LMAX, NIN, NINFO
*       DOUBLE PRECISION   RMAX
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGET36 tests ZTREXC, a routine for reordering diagonal entries of a
*> matrix in complex Schur form. Thus, ZLAEXC computes a unitary matrix
*> Q such that
*>
*>    Q' * T1 * Q  = T2
*>
*> and where one of the diagonal blocks of T1 (the one at row IFST) has
*> been moved to position ILST.
*>
*> The test code verifies that the residual Q'*T1*Q-T2 is small, that T2
*> is in Schur form, and that the final position of the IFST block is
*> ILST.
*>
*> The test matrices are read from a file with logical unit number NIN.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[out] RMAX
*> \verbatim
*>          RMAX is DOUBLE PRECISION
*>          Value of the largest test ratio.
*> \endverbatim
*>
*> \param[out] LMAX
*> \verbatim
*>          LMAX is INTEGER
*>          Example number where largest test ratio achieved.
*> \endverbatim
*>
*> \param[out] NINFO
*> \verbatim
*>          NINFO is INTEGER
*>          Number of examples where INFO is nonzero.
*> \endverbatim
*>
*> \param[out] KNT
*> \verbatim
*>          KNT is INTEGER
*>          Total number of examples tested.
*> \endverbatim
*>
*> \param[in] NIN
*> \verbatim
*>          NIN is INTEGER
*>          Input logical unit number.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zget36( RMAX, LMAX, NINFO, KNT, NIN )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            knt, lmax, nin, ninfo
      DOUBLE PRECISION   rmax
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
      INTEGER            ldt, lwork
      parameter( ldt = 10, lwork = 2*ldt*ldt )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ifst, ilst, info1, info2, j, n
      DOUBLE PRECISION   eps, res
      COMPLEX*16         ctemp
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   result( 2 ), rwork( ldt )
      COMPLEX*16         diag( ldt ), q( ldt, ldt ), t1( ldt, ldt ),
     $                   t2( ldt, ldt ), tmp( ldt, ldt ), work( lwork )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           zcopy, zhst01, zlacpy, zlaset, ztrexc
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'P' )
      rmax = zero
      lmax = 0
      knt = 0
      ninfo = 0
*
*     Read input data until N=0
*
   10 continue
      READ( nin, fmt = * )n, ifst, ilst
      IF( n.EQ.0 )
     $   return
      knt = knt + 1
      DO 20 i = 1, n
         READ( nin, fmt = * )( tmp( i, j ), j = 1, n )
   20 continue
      CALL zlacpy( 'F', n, n, tmp, ldt, t1, ldt )
      CALL zlacpy( 'F', n, n, tmp, ldt, t2, ldt )
      res = zero
*
*     Test without accumulating Q
*
      CALL zlaset( 'Full', n, n, czero, cone, q, ldt )
      CALL ztrexc( 'N', n, t1, ldt, q, ldt, ifst, ilst, info1 )
      DO 40 i = 1, n
         DO 30 j = 1, n
            IF( i.EQ.j .AND. q( i, j ).NE.cone )
     $         res = res + one / eps
            IF( i.NE.j .AND. q( i, j ).NE.czero )
     $         res = res + one / eps
   30    continue
   40 continue
*
*     Test with accumulating Q
*
      CALL zlaset( 'Full', n, n, czero, cone, q, ldt )
      CALL ztrexc( 'V', n, t2, ldt, q, ldt, ifst, ilst, info2 )
*
*     Compare T1 with T2
*
      DO 60 i = 1, n
         DO 50 j = 1, n
            IF( t1( i, j ).NE.t2( i, j ) )
     $         res = res + one / eps
   50    continue
   60 continue
      IF( info1.NE.0 .OR. info2.NE.0 )
     $   ninfo = ninfo + 1
      IF( info1.NE.info2 )
     $   res = res + one / eps
*
*     Test for successful reordering of T2
*
      CALL zcopy( n, tmp, ldt+1, diag, 1 )
      IF( ifst.LT.ilst ) THEN
         DO 70 i = ifst + 1, ilst
            ctemp = diag( i )
            diag( i ) = diag( i-1 )
            diag( i-1 ) = ctemp
   70    continue
      ELSE IF( ifst.GT.ilst ) THEN
         DO 80 i = ifst - 1, ilst, -1
            ctemp = diag( i+1 )
            diag( i+1 ) = diag( i )
            diag( i ) = ctemp
   80    continue
      END IF
      DO 90 i = 1, n
         IF( t2( i, i ).NE.diag( i ) )
     $      res = res + one / eps
   90 continue
*
*     Test for small residual, and orthogonality of Q
*
      CALL zhst01( n, 1, n, tmp, ldt, t2, ldt, q, ldt, work, lwork,
     $             rwork, result )
      res = res + result( 1 ) + result( 2 )
*
*     Test for T2 being in Schur form
*
      DO 110 j = 1, n - 1
         DO 100 i = j + 1, n
            IF( t2( i, j ).NE.czero )
     $         res = res + one / eps
  100    continue
  110 continue
      IF( res.GT.rmax ) THEN
         rmax = res
         lmax = knt
      END IF
      go to 10
*
*     End of ZGET36
*
      END