slauum.f

Go to the documentation of this file.

*> \brief \b SLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download SLAUUM + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slauum.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slauum.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slauum.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAUUM( UPLO, N, A, LDA, INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, N
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLAUUM computes the product U * U**T or L**T * L, where the triangular
*> factor U or L is stored in the upper or lower triangular part of
*> the array A.
*>
*> If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
*> overwriting the factor U in A.
*> If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
*> overwriting the factor L in A.
*>
*> This is the blocked form of the algorithm, calling Level 3 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the triangular factor stored in the array A
*>          is upper or lower triangular:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the triangular factor U or L.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          On entry, the triangular factor U or L.
*>          On exit, if UPLO = 'U', the upper triangle of A is
*>          overwritten with the upper triangle of the product U * U**T;
*>          if UPLO = 'L', the lower triangle of A is overwritten with
*>          the lower triangle of the product L**T * L.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -k, the k-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup realOTHERauxiliary
*
*  =====================================================================
      SUBROUTINE slauum( UPLO, N, A, LDA, INFO )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, n
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            i, ib, nb
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            ilaenv
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slauu2, ssyrk, strmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLAUUM', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   return
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'SLAUUM', uplo, n, -1, -1, -1 )
*
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL slauu2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code
*
         IF( upper ) THEN
*
*           Compute the product U * U**T.
*
            DO 10 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL strmm( 'Right', 'Upper', 'Transpose', 'Non-unit',
     $                     i-1, ib, one, a( i, i ), lda, a( 1, i ),
     $                     lda )
               CALL slauu2( 'Upper', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL sgemm( 'No transpose', 'Transpose', i-1, ib,
     $                        n-i-ib+1, one, a( 1, i+ib ), lda,
     $                        a( i, i+ib ), lda, one, a( 1, i ), lda )
                  CALL ssyrk( 'Upper', 'No transpose', ib, n-i-ib+1,
     $                        one, a( i, i+ib ), lda, one, a( i, i ),
     $                        lda )
               END IF
   10       continue
         ELSE
*
*           Compute the product L**T * L.
*
            DO 20 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL strmm( 'Left', 'Lower', 'Transpose', 'Non-unit', ib,
     $                     i-1, one, a( i, i ), lda, a( i, 1 ), lda )
               CALL slauu2( 'Lower', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL sgemm( 'Transpose', 'No transpose', ib, i-1,
     $                        n-i-ib+1, one, a( i+ib, i ), lda,
     $                        a( i+ib, 1 ), lda, one, a( i, 1 ), lda )
                  CALL ssyrk( 'Lower', 'Transpose', ib, n-i-ib+1, one,
     $                        a( i+ib, i ), lda, one, a( i, i ), lda )
               END IF
   20       continue
         END IF
      END IF
*
      return
*
*     End of SLAUUM
*
      END