sget10.f

Go to the documentation of this file.

*> \brief \b SGET10
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SGET10( M, N, A, LDA, B, LDB, WORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, M, N
*       REAL               RESULT
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SGET10 compares two matrices A and B and computes the ratio
*> RESULT = norm( A - B ) / ( norm(A) * M * EPS )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrices A and B.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and B.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          The m by n matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is REAL array, dimension (LDB,N)
*>          The m by n matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL
*>          RESULT = norm( A - B ) / ( norm(A) * M * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE sget10( M, N, A, LDA, B, LDB, WORK, RESULT )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldb, m, n
      REAL               result
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), b( ldb, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            j
      REAL               anorm, eps, unfl, wnorm
*     ..
*     .. External Functions ..
      REAL               sasum, slamch, slange
      EXTERNAL           sasum, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         result = zero
         return
      END IF
*
      unfl = slamch( 'Safe minimum' )
      eps = slamch( 'Precision' )
*
      wnorm = zero
      DO 10 j = 1, n
         CALL scopy( m, a( 1, j ), 1, work, 1 )
         CALL saxpy( m, -one, b( 1, j ), 1, work, 1 )
         wnorm = max( wnorm, sasum( n, work, 1 ) )
   10 continue
*
      anorm = max( slange( '1', m, n, a, lda, work ), unfl )
*
      IF( anorm.GT.wnorm ) THEN
         result = ( wnorm / anorm ) / ( m*eps )
      ELSE
         IF( anorm.LT.one ) THEN
            result = ( min( wnorm, m*anorm ) / anorm ) / ( m*eps )
         ELSE
            result = min( wnorm / anorm, REAL( M ) ) / ( m*eps )
         END IF
      END IF
*
      return
*
*     End of SGET10
*
      END