clqt03.f

Go to the documentation of this file.

*> \brief \b CLQT03
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLQT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
*                          RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       REAL               RESULT( * ), RWORK( * )
*       COMPLEX            AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
*      $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLQT03 tests CUNMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.
*>
*> CLQT03 compares the results of a call to CUNMLQ with the results of
*> forming Q explicitly by a call to CUNGLQ and then performing matrix
*> multiplication by a call to CGEMM.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows or columns of the matrix C; C is n-by-m if
*>          Q is applied from the left, or m-by-n if Q is applied from
*>          the right.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the orthogonal matrix Q.  N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines the
*>          orthogonal matrix Q.  N >= K >= 0.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is COMPLEX array, dimension (LDA,N)
*>          Details of the LQ factorization of an m-by-n matrix, as
*>          returned by CGELQF. See CGELQF for further details.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is COMPLEX array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] CC
*> \verbatim
*>          CC is COMPLEX array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays AF, C, CC, and Q.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is COMPLEX array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors corresponding
*>          to the LQ factorization in AF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of WORK.  LWORK must be at least M, and should be
*>          M*NB, where NB is the blocksize for this environment.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (4)
*>          The test ratios compare two techniques for multiplying a
*>          random matrix C by an n-by-n orthogonal matrix Q.
*>          RESULT(1) = norm( Q*C - Q*C )  / ( N * norm(C) * EPS )
*>          RESULT(2) = norm( C*Q - C*Q )  / ( N * norm(C) * EPS )
*>          RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS )
*>          RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE clqt03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
     $                   rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               result( * ), rwork( * )
      COMPLEX            af( lda, * ), c( lda, * ), cc( lda, * ),
     $                   q( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            rogue
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          side, trans
      INTEGER            info, iside, itrans, j, mc, nc
      REAL               cnorm, eps, resid
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clange, slamch
      EXTERNAL           lsame, clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, clarnv, claset, cunglq, cunmlq
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL claset( 'Full', n, n, rogue, rogue, q, lda )
      CALL clacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'CUNGLQ'
      CALL cunglq( n, n, k, q, lda, tau, work, lwork, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = n
            nc = m
         ELSE
            side = 'R'
            mc = m
            nc = n
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL clarnv( 2, iseed, mc, c( 1, j ) )
   10    continue
         cnorm = clange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.zero )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
*           Copy C
*
            CALL clacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'CUNMLQ'
            CALL cunmlq( side, trans, mc, nc, k, af, lda, tau, cc, lda,
     $                   work, lwork, info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL cgemm( trans, 'No transpose', mc, nc, mc,
     $                     cmplx( -one ), q, lda, c, lda, cmplx( one ),
     $                     cc, lda )
            ELSE
               CALL cgemm( 'No transpose', trans, mc, nc, nc,
     $                     cmplx( -one ), c, lda, q, lda, cmplx( one ),
     $                     cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = clange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( REAL( MAX( 1, N ) )*cnorm*eps )
*
   20    continue
   30 continue
*
      return
*
*     End of CLQT03
*
      END