zgrqts.f

Go to the documentation of this file.

*> \brief \b ZGRQTS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGRQTS( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
*                          BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LWORK, M, N, P
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   RESULT( 4 ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), AF( LDA, * ), B( LDB, * ),
*      $                   BF( LDB, * ), BWK( LDB, * ), Q( LDA, * ),
*      $                   R( LDA, * ), T( LDB, * ), TAUA( * ), TAUB( * ),
*      $                   WORK( LWORK ), Z( LDB, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGRQTS tests ZGGRQF, which computes the GRQ factorization of an
*> M-by-N matrix A and a P-by-N matrix B: A = R*Q and B = Z*T*Q.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of rows of the matrix B.  P >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The M-by-N matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is COMPLEX*16 array, dimension (LDA,N)
*>          Details of the GRQ factorization of A and B, as returned
*>          by ZGGRQF, see CGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX*16 array, dimension (LDA,N)
*>          The N-by-N unitary matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is COMPLEX*16 array, dimension (LDA,MAX(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, R and Q.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAUA
*> \verbatim
*>          TAUA is COMPLEX*16 array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by DGGQRC.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,N)
*>          On entry, the P-by-N matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*>          BF is COMPLEX*16 array, dimension (LDB,N)
*>          Details of the GQR factorization of A and B, as returned
*>          by ZGGRQF, see CGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (LDB,P)
*>          The P-by-P unitary matrix Z.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is COMPLEX*16 array, dimension (LDB,max(P,N))
*> \endverbatim
*>
*> \param[out] BWK
*> \verbatim
*>          BWK is COMPLEX*16 array, dimension (LDB,N)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the arrays B, BF, Z and T.
*>          LDB >= max(P,N).
*> \endverbatim
*>
*> \param[out] TAUB
*> \verbatim
*>          TAUB is COMPLEX*16 array, dimension (min(P,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by DGGRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK, LWORK >= max(M,P,N)**2.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (4)
*>          The test ratios:
*>            RESULT(1) = norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP)
*>            RESULT(2) = norm( T*Q - Z'*B ) / (MAX(P,N)*norm(B)*ULP)
*>            RESULT(3) = norm( I - Q'*Q ) / ( N*ULP )
*>            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zgrqts( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
     $                   bwk, ldb, taub, work, lwork, rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldb, lwork, m, n, p
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( 4 ), rwork( * )
      COMPLEX*16         a( lda, * ), af( lda, * ), b( ldb, * ),
     $                   bf( ldb, * ), bwk( ldb, * ), q( lda, * ),
     $                   r( lda, * ), t( ldb, * ), taua( * ), taub( * ),
     $                   work( lwork ), z( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
      COMPLEX*16         crogue
      parameter( crogue = ( -1.0d+10, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      DOUBLE PRECISION   anorm, bnorm, resid, ulp, unfl
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange, zlanhe
      EXTERNAL           dlamch, zlange, zlanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zggrqf, zherk, zlacpy, zlaset, zungqr,
     $                   zungrq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      ulp = dlamch( 'Precision' )
      unfl = dlamch( 'Safe minimum' )
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m, n, a, lda, af, lda )
      CALL zlacpy( 'Full', p, n, b, ldb, bf, ldb )
*
      anorm = max( zlange( '1', m, n, a, lda, rwork ), unfl )
      bnorm = max( zlange( '1', p, n, b, ldb, rwork ), unfl )
*
*     Factorize the matrices A and B in the arrays AF and BF.
*
      CALL zggrqf( m, p, n, af, lda, taua, bf, ldb, taub, work, lwork,
     $             info )
*
*     Generate the N-by-N matrix Q
*
      CALL zlaset( 'Full', n, n, crogue, crogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL zlacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL zlacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL zlacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
      CALL zungrq( n, n, min( m, n ), q, lda, taua, work, lwork, info )
*
*     Generate the P-by-P matrix Z
*
      CALL zlaset( 'Full', p, p, crogue, crogue, z, ldb )
      IF( p.GT.1 )
     $   CALL zlacpy( 'Lower', p-1, n, bf( 2, 1 ), ldb, z( 2, 1 ), ldb )
      CALL zungqr( p, p, min( p, n ), z, ldb, taub, work, lwork, info )
*
*     Copy R
*
      CALL zlaset( 'Full', m, n, czero, czero, r, lda )
      IF( m.LE.n ) THEN
         CALL zlacpy( 'Upper', m, m, af( 1, n-m+1 ), lda, r( 1, n-m+1 ),
     $                lda )
      ELSE
         CALL zlacpy( 'Full', m-n, n, af, lda, r, lda )
         CALL zlacpy( 'Upper', n, n, af( m-n+1, 1 ), lda, r( m-n+1, 1 ),
     $                lda )
      END IF
*
*     Copy T
*
      CALL zlaset( 'Full', p, n, czero, czero, t, ldb )
      CALL zlacpy( 'Upper', p, n, bf, ldb, t, ldb )
*
*     Compute R - A*Q'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', m, n, n, -cone,
     $            a, lda, q, lda, cone, r, lda )
*
*     Compute norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP ) .
*
      resid = zlange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, m, n ) ) ) / anorm ) /
     $                 ulp
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute T*Q - Z'*B
*
      CALL zgemm( 'Conjugate transpose', 'No transpose', p, n, p, cone,
     $            z, ldb, b, ldb, czero, bwk, ldb )
      CALL zgemm( 'No transpose', 'No transpose', p, n, n, cone, t, ldb,
     $            q, lda, -cone, bwk, ldb )
*
*     Compute norm( T*Q - Z'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
*
      resid = zlange( '1', p, n, bwk, ldb, rwork )
      IF( bnorm.GT.zero ) THEN
         result( 2 ) = ( ( resid / dble( max( 1, p, m ) ) ) / bnorm ) /
     $                 ulp
      ELSE
         result( 2 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL zlaset( 'Full', n, n, czero, cone, r, lda )
      CALL zherk( 'Upper', 'No Transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( N * ULP ) .
*
      resid = zlanhe( '1', 'Upper', n, r, lda, rwork )
      result( 3 ) = ( resid / dble( max( 1, n ) ) ) / ulp
*
*     Compute I - Z'*Z
*
      CALL zlaset( 'Full', p, p, czero, cone, t, ldb )
      CALL zherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
     $            one, t, ldb )
*
*     Compute norm( I - Z'*Z ) / ( P*ULP ) .
*
      resid = zlanhe( '1', 'Upper', p, t, ldb, rwork )
      result( 4 ) = ( resid / dble( max( 1, p ) ) ) / ulp
*
      return
*
*     End of ZGRQTS
*
      END