slarnd.f

Go to the documentation of this file.

*> \brief \b SLARND
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION SLARND( IDIST, ISEED )
* 
*       .. Scalar Arguments ..
*       INTEGER            IDIST
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLARND returns a random real number from a uniform or normal
*> distribution.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] IDIST
*> \verbatim
*>          IDIST is INTEGER
*>          Specifies the distribution of the random numbers:
*>          = 1:  uniform (0,1)
*>          = 2:  uniform (-1,1)
*>          = 3:  normal (0,1)
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry, the seed of the random number generator; the array
*>          elements must be between 0 and 4095, and ISEED(4) must be
*>          odd.
*>          On exit, the seed is updated.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup real_matgen
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  This routine calls the auxiliary routine SLARAN to generate a random
*>  real number from a uniform (0,1) distribution. The Box-Muller method
*>  is used to transform numbers from a uniform to a normal distribution.
*> \endverbatim
*>
*  =====================================================================
      REAL             FUNCTION slarnd( IDIST, ISEED )
*
*  -- LAPACK auxiliary routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            idist
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, two
      parameter( one = 1.0e+0, two = 2.0e+0 )
      REAL               twopi
      parameter( twopi = 6.2831853071795864769252867663e+0 )
*     ..
*     .. Local Scalars ..
      REAL               t1, t2
*     ..
*     .. External Functions ..
      REAL               slaran
      EXTERNAL           slaran
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cos, log, sqrt
*     ..
*     .. Executable Statements ..
*
*     Generate a real random number from a uniform (0,1) distribution
*
      t1 = slaran( iseed )
*
      IF( idist.EQ.1 ) THEN
*
*        uniform (0,1)
*
         slarnd = t1
      ELSE IF( idist.EQ.2 ) THEN
*
*        uniform (-1,1)
*
         slarnd = two*t1 - one
      ELSE IF( idist.EQ.3 ) THEN
*
*        normal (0,1)
*
         t2 = slaran( iseed )
         slarnd = sqrt( -two*log( t1 ) )*cos( twopi*t2 )
      END IF
      return
*
*     End of SLARND
*
      END